[gentoo-commits] gentoo-x86 commit in app-portage/layman: layman-9999.ebuild ChangeLog

[Sebastian Pipping (sping)]

sping       09/12/29 00:29:41

  Modified:             ChangeLog
  Added:                layman-9999.ebuild
  Log:
  app-portage/layman: Add live ebuild
  (Portage version: 2.2_rc61/cvs/Linux i686)

Revision  Changes    Path
1.80                 app-portage/layman/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/layman/ChangeLog?rev=1.80&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/layman/ChangeLog?rev=1.80&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/layman/ChangeLog?r1=1.79&r2=1.80

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-portage/layman/ChangeLog,v
retrieving revision 1.79
retrieving revision 1.80
diff -u -r1.79 -r1.80
--- ChangeLog	5 Dec 2009 00:44:07 -0000	1.79
+++ ChangeLog	29 Dec 2009 00:29:40 -0000	1.80
@@ -1,6 +1,11 @@
 # ChangeLog for app-portage/layman
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-portage/layman/ChangeLog,v 1.79 2009/12/05 00:44:07 arfrever Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-portage/layman/ChangeLog,v 1.80 2009/12/29 00:29:40 sping Exp $
+
+*layman-9999 (29 Dec 2009)
+
+  29 Dec 2009; Sebastian Pipping <sping@g.o> +layman-9999.ebuild:
+  Add live ebuild
 
   05 Dec 2009; Arfrever Frehtes Taifersar Arahesis <arfrever@g.o>
   layman-1.2.4.ebuild:



1.1                  app-portage/layman/layman-9999.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/layman/layman-9999.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/layman/layman-9999.ebuild?rev=1.1&content-type=text/plain

Index: layman-9999.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-portage/layman/layman-9999.ebuild,v 1.1 2009/12/29 00:29:40 sping Exp $

EAPI="2"
SUPPORT_PYTHON_ABIS="1"

inherit eutils distutils git

DESCRIPTION="A python script for retrieving gentoo overlays."
HOMEPAGE="http://layman.sourceforge.net"
SRC_URI=""
EGIT_REPO_URI="git://layman.git.sourceforge.net/gitroot/layman/layman"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="git subversion test"

DEPEND="dev-python/pyxml
	test? ( dev-util/subversion )
	app-text/xmlto"
RDEPEND=">=dev-lang/python-2.5
	git? ( dev-util/git )
	subversion? (
		|| (
			>=dev-util/subversion-1.5.4[webdav-neon]
			>=dev-util/subversion-1.5.4[webdav-serf]
		)
	)"
RESTRICT_PYTHON_ABIS="2.4 3.*"

pkg_setup() {
	if ! has_version dev-util/subversion; then
		ewarn "You do not have dev-util/subversion installed!"
		ewarn "While layman does not exactly depend on this"
		ewarn "version control system you should note that"
		ewarn "most available overlays are offered via"
		ewarn "dev-util/subversion. If you do not install it"
		ewarn "you will be unable to use these overlays."
		ewarn
	fi
}

src_test() {
	testing() {
		PYTHONPATH="." "$(PYTHON)" layman/tests/dtest.py
	}
	python_execute_function testing
}

src_compile() {
	distutils_src_compile
	emake -C doc || die "emake -C doc failed"
}

src_install() {
	distutils_src_install

	dodir /etc/layman

	cp etc/layman.cfg "${D}"/etc/layman/

	doman doc/layman.8
	dohtml doc/layman.8.html

	keepdir /usr/local/portage/layman
}

pkg_postinst() {
	distutils_pkg_postinst

	einfo "You are now ready to add overlays into your system."
	einfo
	einfo "layman -L"
	einfo
	einfo "will display a list of available overlays."
	einfo
	elog  "Select an overlay and add it using"
	einfo
	elog  "layman -a overlay-name"
	einfo
	elog  "If this is the very first overlay you add with layman,"
	elog  "you need to append the following statement to your"
	elog  "/etc/make.conf file:"
	elog
	elog  "source /usr/local/portage/layman/make.conf"
	elog
	elog  "If you modify the 'storage' parameter in the layman"
	elog  "configuration file (/etc/layman/layman.cfg) you will"
	elog  "need to adapt the path given above to the new storage"
	elog  "directory."
	einfo
	ewarn "Please add the 'source' statement to make.conf only AFTER "
	ewarn "you added your first overlay. Otherwise portage will fail."
	epause 5
}