[gentoo-commits] gentoo-x86 commit in app-emacs/org-mode: ChangeLog org-mode-7.8.03-r1.ebuild org-mode-7.8.02.ebuild org-mode-7.8.03.ebuild

[Ulrich Mueller (ulm)]

ulm         12/01/05 07:31:45

  Modified:             ChangeLog
  Added:                org-mode-7.8.03-r1.ebuild
  Removed:              org-mode-7.8.02.ebuild org-mode-7.8.03.ebuild
  Log:
  Fix typo in site-init file, bug 397721. Remove old.
  
  (Portage version: 2.1.10.44/cvs/Linux x86_64)

Revision  Changes    Path
1.140                app-emacs/org-mode/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emacs/org-mode/ChangeLog?rev=1.140&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emacs/org-mode/ChangeLog?rev=1.140&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emacs/org-mode/ChangeLog?r1=1.139&r2=1.140

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emacs/org-mode/ChangeLog,v
retrieving revision 1.139
retrieving revision 1.140
diff -u -r1.139 -r1.140
--- ChangeLog	4 Jan 2012 18:11:36 -0000	1.139
+++ ChangeLog	5 Jan 2012 07:31:45 -0000	1.140
@@ -1,6 +1,13 @@
 # ChangeLog for app-emacs/org-mode
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emacs/org-mode/ChangeLog,v 1.139 2012/01/04 18:11:36 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emacs/org-mode/ChangeLog,v 1.140 2012/01/05 07:31:45 ulm Exp $
+
+*org-mode-7.8.03-r1 (05 Jan 2012)
+
+  05 Jan 2012; Ulrich Mueller <ulm@g.o> -org-mode-7.8.02.ebuild,
+  -org-mode-7.8.03.ebuild, +org-mode-7.8.03-r1.ebuild,
+  files/50org-mode-gentoo-7.8.03.el:
+  Fix typo in site-init file, bug 397721. Remove old.
 
   04 Jan 2012; Pawel Hajdan jr <phajdan.jr@g.o> org-mode-7.7.ebuild:
   x86 stable wrt bug #396001



1.1                  app-emacs/org-mode/org-mode-7.8.03-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emacs/org-mode/org-mode-7.8.03-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emacs/org-mode/org-mode-7.8.03-r1.ebuild?rev=1.1&content-type=text/plain

Index: org-mode-7.8.03-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emacs/org-mode/org-mode-7.8.03-r1.ebuild,v 1.1 2012/01/05 07:31:45 ulm Exp $

EAPI=4
NEED_EMACS=22

inherit elisp

DESCRIPTION="An Emacs mode for notes and project planning"
HOMEPAGE="http://www.orgmode.org/"
SRC_URI="http://orgmode.org/org-${PV}.tar.gz"

LICENSE="GPL-3 FDL-1.3 contrib? ( GPL-2 MIT as-is )"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~sparc-fbsd ~x86-fbsd ~x86-macos"
IUSE="contrib"

S="${WORKDIR}/org-${PV}"
ELISP_PATCHES="${P}-Makefile.patch"
# Remove autoload file to make sure that it is regenerated with
# the right Emacs version.
ELISP_REMOVE="lisp/org-install.el"
SITEFILE="50${PN}-gentoo-${PV}.el"

src_compile() {
	emake datadir="${SITEETC}/${PN}"
}

src_install() {
	emake \
		prefix="${ED}/usr" \
		lispdir="${ED}${SITELISP}/${PN}" \
		datadir="${ED}${SITEETC}/${PN}" \
		infodir="${ED}/usr/share/info" \
		install

	cp "${FILESDIR}/${SITEFILE}" "${T}/${SITEFILE}"

	if use contrib; then
		elisp-install ${PN}/contrib contrib/lisp/*org*.el || die
		insinto /usr/share/doc/${PF}/contrib
		doins -r contrib/README contrib/babel contrib/odt contrib/scripts
		find "${ED}/usr/share/doc/${PF}/contrib" -type f -name '.*' \
			-exec rm -f '{}' '+'
		# add the contrib subdirectory to load-path
		sed -ie 's:\(.*@SITELISP@\)\(.*\):&\n\1/contrib\2:' \
			"${T}/${SITEFILE}" || die
	fi

	elisp-site-file-install "${T}/${SITEFILE}" || die
	doinfo doc/org
	dodoc README doc/org.pdf doc/orgcard.pdf doc/orgguide.pdf
}