[gentoo-commits] repo/gentoo:master commit in: media-sound/wildmidi/

[Joonas Niilola]

commit:     f2309f62f521633e8e7e68cac345de75a5cf3635
Author:     Azamat H. Hackimov <azamat.hackimov <AT> gmail <DOT> com>
AuthorDate: Sat Mar 27 13:08:56 2021 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Wed Mar 31 07:40:18 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f2309f62

media-sound/wildmidi: update to 0.4.4

Package-Manager: Portage-3.0.13, Repoman-3.0.2
Signed-off-by: Azamat H. Hackimov <azamat.hackimov <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/20144
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 media-sound/wildmidi/Manifest              |  1 +
 media-sound/wildmidi/wildmidi-0.4.4.ebuild | 59 ++++++++++++++++++++++++++++++
 2 files changed, 60 insertions(+)

diff --git a/media-sound/wildmidi/Manifest b/media-sound/wildmidi/Manifest
index c76b733e91d..410e1850e50 100644
--- a/media-sound/wildmidi/Manifest
+++ b/media-sound/wildmidi/Manifest
@@ -1 +1,2 @@
 DIST wildmidi-0.4.3.tar.gz 196750 BLAKE2B 580903dd1e7dc61193b593f3706d5070ae5cf26394919f8d632098aa0dda14d8d65631c902a6a01d02d046e639df4d66727849954b5d6f76dba8d12235e20b8d SHA512 7e86e998ee97cdf57328e4cf5ef52a64926fd01999879c0eae5b6c823be4e6d116f7026230bd15d209e6616fbc7ba1c29ebd1f3be04735e341ce5c83298f956f
+DIST wildmidi-0.4.4.tar.gz 197597 BLAKE2B 5f5b11bec70b24b4798ac39d4d30420916609f3d65497ef88b48ef292f41d0cc81cc8d9c8c47ffc68705d6297a9ce55ef5d7ebdf63f8c18b8b0f7982c1f60bfc SHA512 5b74ee83f1d7ce3b45d2f996aaa30ec6e7d7808eab294a3eaf6fcef77443523df1f54bb0fb1b3105edd0d72d75885fda1a2e97c68defb5bbd687bda5077d3454

diff --git a/media-sound/wildmidi/wildmidi-0.4.4.ebuild b/media-sound/wildmidi/wildmidi-0.4.4.ebuild
new file mode 100644
index 00000000000..f6f59cf6d83
--- /dev/null
+++ b/media-sound/wildmidi/wildmidi-0.4.4.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake readme.gentoo-r1
+
+DESCRIPTION="MIDI processing library and player using the GUS patch set"
+HOMEPAGE="http://www.mindwerks.net/projects/wildmidi/"
+SRC_URI="https://github.com/Mindwerks/${PN}/archive/${P}.tar.gz"
+
+LICENSE="GPL-3+ LGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86"
+IUSE="+alsa openal oss +player"
+
+DEPEND="
+	player? (
+		alsa? ( media-libs/alsa-lib )
+		openal? ( media-libs/openal )
+	)
+"
+RDEPEND="${DEPEND}
+	media-sound/timidity-freepats
+"
+
+REQUIRED_USE="player? ( ^^ ( alsa oss openal ) )"
+
+DOC_CONTENTS="${PN} is using timidity-freepats for midi playback.
+	A default configuration file was placed on /etc/${PN}/${PN}.cfg.
+	For more information please read the ${PN}.cfg manpage."
+
+S="${WORKDIR}/${PN}-${P}"
+
+src_prepare() {
+	cmake_src_prepare
+	# Fix location of media-sound/timidity-freepats
+	# See #749759
+	sed -i -e "s:midi/freepats:timidity/freepats:" cfg/wildmidi.cfg || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWANT_ALSA=$(usex alsa)
+		-DWANT_OPENAL=$(usex openal)
+		-DWANT_OSS=$(usex oss)
+		-DWANT_PLAYER=$(usex player)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	insinto /etc/${PN}/
+	doins cfg/wildmidi.cfg
+
+	readme.gentoo_create_doc
+}