[gentoo-commits] repo/gentoo:master commit in: net-irc/kvirc/

[Mike Gilbert]

commit:     e3d68d650dc8bba91d4432200adb4adce1ad0ed8
Author:     Arfrever Frehtes Taifersar Arahesis <Arfrever <AT> Apache <DOT> Org>
AuthorDate: Sat Apr  2 01:03:55 2016 +0000
Commit:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
CommitDate: Sat Apr  2 21:30:40 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e3d68d65

net-irc/kvirc: Version bump (5.0_pre20160401144043).

 net-irc/kvirc/Manifest                           |   1 +
 net-irc/kvirc/kvirc-5.0_pre20160401144043.ebuild | 138 +++++++++++++++++++++++
 2 files changed, 139 insertions(+)

diff --git a/net-irc/kvirc/Manifest b/net-irc/kvirc/Manifest
index e59d939..8768d59 100644
--- a/net-irc/kvirc/Manifest
+++ b/net-irc/kvirc/Manifest
@@ -1,3 +1,4 @@
 DIST kvirc-4.4_pre20151218202654.tar.gz 7185704 SHA256 592a4cecf7f810501de5fa6daa7b3909a3bd600c59a6aa2e5a35d5dac4ad5d48 SHA512 bcd2403d869f92260bb6d07eb1313a9ecd85b211366d1655ff83d8a70f555f062e2e56d0743520f41e3e5131c8283ff31fed05765654f47ba5adbfce71339f7b WHIRLPOOL 78e915ea445f5a7a386397322e33dd2e019a9f55db48405e8bc6cca8daf6bc4e9b1e35138604deb77b62c0bdf740fc514f01ed8c473b442d69a94e6dade4670e
 DIST kvirc-4.4_pre6250.tar.xz 4606432 SHA256 58919286d63d8579778c9374b8aab7bde3ba2238bee32dcb5376b0aa45951a92 SHA512 2ba35cfd68a42fe075845241bf445f9dd3ca01b701b17f3162c34f8ef6f03a84f098b4647c821294cb54e2bbca9436debd6f53da98f7b83475196c115b936a94 WHIRLPOOL 3d18094433e258f4fa824eb2a0ac55edf54a879981398b44301a2e7444f61071c4b53131f5f8ad6795e92cf71d6ddda7e1aea7c5c2a3e9e46d2188f1267696f7
 DIST kvirc-5.0_pre20160201053254.tar.gz 6754497 SHA256 7a6438835f3173f9c357f3225c1dfe8a54ae99c0d422a656fddbb695431f90f4 SHA512 cae8d7ec7fe4aeee509bf8de150dd70609ef80f152e57d5bc4801f5e8845ab8c8de7ee56345da45f761d8d57865e53b7c1da3f3e3a39f309f5e0c9b751a797dc WHIRLPOOL 7f27006a8bbcdde911b13bc8c957adfcc8ccb4f7cec7602cf83e97cb13099d52a51dae5c4b82b52aa4b1b021629e71e1a88781f06d858ca50b58a2566996a4bd
+DIST kvirc-5.0_pre20160401144043.tar.gz 6758117 SHA256 2ec2d5302232292a417caf8885f03908410edb019deb108008d8dc442e5f4436 SHA512 8ae41302d491260aa836683999effdb70bd265c105c7092674e02951408d6658d6c29bd20495daba8508f066cce2840d012a5c30cb1f6305c916f10e3b398b4b WHIRLPOOL 71bc01fdf519739639aadc382d865e709a07a272ddad2d01af06edd8d32c08af4e238ad9aea967a452acd43ae09a3819481c0f71f8d85d8688ffe8c39b0a13cf

