[gentoo-commits] gentoo-x86 commit in dev-python/flask-cors: flask-cors-1.9.0.ebuild ChangeLog

[Ian Delaney (idella4)]

idella4     14/09/23 14:10:01

  Modified:             ChangeLog
  Added:                flask-cors-1.9.0.ebuild
  Log:
  bump; re-addition of inital doc build and a viable test phase subsequent to pull requests submitted by wking and accepted by upstream
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

Revision  Changes    Path
1.3                  dev-python/flask-cors/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/flask-cors/ChangeLog?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/flask-cors/ChangeLog?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/flask-cors/ChangeLog?r1=1.2&r2=1.3

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/flask-cors/ChangeLog,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- ChangeLog	14 Sep 2014 18:26:54 -0000	1.2
+++ ChangeLog	23 Sep 2014 14:10:01 -0000	1.3
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/flask-cors
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/flask-cors/ChangeLog,v 1.2 2014/09/14 18:26:54 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/flask-cors/ChangeLog,v 1.3 2014/09/23 14:10:01 idella4 Exp $
+
+*flask-cors-1.9.0 (23 Sep 2014)
+
+  23 Sep 2014; Ian Delaney <idella4@g.o> +flask-cors-1.9.0.ebuild:
+  bump; re-addition of inital doc build and a viable test phase subsequent to
+  pull requests submitted by wking and accepted by upstream
 
   14 Sep 2014; Mike Gilbert <floppym@g.o> flask-cors-1.8.0.ebuild:
   Drop docs build until a more reasonable solution can be found. Acknowledged by



1.1                  dev-python/flask-cors/flask-cors-1.9.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/flask-cors/flask-cors-1.9.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/flask-cors/flask-cors-1.9.0.ebuild?rev=1.1&content-type=text/plain

Index: flask-cors-1.9.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/flask-cors/flask-cors-1.9.0.ebuild,v 1.1 2014/09/23 14:10:01 idella4 Exp $

EAPI=5
PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )

inherit distutils-r1

MY_PN="Flask-Cors"
MY_P="${MY_PN}-${PV}"

if [[ "${PV}" == "9999" ]]; then
	inherit git-2
	EGIT_REPO_URI="git://github.com/wcdolphin/${PN}.git"
	SRC_URI=""
else
	SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz -> ${P}.tar.gz"
fi

DESCRIPTION="A Flask extension for Cross Origin Resource Sharing (CORS)"
HOMEPAGE="https://github.com/wcdolphin/flask-cors https://pypi.python.org/pypi/Flask-Cors"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc test"

RDEPEND="dev-python/flask[${PYTHON_USEDEP}]
	dev-python/six[${PYTHON_USEDEP}]"
DEPEND="
	dev-python/setuptools[${PYTHON_USEDEP}]
	doc? (
		${RDEPEND}
		>=dev-python/python-docs-2.7.6-r1:2.7
		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
	)
	test? (
		${RDEPEND}
		dev-python/nose[${PYTHON_USEDEP}]
	)"

S="${WORKDIR}/${MY_P}"

python_prepare_all() {
	if use doc; then
		local PYTHON_DOC_ATOM=$(best_version --host-root dev-python/python-docs:2.7)
		local PYTHON_DOC_VERSION="${PYTHON_DOC_ATOM#dev-python/python-docs-}"
		local PYTHON_DOC="/usr/share/doc/python-docs-${PYTHON_DOC_VERSION}/html"
		local PYTHON_DOC_INVENTORY="${PYTHON_DOC}/objects.inv"
		sed -i "s|'http://docs.python.org/': None|'${PYTHON_DOC}': '${PYTHON_DOC_INVENTORY}'|" docs/conf.py || die
	fi
	distutils-r1_python_prepare_all
}

python_compile_all() {
	use doc && emake -C docs html
}

python_test() {
	esetup.py test
}

python_install_all() {
	use doc && local HTML_DOCS=( docs/_build/html/. )

	distutils-r1_python_install_all
}