[gentoo-commits] gentoo-x86 commit in app-misc/ca-certificates: ChangeLog ca-certificates-20080514-r1.ebuild

[Robin H. Johnson (robbat2)]

robbat2     08/05/31 18:35:24

  Modified:             ChangeLog
  Added:                ca-certificates-20080514-r1.ebuild
  Log:
  Include a bit of CONFIG_PROTECT_MASK magic, so that the /etc/ca-certificates.conf is updated before update-ca-certificates is run, resolves bug #177397.
  (Portage version: 2.1.5.2)

Revision  Changes    Path
1.16                 app-misc/ca-certificates/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/ca-certificates/ChangeLog?rev=1.16&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/ca-certificates/ChangeLog?rev=1.16&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/ca-certificates/ChangeLog?r1=1.15&r2=1.16

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/ca-certificates/ChangeLog,v
retrieving revision 1.15
retrieving revision 1.16
diff -p -w -b -B -u -u -r1.15 -r1.16
--- ChangeLog	25 May 2008 04:32:35 -0000	1.15
+++ ChangeLog	31 May 2008 18:35:24 -0000	1.16
@@ -1,6 +1,14 @@
 # ChangeLog for app-misc/ca-certificates
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/ca-certificates/ChangeLog,v 1.15 2008/05/25 04:32:35 robbat2 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/ca-certificates/ChangeLog,v 1.16 2008/05/31 18:35:24 robbat2 Exp $
+
+*ca-certificates-20080514-r1 (31 May 2008)
+
+  31 May 2008; Robin H. Johnson <robbat2@g.o>
+  +ca-certificates-20080514-r1.ebuild:
+  Include a bit of CONFIG_PROTECT_MASK magic, so that the
+  /etc/ca-certificates.conf is updated before update-ca-certificates is run,
+  resolves bug #177397.
 
 *ca-certificates-20080514 (25 May 2008)
 



1.1                  app-misc/ca-certificates/ca-certificates-20080514-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/ca-certificates/ca-certificates-20080514-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/ca-certificates/ca-certificates-20080514-r1.ebuild?rev=1.1&content-type=text/plain

Index: ca-certificates-20080514-r1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/ca-certificates/ca-certificates-20080514-r1.ebuild,v 1.1 2008/05/31 18:35:24 robbat2 Exp $

inherit eutils

DESCRIPTION="Common CA Certificates PEM files"
HOMEPAGE="http://www.cacert.org/"
SRC_URI="mirror://debian/pool/main/c/${PN}/${PN}_${PV}_all.deb"

LICENSE="MPL-1.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE=""

DEPEND="|| ( >=sys-apps/coreutils-6.10-r1 sys-apps/mktemp sys-freebsd/freebsd-ubin )"
RDEPEND="${DEPEND}
	dev-libs/openssl"

S=${WORKDIR}

src_unpack() {
	unpack ${A}
	unpack ./data.tar.gz
	rm -f control.tar.gz data.tar.gz debian-binary
}

pkg_setup() {
	# For the conversion to having it in CONFIG_PROTECT_MASK,
	# we need to tell users about it once manually first.
	[[ -f /etc/env.d/98ca-certificates ]] \
		|| ewarn "You should run update-ca-certificates manually after etc-update"
}

src_install() {
	cp -pPR * "${D}"/ || die "installing data failed"

	(
	echo "# Automatically generated by ${CAT}/${PF}"
	echo "# $(date -u)"
	echo "# Do not edit."
	cd "${D}"/usr/share/ca-certificates
	find . -name '*.crt' | sort | cut -b3-
	) > "${D}"/etc/ca-certificates.conf

	mv "${D}"/usr/share/doc/{ca-certificates,${PF}} || die
	prepalldocs
	dodir /etc/env.d/
	echo 'CONFIG_PROTECT_MASK="/etc/ca-certificates.conf"' > "${D}/etc/env.d/98ca-certificates"
}

pkg_postinst() {
	[[ ${ROOT} != "/" ]] && return 0
	# However it's too overzealous when the user has custom certs in place.
	# --fresh is to clean up dangling symlinks
	update-ca-certificates
}



-- 
gentoo-commits@l.g.o mailing list