[gentoo-commits] gentoo-x86 commit in dev-embedded/avr-libc: ChangeLog avr-libc-1.8.0.ebuild

[Tim Harder (radhermit)]

radhermit    12/01/04 04:50:01

  Modified:             ChangeLog
  Added:                avr-libc-1.8.0.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha84/cvs/Linux x86_64)

Revision  Changes    Path
1.50                 dev-embedded/avr-libc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-embedded/avr-libc/ChangeLog?rev=1.50&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-embedded/avr-libc/ChangeLog?rev=1.50&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-embedded/avr-libc/ChangeLog?r1=1.49&r2=1.50

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-embedded/avr-libc/ChangeLog,v
retrieving revision 1.49
retrieving revision 1.50
diff -u -r1.49 -r1.50
--- ChangeLog	4 Sep 2011 23:57:48 -0000	1.49
+++ ChangeLog	4 Jan 2012 04:50:01 -0000	1.50
@@ -1,6 +1,11 @@
 # ChangeLog for dev-embedded/avr-libc
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-embedded/avr-libc/ChangeLog,v 1.49 2011/09/04 23:57:48 radhermit Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-embedded/avr-libc/ChangeLog,v 1.50 2012/01/04 04:50:01 radhermit Exp $
+
+*avr-libc-1.8.0 (04 Jan 2012)
+
+  04 Jan 2012; Tim Harder <radhermit@g.o> +avr-libc-1.8.0.ebuild:
+  Version bump.
 
   04 Sep 2011; Tim Harder <radhermit@g.o> avr-libc-1.7.1.ebuild:
   Minor grammar fix.



1.1                  dev-embedded/avr-libc/avr-libc-1.8.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-embedded/avr-libc/avr-libc-1.8.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-embedded/avr-libc/avr-libc-1.8.0.ebuild?rev=1.1&content-type=text/plain

Index: avr-libc-1.8.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-embedded/avr-libc/avr-libc-1.8.0.ebuild,v 1.1 2012/01/04 04:50:01 radhermit Exp $

CHOST="avr"
CTARGET="avr"

EAPI="4"

inherit flag-o-matic

DESCRIPTION="C library for Atmel AVR microcontrollers"
HOMEPAGE="http://www.nongnu.org/avr-libc/"
SRC_URI="http://savannah.nongnu.org/download/avr-libc/${P}.tar.bz2
	http://savannah.nongnu.org/download/avr-libc/${PN}-manpages-${PV}.tar.bz2
	doc? ( http://savannah.nongnu.org/download/avr-libc/${PN}-user-manual-${PV}.tar.bz2 )"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="doc crosscompile_opts_headers-only"

DEPEND=">=sys-devel/crossdev-0.9.1"
[[ ${CATEGORY/cross-} != ${CATEGORY} ]] \
	&& RDEPEND="!dev-embedded/avr-libc" \
	|| RDEPEND=""

DOCS="AUTHORS ChangeLog* NEWS README"

pkg_setup() {
	# check for avr-gcc, bug #134738
	ebegin "Checking for avr-gcc"
	if type -p avr-gcc > /dev/null ; then
		eend 0
	else
		eend 1

		eerror
		eerror "Failed to locate 'avr-gcc' in \$PATH. You can install an AVR toolchain using:"
		eerror "  $ crossdev -t avr"
		eerror
		die "AVR toolchain not found"
	fi
}

src_prepare() {
	# work around broken gcc versions PR45261
	local mcu
	for mcu in $(sed -r -n '/CHECK_AVR_DEVICE/{s:.*[(](.*)[)]:\1:;p}' configure.ac) ; do
		if avr-gcc -E - -mmcu=${mcu} <<<"" |& grep -q 'unknown MCU' ; then
			sed -i "/HAS_${mcu}=yes/s:yes:no:" configure
		fi
	done

	# Install docs in correct directory
	sed -i -e "/DOC_INST_DIR/s:\$(VERSION):${PVR}:" configure || die

	strip-flags
	strip-unsupported-flags
}

src_install() {
	default

	# man pages can not go into standard locations
	# as they would then overwrite libc man pages
	insinto /usr/share/doc/${PF}/man/man3
	doins "${WORKDIR}"/man/man3/*
	prepman /usr/share/doc/${PF}

	use doc	&& dohtml "${WORKDIR}"/${PN}-user-manual-${PV}/*
}