[gentoo-commits] gentoo-x86 commit in net-misc/netctl: netctl-1.3.ebuild ChangeLog

[Mike Gilbert (floppym)]

floppym     13/09/28 16:00:31

  Modified:             ChangeLog
  Added:                netctl-1.3.ebuild
  Log:
  Bump.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

Revision  Changes    Path
1.13                 net-misc/netctl/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/netctl/ChangeLog?rev=1.13&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/netctl/ChangeLog?rev=1.13&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/netctl/ChangeLog?r1=1.12&r2=1.13

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/netctl/ChangeLog,v
retrieving revision 1.12
retrieving revision 1.13
diff -u -r1.12 -r1.13
--- ChangeLog	2 Aug 2013 16:26:09 -0000	1.12
+++ ChangeLog	28 Sep 2013 16:00:31 -0000	1.13
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/netctl
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/netctl/ChangeLog,v 1.12 2013/08/02 16:26:09 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/netctl/ChangeLog,v 1.13 2013/09/28 16:00:31 floppym Exp $
+
+*netctl-1.3 (28 Sep 2013)
+
+  28 Sep 2013; Mike Gilbert <floppym@g.o> +netctl-1.3.ebuild:
+  Bump.
 
 *netctl-1.2 (02 Aug 2013)
 



1.1                  net-misc/netctl/netctl-1.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/netctl/netctl-1.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/netctl/netctl-1.3.ebuild?rev=1.1&content-type=text/plain

Index: netctl-1.3.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/netctl/netctl-1.3.ebuild,v 1.1 2013/09/28 16:00:31 floppym Exp $

EAPI=5

inherit bash-completion-r1

if [[ ${PV} = *9999* ]]; then
	EGIT_REPO_URI="git://projects.archlinux.org/netctl.git"
	inherit git-2
	DEPEND="app-text/asciidoc"
else
	SRC_URI="ftp://ftp.archlinux.org/other/packages/${PN}/${P}.tar.xz"
	KEYWORDS="~amd64 ~x86"
fi

DESCRIPTION="Profile based network connection tool from Arch Linux"
HOMEPAGE="https://wiki.archlinux.org/index.php/Netctl
	https://www.archlinux.org/packages/core/any/netctl/
	https://projects.archlinux.org/netctl.git/"
LICENSE="BSD"
SLOT="0"
IUSE=""

DEPEND+="
	virtual/pkgconfig
	sys-apps/systemd
"
RDEPEND="
	>=app-shells/bash-4.0
	>=net-dns/openresolv-3.5.4-r1
	sys-apps/iproute2
	sys-apps/systemd
	!<net-misc/dhcpcd-5.6.7
"

src_prepare() {
	sed -i -e "s:/usr/bin/ifplugd:/usr/sbin/ifplugd:" \
		"services/netctl-ifplugd@.service" || die
}

src_compile() {
	return 0
}

src_install() {
	emake DESTDIR="${D%/}" SHELL=bash install
	dodoc AUTHORS NEWS README
	newbashcomp contrib/bash-completion netctl
	insinto /usr/share/zsh/site-functions
	newins contrib/zsh-completion _netctl
}

optfeature() {
	local desc=$1
	shift
	while (( $# )); do
		if has_version "$1"; then
			elog "  [I] $1 for ${desc}"
		else
			elog "  [ ] $1 for ${desc}"
		fi
		shift
	done
}

pkg_postinst() {
	if [[ -z ${REPLACING_VERSIONS} ]]; then
		elog "To get additional features, a number of optional runtime dependencies may be"
		elog "installed."
		optfeature "DHCP support" net-misc/dhcpcd ">=net-misc/dhcp-5.6.7[client]"
		optfeature "WPA support" net-wireless/wpa_supplicant
		optfeature "interactive assistant" dev-util/dialog
		optfeature "automatic connection" sys-apps/ifplugd
		optfeature "bonding support" net-misc/ifenslave
		optfeature "dialup support" net-dialup/ppp
	fi
}