[gentoo-commits] gentoo-x86 commit in dev-python/flask: flask-0.7.2.ebuild ChangeLog

[Dirkjan Ochtman (djc)]

djc         11/07/06 18:58:43

  Modified:             ChangeLog
  Added:                flask-0.7.2.ebuild
  Log:
  Version bump flask to 0.7.2.
  
  (Portage version: 2.1.10.4/cvs/Linux x86_64)

Revision  Changes    Path
1.8                  dev-python/flask/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/flask/ChangeLog?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/flask/ChangeLog?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/flask/ChangeLog?r1=1.7&r2=1.8

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/flask/ChangeLog,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- ChangeLog	12 Feb 2011 17:45:26 -0000	1.7
+++ ChangeLog	6 Jul 2011 18:58:42 -0000	1.8
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/flask
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/flask/ChangeLog,v 1.7 2011/02/12 17:45:26 arfrever Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/flask/ChangeLog,v 1.8 2011/07/06 18:58:42 djc Exp $
+
+*flask-0.7.2 (06 Jul 2011)
+
+  06 Jul 2011; Dirkjan Ochtman <djc@g.o> +flask-0.7.2.ebuild:
+  Version bump to 0.7.2.
 
   12 Feb 2011; Arfrever Frehtes Taifersar Arahesis <arfrever@g.o>
   flask-0.6.1.ebuild:



1.1                  dev-python/flask/flask-0.7.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/flask/flask-0.7.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/flask/flask-0.7.2.ebuild?rev=1.1&content-type=text/plain

Index: flask-0.7.2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/flask/flask-0.7.2.ebuild,v 1.1 2011/07/06 18:58:42 djc Exp $

EAPI="3"
PYTHON_DEPEND="2"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.*"

inherit distutils

MY_PN="Flask"
MY_P="${MY_PN}-${PV}"

DESCRIPTION="A microframework based on Werkzeug, Jinja2 and good intentions"
HOMEPAGE="http://pypi.python.org/pypi/Flask"
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc examples test"

RDEPEND="dev-python/blinker
	>=dev-python/jinja-2.4
	dev-python/setuptools
	>=dev-python/werkzeug-0.6.1"
DEPEND="${RDEPEND}
	doc? ( >=dev-python/sphinx-0.6 )"

S="${WORKDIR}/${MY_P}"

src_compile() {
	distutils_src_compile

	if use doc; then
		einfo "Generation of documentation"
		pushd docs > /dev/null
		PYTHONPATH=".." emake html || die "Generation of documentation failed"
		popd > /dev/null
	fi
}

src_test() {
	testing() {
		PYTHONPATH="." "$(PYTHON)" tests/flask_tests.py
	}
	python_execute_function testing
}

src_install() {
	distutils_src_install

	if use doc; then
		pushd docs/_build/html > /dev/null
		insinto /usr/share/doc/${PF}/html
		doins -r [a-z]* _images _static || die "Installation of documentation failed"
		popd > /dev/null
	fi

	if use examples; then
		insinto /usr/share/doc/${PF}
		doins -r examples || die "Installation of examples failed"
	fi
}