[gentoo-commits] repo/gentoo:master commit in: dev-util/distro-info/

[Joonas Niilola]

commit:     de92217bfdd3fc69790f29381310e9f735c485de
Author:     Yuri Konotopov <ykonotopov <AT> gnome <DOT> org>
AuthorDate: Thu Feb 25 13:31:58 2021 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Mon Mar  1 08:25:56 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=de92217b

dev-util/distro-info: version bump to 1.0

Closes: https://bugs.gentoo.org/771939
Package-Manager: Portage-3.0.13, Repoman-3.0.2
Signed-off-by: Yuri Konotopov <ykonotopov <AT> gnome.org>
Closes: https://github.com/gentoo/gentoo/pull/19648
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 dev-util/distro-info/Manifest               |  1 +
 dev-util/distro-info/distro-info-1.0.ebuild | 94 +++++++++++++++++++++++++++++
 2 files changed, 95 insertions(+)

diff --git a/dev-util/distro-info/Manifest b/dev-util/distro-info/Manifest
index e289b24a1b0..1fb0882fe13 100644
--- a/dev-util/distro-info/Manifest
+++ b/dev-util/distro-info/Manifest
@@ -1 +1,2 @@
 DIST distro-info_0.22.tar.xz 29104 BLAKE2B 88eab833ea34de9e62f858e1fb9acfb94efb60114d2213b8bbb77a440c114dbac70a1707d1469113c1a98ea94d953ffa36480c132c294fd8e22b816a444b25e1 SHA512 b9d97e469b9173651c1816f39cc2315622b46f1579cbaba29c417a51417425e90a45283e83c7efee35db78621df08997f5395c8c1b0259f69e5cd91dee65793f
+DIST distro-info_1.0.tar.xz 30908 BLAKE2B 8355e54919d83d09d3eb7983a35151f0e4253c62eefeccf4d1e614cef0bb7cecf466007c7789749c145674aa30324423f9977a26695d5de537f80d5eb069f371 SHA512 2d84b5845ff4e7ce8059fe83e9d64a380d6732e0e85bc889c948068579d27a86fd31f8e6b7d8cc256f4ff4631cd0ffd480835bf290452d3bc28469f5b3be9ddb

diff --git a/dev-util/distro-info/distro-info-1.0.ebuild b/dev-util/distro-info/distro-info-1.0.ebuild
new file mode 100644
index 00000000000..424eef903fb
--- /dev/null
+++ b/dev-util/distro-info/distro-info-1.0.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8} )
+DISTUTILS_OPTIONAL=true
+
+inherit distutils-r1
+
+DESCRIPTION="Provides information about the Debian distributions' releases"
+HOMEPAGE="https://debian.org"
+SRC_URI="mirror://debian/pool/main/d/${PN}/${PN}_${PV}.tar.xz"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="python test"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+COMMON_DEPEND="dev-lang/perl:=
+	python? ( ${PYTHON_DEPS} )"
+DEPEND="${COMMON_DEPEND}
+	python? ( dev-python/setuptools[${PYTHON_USEDEP}] )
+	test? (
+		dev-util/shunit2
+		dev-python/pylint[${PYTHON_USEDEP}]
+	)"
+RDEPEND="${COMMON_DEPEND}
+	dev-util/distro-info-data"
+
+src_prepare() {
+	default
+
+	# 1. Gentoo do not provides dpkg vendor information
+	# 2. Strip *FLAGS
+	# 3. Strip predefined CFLAGS
+	# 4. Point to correct perl's vendorlib
+	# 5. Remove python tests - python eclass will be used instead
+	sed -e "/cd python && python/d" \
+		-e "/VENDOR/d" \
+		-e "/dpkg-buildflags/d" \
+		-e "s/-g -O2//g" \
+		-e "s:\$(PREFIX)/share/perl5/Debian:\$(PERL_VENDORLIB)/Debian:g" \
+		-e "/pyversions/d" \
+		-i "${S}"/Makefile || die
+}
+
+src_configure() {
+	default
+
+	if use python; then
+		pushd ./python > /dev/null || die
+		distutils-r1_src_configure
+		popd > /dev/null || die
+	fi
+}
+
+src_compile() {
+	default
+
+	if use python; then
+		pushd ./python > /dev/null || die
+		distutils-r1_src_compile
+		popd > /dev/null || die
+	fi
+}
+
+src_install() {
+	emake PERL_VENDORLIB=$(perl -e 'require Config; print "$Config::Config{'vendorlib'}\n";') \
+		DESTDIR="${D}" install
+
+	if use python; then
+		pushd ./python > /dev/null || die
+		distutils-r1_src_install
+		popd > /dev/null || die
+	fi
+}
+
+src_test() {
+	TZ=UTC default
+
+	if use python; then
+		python_test() {
+			esetup.py test
+		}
+
+		pushd ./python > /dev/null || die
+		distutils-r1_src_test
+		popd > /dev/null || die
+	fi
+}