[gentoo-commits] gentoo-x86 commit in dev-db/phpmyadmin: phpmyadmin-4.4.12.ebuild ChangeLog

[Jorge Manuel B. S. Vicetto (jmbsvicetto)]

jmbsvicetto    15/07/23 02:30:18

  Modified:             ChangeLog
  Added:                phpmyadmin-4.4.12.ebuild
  Log:
  Bump to the 4.4.12 release - bug 555142. Update HOMEPAGE and SRC_URI.
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key BB0E6E98)

Revision  Changes    Path
1.569                dev-db/phpmyadmin/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/phpmyadmin/ChangeLog?rev=1.569&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/phpmyadmin/ChangeLog?rev=1.569&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/phpmyadmin/ChangeLog?r1=1.568&r2=1.569

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-db/phpmyadmin/ChangeLog,v
retrieving revision 1.568
retrieving revision 1.569
diff -u -r1.568 -r1.569
--- ChangeLog	17 Jul 2015 16:40:24 -0000	1.568
+++ ChangeLog	23 Jul 2015 02:30:18 -0000	1.569
@@ -1,6 +1,12 @@
 # ChangeLog for dev-db/phpmyadmin
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-db/phpmyadmin/ChangeLog,v 1.568 2015/07/17 16:40:24 klausman Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-db/phpmyadmin/ChangeLog,v 1.569 2015/07/23 02:30:18 jmbsvicetto Exp $
+
+*phpmyadmin-4.4.12 (23 Jul 2015)
+
+  23 Jul 2015; Jorge Manuel B. S. Vicetto <jmbsvicetto@g.o>
+  +phpmyadmin-4.4.12.ebuild:
+  Bump to the 4.4.12 release - bug 555142. Update HOMEPAGE and SRC_URI.
 
   17 Jul 2015; Tobias Klausmann <klausman@g.o>
   phpmyadmin-4.4.6.1.ebuild:



1.1                  dev-db/phpmyadmin/phpmyadmin-4.4.12.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/phpmyadmin/phpmyadmin-4.4.12.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/phpmyadmin/phpmyadmin-4.4.12.ebuild?rev=1.1&content-type=text/plain

Index: phpmyadmin-4.4.12.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/phpmyadmin/phpmyadmin-4.4.12.ebuild,v 1.1 2015/07/23 02:30:18 jmbsvicetto Exp $

EAPI="5"

inherit eutils webapp

MY_PV=${PV/_/-}
MY_PN="phpMyAdmin"
MY_P="${MY_PN}-${MY_PV}-all-languages"

DESCRIPTION="Web-based administration for MySQL database in PHP"
HOMEPAGE="https://www.phpmyadmin.net/"
SRC_URI="https://files.phpmyadmin.net/${MY_PN}/${MY_PV}/${MY_P}.zip"

LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~ppc-macos ~x64-macos ~x86-macos"
IUSE="setup"

RDEPEND="
	dev-lang/php[crypt,ctype,filter,json,session,unicode]
	|| (
		dev-lang/php[mysqli]
		dev-lang/php[mysql]
	)
	virtual/httpd-php:*
"

need_httpd_cgi

S="${WORKDIR}"/${MY_P}

pkg_setup() {
	webapp_pkg_setup
}

src_install() {
	webapp_src_preinst

	dodoc README RELEASE-DATE-${MY_PV} ChangeLog || die
	rm -f LICENSE README* RELEASE-DATE-${MY_PV}

	if ! use setup; then
		rm -rf setup || die "Cannot remove setup utility"
		elog "The phpMyAdmin setup utility has been removed."
		elog "It is a regular target of various exploits. If you need it, set USE=setup."
	else
		elog "You should consider disabling the setup USE flag"
		elog "to exclude the setup utility if you don't use it."
		elog "It regularly is the target of various exploits."
	fi

	insinto "${MY_HTDOCSDIR#${EPREFIX}}"
	doins -r .

	webapp_configfile "${MY_HTDOCSDIR#${EPREFIX}}"/libraries/config.default.php
	webapp_serverowned "${MY_HTDOCSDIR#${EPREFIX}}"/libraries/config.default.php

	webapp_postinst_txt en "${FILESDIR}"/postinstall-en-3.1.txt
	webapp_src_install
}