[gentoo-commits] repo/gentoo:master commit in: net-misc/owncloud-client/

[Bernard Cafarelli]

commit:     bff6586b9943bea7f60c54dedcfa8fc4e34d4460
Author:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
AuthorDate: Mon Feb  3 10:11:46 2020 +0000
Commit:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
CommitDate: Mon Feb  3 10:11:57 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bff6586b

net-misc/owncloud-client: 2.6.1 version bump

Drop shibboleth USE-flag, it was completely dropped upstream
Add optional gnome-keyring runtime dependency
Fix USE=test build option
Use xdg eclass for icon cache update

Closes: https://bugs.gentoo.org/666798
Closes: https://bugs.gentoo.org/706594
Package-Manager: Portage-2.3.87, Repoman-2.3.20
Signed-off-by: Bernard Cafarelli <voyageur <AT> gentoo.org>

 net-misc/owncloud-client/Manifest                  |  1 +
 .../owncloud-client-2.6.1.13407.ebuild             | 84 ++++++++++++++++++++++
 2 files changed, 85 insertions(+)

diff --git a/net-misc/owncloud-client/Manifest b/net-misc/owncloud-client/Manifest
index 1055db0bab7..61d9950b6d1 100644
--- a/net-misc/owncloud-client/Manifest
+++ b/net-misc/owncloud-client/Manifest
@@ -1 +1,2 @@
 DIST owncloudclient-2.6.0.13018.tar.xz 17311396 BLAKE2B b0c76b2fea51ca9e71f918ada2b99ce20b9b62494c41608e804c4ca0c8aafe59897fea31d28bed1ec61feefca4b4b6e783c6fa777ea56524e7c18d1a460ab954 SHA512 b8eb9dc6f9c061a74fee3f31926a3fb7f5093277955fe327d1169c84f929d1e1ad8da472a7098c1c10399f395c6bfc3b2684cf4c85cddc5e45b733abfb8e4046
+DIST owncloudclient-2.6.1.13407.tar.xz 17317284 BLAKE2B b88bfc987aca036b6269e094cee5b91a3516db7b899df4cfde4961ba6eb3bb24329de103b154f0a21e5778997659cfb9b53be2f88affe03251aa9c747276d517 SHA512 40e0b607ac6cd5437682cd40e125404472c5ad63520e1dde19729760c0b7612451b3a34ede74e988d8fd09a6fae7d17a3dd6c5b0cfa6563dab7245e5f67c52bf

diff --git a/net-misc/owncloud-client/owncloud-client-2.6.1.13407.ebuild b/net-misc/owncloud-client/owncloud-client-2.6.1.13407.ebuild
new file mode 100644
index 00000000000..fbddf9224bb
--- /dev/null
+++ b/net-misc/owncloud-client/owncloud-client-2.6.1.13407.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils xdg
+
+DESCRIPTION="Synchronize files from ownCloud Server with your computer"
+HOMEPAGE="https://owncloud.org/"
+SRC_URI="https://download.owncloud.com/desktop/stable/${P/-}.tar.xz"
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc dolphin gnome-keyring nautilus test"
+
+COMMON_DEPEND=">=dev-db/sqlite-3.4:3
+	dev-libs/qtkeychain[qt5(+)]
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-fs/inotify-tools
+	dolphin? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+	)
+	nautilus? ( dev-python/nautilus-python )"
+
+RDEPEND="${COMMON_DEPEND}
+	gnome-keyring? ( gnome-base/gnome-keyring )"
+DEPEND="${COMMON_DEPEND}
+	dev-qt/linguist-tools:5
+	doc? (
+		dev-python/sphinx
+		dev-tex/latexmk
+		dev-texlive/texlive-latexextra
+		virtual/latex-base
+	)
+	dolphin? ( kde-frameworks/extra-cmake-modules )
+	test? (
+		dev-util/cmocka
+		dev-qt/qttest:5
+	)"
+
+RESTRICT="!test? ( test )"
+
+S=${WORKDIR}/${P/-}
+
+src_prepare() {
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die
+
+	if ! use nautilus; then
+		pushd shell_integration > /dev/null || die
+		cmake_comment_add_subdirectory nautilus
+		popd > /dev/null || die
+	fi
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DCMAKE_DISABLE_FIND_PACKAGE_Sphinx=$(usex !doc)
+		-DCMAKE_DISABLE_FIND_PACKAGE_KF5=$(usex !dolphin)
+		-DBUILD_TESTING=$(usex test)
+	)
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	if ! use doc ; then
+		elog "Documentation and man pages not installed"
+		elog "Enable doc USE-flag to generate them"
+	fi
+	xdg_pkg_postinst
+}