[gentoo-commits] gentoo-x86 commit in media-video/makemkv: ChangeLog makemkv-1.7.4-r1.ebuild makemkv-1.6.16.ebuild

[Matthew Marlow (mattm)]

mattm       12/07/02 03:46:19

  Modified:             ChangeLog
  Added:                makemkv-1.7.4-r1.ebuild
  Removed:              makemkv-1.6.16.ebuild
  Log:
  Per request from Bug 396253, took over maintainership of media-video/makemkv.  Bumped to latest user contributed ebuild. Verified dependencies and installation/operation, supplemented basic elog install directions, and removed obsolete/non functional prior ebuild.
  
  (Portage version: 2.1.10.65/cvs/Linux x86_64)

Revision  Changes    Path
1.5                  media-video/makemkv/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/makemkv/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/makemkv/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/makemkv/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/makemkv/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	1 Jul 2012 05:49:46 -0000	1.4
+++ ChangeLog	2 Jul 2012 03:46:19 -0000	1.5
@@ -1,6 +1,15 @@
 # ChangeLog for media-video/makemkv
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/makemkv/ChangeLog,v 1.4 2012/07/01 05:49:46 yngwin Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/makemkv/ChangeLog,v 1.5 2012/07/02 03:46:19 mattm Exp $
+
+*makemkv-1.7.4-r1 (02 Jul 2012)
+
+  02 Jul 2012; Matthew Marlowe <mattm@g.o> -makemkv-1.6.16.ebuild,
+  +makemkv-1.7.4-r1.ebuild, +files/makemkv-1.7.4-makefile.linux.patch:
+  Per request from Bug 396253, took over maintainership of media-video/makemkv.
+  Bumped to latest user contributed ebuild. Verified dependencies and
+  installation/operation, supplemented basic elog install directions, and
+  removed obsolete/non functional prior ebuild.
 
   01 Jul 2012; Ben de Groot <yngwin@g.o> metadata.xml:
   Reassign as per bug #396253



1.1                  media-video/makemkv/makemkv-1.7.4-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/makemkv/makemkv-1.7.4-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/makemkv/makemkv-1.7.4-r1.ebuild?rev=1.1&content-type=text/plain

Index: makemkv-1.7.4-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/makemkv/makemkv-1.7.4-r1.ebuild,v 1.1 2012/07/02 03:46:19 mattm Exp $

EAPI=3

RESTRICT="mirror"

inherit multilib eutils

MY_P="makemkv_v${PV}_oss"
MY_PB="makemkv_v${PV}_bin"

DESCRIPTION="Tool for ripping Blu-Ray, HD-DVD and DVD discs and copying content to a Matroska container"
HOMEPAGE="http://www.makemkv.com/"
SRC_URI="http://www.makemkv.com/download/${MY_P}.tar.gz
	http://www.makemkv.com/download/${MY_PB}.tar.gz"

LICENSE="MakeMKV-EULA"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND="x11-libs/qt-gui:4
	dev-libs/openssl:0
	media-libs/mesa
	dev-libs/expat
	x11-libs/qt-dbus:4
	sys-libs/zlib"
RDEPEND="${DEPEND}"

QA_PREBUILT="opt/bin/makemkvcon"
DEFAULT_PROFILE="default.mmcp.xml"

src_prepare() {
	epatch "${FILESDIR}/${P}-makefile.linux.patch"
	cd "${MY_P}"
}

src_compile() {
	cd "${MY_P}"
	emake GCC="$(tc-getCC) ${CFLAGS} ${LDFLAGS}" -f makefile.linux || die "make failed"
}

src_install() {
	# install oss package
	cd "${MY_P}"
	dolib.so out/libdriveio.so.0 || die "dolib.so out/libdriveio.so.0 died"
	dolib.so out/libmakemkv.so.1 || die "dolib.so out/libmakemkv.so.1 died"
	dosym libdriveio.so.0 /usr/$(get_libdir)/libdriveio.so.0.${PV} || die "dosym libdriveio.so.0 died "
	dosym libdriveio.so.0 /usr/$(get_libdir)/libdriveio.so || die "dosym libdriveio.so.0 died "
	dosym libmakemkv.so.1 /usr/$(get_libdir)/libmakemkv.so.1.${PV} || die "dosym libmakemkv.so.1 died"
	dosym libmakemkv.so.1 /usr/$(get_libdir)/libmakemkv.so || die "dosym libmakemkv.so.1 died"
	into /opt
	dobin out/makemkv || die "dobin makemkv died"

	newicon makemkvgui/src/img/128/mkv_icon.png ${PN}.png
	make_desktop_entry ${PN} "MakeMKV" ${PN} "Qt;AudioVideo;Video"

	# install bin package
	cd "${WORKDIR}/${MY_PB}/bin"
	if use x86; then
		dobin i386/makemkvcon || die "dobin makemkvcon died"
	elif use amd64; then
		dobin amd64/makemkvcon || die "dobin makemkvcon died"
	fi

	# install license and default profile
	cd "${WORKDIR}/${MY_PB}/src"
	into /usr
	dodoc eula_en_linux.txt
	insinto /usr/share/${PF}
	doins share/${DEFAULT_PROFILE}
}

pkg_postinst() {
	elog "While MakeMKV is in beta mode, upstream has provided a license"
	elog "to use if you do not want to purchase one."
	elog ""
	elog "See this forum thread for more information, including the key:"
	elog "http://www.makemkv.com/forum2/viewtopic.php?f=5&t=1053"
	elog ""
	elog "Note that beta license may have an expiration date and you will"
	elog "need to check for newer licenses/releases. "
	elog ""
	elog "If this is a new install, remember to copy the default profile"
	elog "to the config directory:"
	elog "cp /usr/share/${PF}/${DEFAULT_PROFILE} ~/.MakeMKV/${DEFAULT_PROFILE}"
}