[gentoo-commits] repo/gentoo:master commit in: www-client/opera-developer/

[Stephan Hartmann]

commit:     6a0d43fade96760ebca7a3028565253de6dc6fa5
Author:     Stephan Hartmann <sultan <AT> gentoo <DOT> org>
AuthorDate: Wed Sep  1 21:09:08 2021 +0000
Commit:     Stephan Hartmann <sultan <AT> gentoo <DOT> org>
CommitDate: Wed Sep  1 21:09:32 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6a0d43fa

www-client/opera-developer: bump to 80.0.4162.0

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Stephan Hartmann <sultan <AT> gentoo.org>

 www-client/opera-developer/Manifest                |   1 +
 .../opera-developer-80.0.4162.0.ebuild             | 157 +++++++++++++++++++++
 2 files changed, 158 insertions(+)

diff --git a/www-client/opera-developer/Manifest b/www-client/opera-developer/Manifest
index c58fa792a98..2e0f9280c27 100644
--- a/www-client/opera-developer/Manifest
+++ b/www-client/opera-developer/Manifest
@@ -1,6 +1,7 @@
 DIST opera-developer_79.0.4142.0_amd64.deb 77573852 BLAKE2B 1195809dc53f593350636168828fd43b45648059dbc752d203704b78a33629ec326005a696328c3a433f06cb8b74f42fc7a67d15d2ee87b9e3cba70936b37ecc SHA512 3a91e85fc045ad8d4e4a4c98d045a4cda85aaf9c5e238d1b99546cd26166712d4652c263dcc0af314913974fc139495ff0c45f741ee2048aa5d947413b573dab
 DIST opera-developer_80.0.4150.0_amd64.rpm 76215956 BLAKE2B 443b86a84615c9b7412baf929138703d9c0a8b52e9b82a23c36c927cd2594e19e1713a4062c945054def4e9b3702b2b6a40c1fa23e9b38722dd8e93cf5db1174 SHA512 2021cc6d1b6cec5801baf1973fabbe6643bfcae437792c38f98c4753e9c16787f49c07079ed68f3820e277013c179f3690bd5c7a0be8ab8d03aae7c2c7243e6c
 DIST opera-developer_80.0.4157.0_amd64.deb 79823544 BLAKE2B e39570f48b85efe5dfed9eee765964b876ab6d7b824b012132ac344cd863fe3396dda705b188123822fde0ba37784df65b3f05d1cebdfa6433bc640c942ad88d SHA512 441de56f3863044091e87849a36b31dda7385971322e31b99e66664a26ba744d38b83fe986c23d10d9cfc3997f8951d7f61dcc901b30bf742f30cb3650e3b2c2
+DIST opera-developer_80.0.4162.0_amd64.deb 79608536 BLAKE2B 23900af1f692c650b71cfe3f4f1b94c5e9ef9c8f161657596763e5bb75b1a1ad0c1fa98cd95002e73831661800f512527ca7bef6452fba83fea82f27c6b82552 SHA512 79a365ca877826ae795e7bd05b3fcc8478fd45048cb0831d7a03de1545632eaf8c9210f0fd908670ec4306c173cfc91e2cb299afa5aa159f3632aeac06f8213a
 DIST opera-ffmpeg-codecs-93.0.4573.0.tar.xz 1389664 BLAKE2B 4efc7341655bed294d4c6237dd9e7d005a815c495a45bec6f0b7fcbec40345e22ad5199ec1db3c822c123663d3ce95e6b87af18b1ac6cad31793ae7fdb440918 SHA512 f7c62c6860d1440e91344c41d6c9b3fbef4745cb95262538dcb3af9147406b3b0c71e72605042c423cbdd618a53f902791bcb6b7fcc8a4cae92ebf3cb38e8407
 DIST opera-ffmpeg-codecs-94.0.4590.0.tar.xz 1388672 BLAKE2B 736debcdbdfa63f0e5afa3bca70783aadaad5db5751666099ff290b8bde1ba1ef8ab12612a5dc2f4db3ba3b79ed7bdd7b6091480639578c9610058d2dc3584fd SHA512 c6fabd319b048b068f6763cf99406f4431c22311cb14159af673ee4b8f39a3f4376cb299746de9e797ee1965dde1f597ef5a733c5fcf8e527ce59964c85921dd
 DIST opera-ffmpeg-codecs-94.0.4603.0.tar.xz 1388572 BLAKE2B 55a598883dfbab598f48a662009ab02c4974a95ba023e3b2d36bdad3267ab4586cfd05891f83a96933b6b0b02dc1d2a496bb796ecb5421635a370f6c79c60a98 SHA512 dfeb7174ad5d696f78a86735462757d0245aecf0d00c21ba6ff3c16f6af586979457ebb23db228f3769cf09636ed70421aafe29eb622ca658e766dafc860827a

diff --git a/www-client/opera-developer/opera-developer-80.0.4162.0.ebuild b/www-client/opera-developer/opera-developer-80.0.4162.0.ebuild
new file mode 100644
index 00000000000..bf0853a5f75
--- /dev/null
+++ b/www-client/opera-developer/opera-developer-80.0.4162.0.ebuild
@@ -0,0 +1,157 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB en-US es-419 es fil fi fr-CA fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+
+# These are intended for ebuild maintainer use to force RPM if DEB is not available.
+: ${OPERA_FORCE_RPM=no}
+
+if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+	OPERA_UNPACKER="rpm"
+	OPERA_ARCHIVE_EXT="rpm"
+else
+	OPERA_UNPACKER="unpacker"
+	OPERA_ARCHIVE_EXT="deb"
+fi
+
+inherit chromium-2 multilib pax-utils ${OPERA_UNPACKER} xdg
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2018"
+SLOT="0"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN}"
+	"https://download2.operacdn.com/pub/${PN}"
+	"https://download3.operacdn.com/pub/${PN}"
+	"https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+	MY_PN=${PN}-stable
+	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+	MY_PN=${PN}
+fi
+
+KEYWORDS="-* ~amd64"
+
+FFMPEG_VERSION="94.0.4603.0"
+
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}
+	proprietary-codecs? (
+		mirror+https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
+	)"
+
+IUSE="+proprietary-codecs suid"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	app-accessibility/at-spi2-atk:2
+	app-accessibility/at-spi2-core:2
+	dev-libs/atk
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gsettings-desktop-schemas
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rpm_src_unpack "${A[0]}"
+	else
+		unpacker
+	fi
+
+	# move to /opt, bug #573052
+	mkdir -p "${OPERA_HOME%${PN}}"
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
+	else
+		mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+	fi
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rm "${OPERA_HOME}/setup_repo.sh" || die
+	else
+		rm -r "usr/share/lintian" || die
+
+		# fix docs
+		mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+		gzip -d usr/share/doc/${PF}/changelog.gz || die
+	fi
+
+	# fix desktop file
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		mv lib_extra "${OPERA_HOME}"
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "${OPERA_HOME}/opera_sandbox"
+}