[gentoo-commits] repo/gentoo:master commit in: dev-libs/libslz/

[David Seifert]

commit:     45ba33c205f0b6446a6c827bf746917147423f68
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Fri Sep  9 07:58:59 2022 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Fri Sep  9 07:58:59 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=45ba33c2

dev-libs/libslz: drop multilib, static-libs, EAPI 8

No multilib or static-libs reverse dependencies.

Signed-off-by: Sam James <sam <AT> gentoo.org>
Signed-off-by: David Seifert <soap <AT> gentoo.org>

 dev-libs/libslz/libslz-1.2.0-r1.ebuild | 44 +++++++++++++++++++++++
 dev-libs/libslz/libslz-1.2.0.ebuild    | 65 ----------------------------------
 2 files changed, 44 insertions(+), 65 deletions(-)

diff --git a/dev-libs/libslz/libslz-1.2.0-r1.ebuild b/dev-libs/libslz/libslz-1.2.0-r1.ebuild
new file mode 100644
index 000000000000..8fff4fd6f227
--- /dev/null
+++ b/dev-libs/libslz/libslz-1.2.0-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Stateless, zlib-compatible, and very fast compression library"
+HOMEPAGE="http://1wt.eu/projects/libslz"
+SRC_URI="http://git.1wt.eu/web?p=${PN}.git;a=snapshot;h=v${PV};sf=tbz2 -> ${P}.tar.bz2"
+S="${WORKDIR}/${PN}"
+
+LICENSE="MIT"
+SLOT="0/1"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~x86"
+IUSE="tools"
+
+src_compile() {
+	local opts=(
+		CC="$(tc-getCC)"
+		OPT_CFLAGS="${CFLAGS}"
+		USR_LFLAGS="${LDFLAGS}"
+		shared
+		$(usev tools)
+	)
+
+	emake "${opts[@]}"
+}
+
+src_install() {
+	local opts=(
+		STRIP=":"
+		DESTDIR="${D}"
+		PREFIX="${EPREFIX}/usr"
+		LIBDIR="${EPREFIX}/usr/$(get_libdir)"
+		install-headers
+		install-shared
+		$(usev tools install-tools)
+	)
+
+	einstalldocs
+
+	emake "${opts[@]}"
+}

diff --git a/dev-libs/libslz/libslz-1.2.0.ebuild b/dev-libs/libslz/libslz-1.2.0.ebuild
deleted file mode 100644
index be90a23d2bc6..000000000000
--- a/dev-libs/libslz/libslz-1.2.0.ebuild
+++ /dev/null
@@ -1,65 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-inherit toolchain-funcs multilib-minimal
-
-DESCRIPTION="stateless, zlib-compatible, and very fast compression library"
-HOMEPAGE="http://1wt.eu/projects/libslz"
-SRC_URI="http://git.1wt.eu/web?p=${PN}.git;a=snapshot;h=v${PV};sf=tbz2 -> ${P}.tar.bz2"
-
-LICENSE="MIT"
-SLOT="0/1"
-KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~x86"
-IUSE="static-libs tools"
-
-DEPEND=""
-RDEPEND="${DEPEND}"
-
-S="${WORKDIR}/${PN}"
-
-src_prepare() {
-	default
-
-	multilib_copy_sources
-}
-
-multilib_src_compile() {
-	local -a opts=(
-		CC="$(tc-getCC)" \
-		OPT_CFLAGS="${CFLAGS}" \
-		USR_LFLAGS="${LDFLAGS}" \
-		shared \
-		$(usex static-libs static '')
-	)
-
-	if multilib_is_native_abi ; then
-		opts+=(
-			$(usex tools tools '')
-		)
-	fi
-
-	emake "${opts[@]}"
-}
-
-multilib_src_install() {
-	local -a opts=(
-		STRIP=":" \
-		DESTDIR="${ED}" \
-		PREFIX="${EPREFIX}/usr" \
-		LIBDIR="${EPREFIX}/usr/$(get_libdir)" \
-		install-headers
-		install-shared \
-		$(usex static-libs install-static '')
-	)
-
-	if multilib_is_native_abi ; then
-		einstalldocs
-
-		opts+=(
-			$(usex tools install-tools '')
-		)
-	fi
-
-	emake "${opts[@]}"
-}