diff --git a/net-irc/kvirc/kvirc-5.0_pre20160401144043.ebuild b/net-irc/kvirc/kvirc-5.0_pre20160401144043.ebuild
new file mode 100644
index 0000000..80627c0
--- /dev/null
+++ b/net-irc/kvirc/kvirc-5.0_pre20160401144043.ebuild
@@ -0,0 +1,138 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+PYTHON_DEPEND="python? 2"
+
+inherit cmake-utils flag-o-matic multilib python
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/kvirc/KVIrc"
+	KVIRC_GIT_REVISION=""
+	KVIRC_GIT_SOURCES_DATE=""
+else
+	inherit vcs-snapshot
+
+	KVIRC_GIT_REVISION="a559c50d8ff1ba2c265d22cb45ce0b79b26584d9"
+	KVIRC_GIT_SOURCES_DATE="${PV#*_pre}"
+	KVIRC_GIT_SOURCES_DATE="$(printf "%04u-%02u-%02u" ${KVIRC_GIT_SOURCES_DATE:0:4} ${KVIRC_GIT_SOURCES_DATE:4:2} ${KVIRC_GIT_SOURCES_DATE:6:2})"
+fi
+
+DESCRIPTION="Advanced IRC Client"
+HOMEPAGE="http://www.kvirc.net/ https://github.com/kvirc/KVIrc"
+if [[ "${PV}" == "9999" ]]; then
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/kvirc/KVIrc/archive/${KVIRC_GIT_REVISION}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="kvirc"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="audiofile +dbus dcc_video +dcc_voice debug doc gsm +ipc ipv6 kde +nls oss +perl +phonon profile +python spell +ssl theora +transparency webkit"
+
+RDEPEND="dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	sys-libs/zlib:0=
+	x11-libs/libX11
+	audiofile? ( media-libs/audiofile )
+	dbus? ( dev-qt/qtdbus:5 )
+	dcc_video? ( dev-qt/qtmultimedia:5[widgets] )
+	kde? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/ki18n:5
+		kde-frameworks/knotifications:5
+		kde-frameworks/kservice:5
+		kde-frameworks/kwindowsystem:5
+		kde-frameworks/kxmlgui:5
+	)
+	perl? ( dev-lang/perl:0= )
+	phonon? ( media-libs/phonon:0[qt5] )
+	spell? ( app-text/enchant )
+	ssl? ( dev-libs/openssl:0= )
+	theora? (
+		media-libs/libogg
+		media-libs/libtheora
+		media-libs/libvorbis
+	)
+	webkit? ( dev-qt/qtwebkit:5 )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	x11-proto/scrnsaverproto
+	doc? ( app-doc/doxygen )
+	kde? ( kde-frameworks/extra-cmake-modules:5 )
+	nls? ( sys-devel/gettext )"
+RDEPEND="${RDEPEND}
+	gsm? ( media-sound/gsm )"
+REQUIRED_USE="audiofile? ( oss )"
+
+DOCS=(ChangeLog doc/FAQ)
+
+pkg_setup() {
+	if use python; then
+		python_set_active_version 2
+		python_pkg_setup
+	fi
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	if [[ "${PV}" == "9999" ]]; then
+		KVIRC_GIT_REVISION="$(git show -s --format=%H)"
+		KVIRC_GIT_SOURCES_DATE="$(git show -s --format=%cd --date=short)"
+	fi
+	einfo "Setting of revision number to ${KVIRC_GIT_REVISION} ${KVIRC_GIT_SOURCES_DATE}"
+	sed -e "/#define KVI_DEFAULT_FRAME_CAPTION/s/KVI_VERSION/& \" (${KVIRC_GIT_REVISION} ${KVIRC_GIT_SOURCES_DATE})\"/" -i src/kvirc/ui/KviMainWindow.cpp || die "Setting of revision number failed"
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+
+	local libdir="$(get_libdir)"
+	local mycmakeargs=(
+		-DLIB_SUFFIX=${libdir#lib}
+		-DMANUAL_REVISION=${KVIRC_GIT_REVISION}
+		-DMANUAL_SOURCES_DATE=${KVIRC_GIT_SOURCES_DATE//-/}
+		-DWANT_CRYPT=yes
+		-DWANT_ENV_FLAGS=yes
+		-DWANT_VERBOSE=yes
+
+		-DWANT_AUDIOFILE=$(usex audiofile)
+		-DWANT_DCC_VIDEO=$(usex dcc_video)
+		-DWANT_DCC_VOICE=$(usex dcc_voice)
+		-DWANT_DEBUG=$(usex debug)
+		-DWANT_DOXYGEN=$(usex doc)
+		-DWANT_GETTEXT=$(usex nls)
+		-DWANT_GSM=$(usex gsm)
+		-DWANT_IPC=$(usex ipc)
+		-DWANT_IPV6=$(usex ipv6)
+		-DWANT_KDE=$(usex kde)
+		-DWANT_MEMORY_PROFILE=$(usex profile)
+		-DWANT_OGG_THEORA=$(usex theora)
+		-DWANT_OPENSSL=$(usex ssl)
+		-DWANT_OSS=$(usex oss)
+		-DWANT_PERL=$(usex perl)
+		-DWANT_PHONON=$(usex phonon)
+		-DWANT_PYTHON=$(usex python)
+		-DWANT_QTDBUS=$(usex dbus)
+		-DWANT_QTWEBKIT=$(usex webkit)
+		-DWANT_SPELLCHECKER=$(usex spell)
+		-DWANT_TRANSPARENCY=$(usex transparency)
+
+		# COMPILE_SVG_SUPPORT not used in source code.
+		-DWANT_QTSVG=no
+	)
+
+	cmake-utils_src_configure
+}