[gentoo-commits] gentoo-x86 commit in sys-libs/freeipmi: freeipmi-1.3.3.ebuild ChangeLog freeipmi-1.3.2.ebuild freeipmi-1.2.9.ebuild freeipmi-1.3.1.ebuild freeipmi-1.2.8.ebuild

[Diego Petteno (flameeyes)]

flameeyes    13/12/02 21:50:42

  Modified:             ChangeLog
  Added:                freeipmi-1.3.3.ebuild
  Removed:              freeipmi-1.3.2.ebuild freeipmi-1.2.9.ebuild
                        freeipmi-1.3.1.ebuild freeipmi-1.2.8.ebuild
  Log:
  Version bump and remove old.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 1CD13C8AD4301342)

Revision  Changes    Path
1.78                 sys-libs/freeipmi/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/freeipmi/ChangeLog?rev=1.78&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/freeipmi/ChangeLog?rev=1.78&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/freeipmi/ChangeLog?r1=1.77&r2=1.78

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/freeipmi/ChangeLog,v
retrieving revision 1.77
retrieving revision 1.78
diff -u -r1.77 -r1.78
--- ChangeLog	12 Sep 2013 07:32:40 -0000	1.77
+++ ChangeLog	2 Dec 2013 21:50:42 -0000	1.78
@@ -1,6 +1,13 @@
 # ChangeLog for sys-libs/freeipmi
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/freeipmi/ChangeLog,v 1.77 2013/09/12 07:32:40 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/freeipmi/ChangeLog,v 1.78 2013/12/02 21:50:42 flameeyes Exp $
+
+*freeipmi-1.3.3 (02 Dec 2013)
+
+  02 Dec 2013; Diego E. Pettenò <flameeyes@g.o> +freeipmi-1.3.3.ebuild,
+  -freeipmi-1.2.8.ebuild, -freeipmi-1.2.9.ebuild, -freeipmi-1.3.1.ebuild,
+  -freeipmi-1.3.2.ebuild:
+  Version bump and remove old.
 
 *freeipmi-1.3.2 (12 Sep 2013)
 



1.1                  sys-libs/freeipmi/freeipmi-1.3.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/freeipmi/freeipmi-1.3.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/freeipmi/freeipmi-1.3.3.ebuild?rev=1.1&content-type=text/plain

Index: freeipmi-1.3.3.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-libs/freeipmi/freeipmi-1.3.3.ebuild,v 1.1 2013/12/02 21:50:42 flameeyes Exp $

EAPI=5

inherit autotools eutils multilib autotools-utils

DESCRIPTION="Provides Remote-Console and System Management Software as per IPMI v1.5/2.0"
HOMEPAGE="http://www.gnu.org/software/freeipmi/"

MY_P="${P/_/.}"
S="${WORKDIR}"/${MY_P}
[[ ${MY_P} == *.beta* ]] && ALPHA="-alpha"
SRC_URI="mirror://gnu${ALPHA}/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug nagios"

RDEPEND="dev-libs/libgcrypt"
DEPEND="${RDEPEND}
		virtual/os-headers"
RDEPEND="${RDEPEND}
	nagios? (
		|| ( net-analyzer/icinga net-analyzer/nagios )
		dev-lang/perl
	)
	sys-apps/openrc"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-1.1.1-strictaliasing.patch

	AT_M4DIR="config" eautoreconf
}

src_configure() {
	local myeconfargs=(
		$(use_enable debug)
		--disable-static
		--disable-init-scripts
		--localstatedir=/var
	)

	autotools-utils_src_configure
}

# There are no tests
src_test() { :; }

src_install() {
	autotools-utils_src_install

	# freeipmi by defaults install _all_ commands to /usr/sbin, but
	# quite a few can be run remotely as standard user, so move them
	# in /usr/bin afterwards.
	dodir /usr/bin
	for file in ipmi{detect,ping,power,console}; do
		mv "${D}"/usr/{s,}bin/${file} || die

		# The default install symlinks these commands to add a dash
		# after the ipmi prefix; we repeat those after move for
		# consistency.
		rm "${D}"/usr/sbin/${file/ipmi/ipmi-}
		dosym ${file} /usr/bin/${file/ipmi/ipmi-}
	done

	# Install the nagios plugin in its proper place, if desired
	if use nagios; then
		dodir /usr/$(get_libdir)/nagios/plugins
		mv "${D}"/usr/share/doc/${PF}/contrib/nagios/nagios_ipmi_sensors.pl \
			"${D}"/usr/$(get_libdir)/nagios/plugins/ || die
		fperms 0755 /usr/$(get_libdir)/nagios/plugins/nagios_ipmi_sensors.pl

		insinto /etc/icinga/conf.d
		newins "${FILESDIR}"/freeipmi.icinga freeipmi-command.cfg
	fi

	dodoc AUTHORS ChangeLog* DISCLAIMER* NEWS README* TODO doc/*.txt

	keepdir \
		/var/cache/ipmimonitoringsdrcache \
		/var/lib/freeipmi \
		/var/log/ipmiconsole

	# starting from version 1.2.0 the two daemons are similar enough
	newinitd "${FILESDIR}"/bmc-watchdog.initd.4 ipmidetectd
	newconfd "${FILESDIR}"/ipmidetectd.confd ipmidetectd

	newinitd "${FILESDIR}"/bmc-watchdog.initd.4 bmc-watchdog
	newconfd "${FILESDIR}"/bmc-watchdog.confd bmc-watchdog

	newinitd "${FILESDIR}"/bmc-watchdog.initd.4 ipmiseld
	newconfd "${FILESDIR}"/ipmiseld.confd ipmiseld
}