[gentoo-commits] gentoo-x86 commit in sys-devel/gettext: ChangeLog gettext-0.17-r1.ebuild

[Peter Volkov (pva)]

pva         10/01/05 07:13:54

  Modified:             ChangeLog
  Added:                gettext-0.17-r1.ebuild
  Log:
  Backport upstream fix: replace a lone high surrogate with U+FFFD, bug #299658. Required for gajim test suite to pass.
  (Portage version: 2.1.7.16/cvs/Linux x86_64)

Revision  Changes    Path
1.170                sys-devel/gettext/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/gettext/ChangeLog?rev=1.170&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/gettext/ChangeLog?rev=1.170&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/gettext/ChangeLog?r1=1.169&r2=1.170

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-devel/gettext/ChangeLog,v
retrieving revision 1.169
retrieving revision 1.170
diff -u -r1.169 -r1.170
--- ChangeLog	29 May 2009 19:57:17 -0000	1.169
+++ ChangeLog	5 Jan 2010 07:13:54 -0000	1.170
@@ -1,6 +1,13 @@
 # ChangeLog for sys-devel/gettext
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-devel/gettext/ChangeLog,v 1.169 2009/05/29 19:57:17 flameeyes Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/gettext/ChangeLog,v 1.170 2010/01/05 07:13:54 pva Exp $
+
+*gettext-0.17-r1 (05 Jan 2010)
+
+  05 Jan 2010; Peter Volkov <pva@g.o> +gettext-0.17-r1.ebuild,
+  +files/gettext-0.17-x-python.patch:
+  Backport upstream fix: replace a lone high surrogate with U+FFFD, bug
+  #299658. Required for gajim test suite to pass.
 
   29 May 2009; Diego E. Pettenò <flameeyes@g.o> gettext-0.17.ebuild:
   Replace kernel-conditional dependency on sys-apps/acl with virtual/acl.



1.1                  sys-devel/gettext/gettext-0.17-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/gettext/gettext-0.17-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/gettext/gettext-0.17-r1.ebuild?rev=1.1&content-type=text/plain

Index: gettext-0.17-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-devel/gettext/gettext-0.17-r1.ebuild,v 1.1 2010/01/05 07:13:54 pva Exp $

inherit flag-o-matic eutils multilib toolchain-funcs mono libtool

DESCRIPTION="GNU locale utilities"
HOMEPAGE="http://www.gnu.org/software/gettext/gettext.html"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"

LICENSE="GPL-3 LGPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
IUSE="acl doc emacs nls nocxx openmp"

DEPEND="virtual/libiconv
	dev-libs/libxml2
	sys-libs/ncurses
	dev-libs/expat
	acl? ( virtual/acl )"
PDEPEND="emacs? ( app-emacs/po-mode )"

src_unpack() {
	unpack ${A}
	cd "${S}"

	epunt_cxx

	epatch "${FILESDIR}"/${PN}-0.14.1-lib-path-tests.patch #81628
	epatch "${FILESDIR}"/${PN}-0.14.2-fix-race.patch #85054
	epatch "${FILESDIR}"/${PN}-0.15-expat-no-dlopen.patch #146211
	epatch "${FILESDIR}"/${PN}-0.17-open-args.patch #232081
	epatch "${FILESDIR}"/${P}-gnuinfo.patch #249167
	epatch "${FILESDIR}"/${P}-x-python.patch #299658

	# bundled libtool seems to be broken so skip certain rpath tests
	# http://lists.gnu.org/archive/html/bug-libtool/2005-03/msg00070.html
	sed -i \
		-e '2iexit 77' \
		autoconf-lib-link/tests/rpath-3*[ef] || die "sed tests"

	# until upstream pulls a new gnulib/acl, we have to hack around it
	if ! use acl ; then
		eval export ac_cv_func_acl{,delete_def_file,extended_file,free,from_{mode,text},{g,s}et_{fd,file}}=no
		export ac_cv_header_acl_libacl_h=no
		export ac_cv_header_sys_acl_h=no
		export ac_cv_search_acl_get_file=no
		export gl_cv_func_working_acl_get_file=no
		sed -i -e 's:use_acl=1:use_acl=0:' gettext-tools/configure
	fi
}

src_compile() {
	local myconf=""
	# Build with --without-included-gettext (on glibc systems)
	if use elibc_glibc ; then
		myconf="${myconf} --without-included-gettext $(use_enable nls)"
	else
		myconf="${myconf} --with-included-gettext --enable-nls"
	fi
	use nocxx && export CXX=$(tc-getCC)

	# --without-emacs: Emacs support is now in a separate package
	# --with-included-glib: glib depends on us so avoid circular deps
	# --with-included-libcroco: libcroco depends on glib which ... ^^^
	econf \
		--docdir="/usr/share/doc/${PF}" \
		--without-emacs \
		--disable-java \
		--with-included-glib \
		--with-included-libcroco \
		$(use_enable openmp) \
		${myconf} \
		|| die
	emake || die
}

src_install() {
	emake install DESTDIR="${D}" || die "install failed"
	use nls || rm -r "${D}"/usr/share/locale
	dosym msgfmt /usr/bin/gmsgfmt #43435
	dobin gettext-tools/misc/gettextize || die "gettextize"

	# remove stuff that glibc handles
	if use elibc_glibc ; then
		rm -f "${D}"/usr/include/libintl.h
		rm -f "${D}"/usr/$(get_libdir)/libintl.*
	fi
	rm -f "${D}"/usr/share/locale/locale.alias "${D}"/usr/lib/charset.alias

	if [[ ${USERLAND} == "BSD" ]] ; then
		libname="libintl$(get_libname 8)"
		# Move dynamic libs and creates ldscripts into /usr/lib
		dodir /$(get_libdir)
		mv "${D}"/usr/$(get_libdir)/${libname}* "${D}"/$(get_libdir)/
		gen_usr_ldscript ${libname}
	fi

	if use doc ; then
		dohtml "${D}"/usr/share/doc/${PF}/*.html
	else
		rm -rf "${D}"/usr/share/doc/${PF}/{csharpdoc,examples,javadoc2,javadoc1}
	fi
	rm -f "${D}"/usr/share/doc/${PF}/*.html

	dodoc AUTHORS ChangeLog NEWS README THANKS
}

pkg_preinst() {
	# older gettext's sometimes installed libintl ...
	# need to keep the linked version or the system
	# could die (things like sed link against it :/)
	preserve_old_lib /{,usr/}$(get_libdir)/libintl$(get_libname 7)
}

pkg_postinst() {
	preserve_old_lib_notify /{,usr/}$(get_libdir)/libintl$(get_libname 7)
}