[gentoo-commits] repo/gentoo:master commit in: sci-libs/indilib/

[Andreas Sturmlechner]

commit:     06f859cbe85c7d020af20631e4da8d6a6750acda
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 31 22:27:37 2019 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Jan  1 07:55:13 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=06f859cb

sci-libs/indilib: Fix udev rules install path

Thanks-to: James Bates <james.h.bates <AT> gmail.com>
Closes: https://bugs.gentoo.org/703952
Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 sci-libs/indilib/indilib-1.8.2-r2.ebuild | 56 ++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

diff --git a/sci-libs/indilib/indilib-1.8.2-r2.ebuild b/sci-libs/indilib/indilib-1.8.2-r2.ebuild
new file mode 100644
index 00000000000..f8b0dd3086f
--- /dev/null
+++ b/sci-libs/indilib/indilib-1.8.2-r2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake udev
+
+DESCRIPTION="INDI Astronomical Control Protocol library"
+HOMEPAGE="https://www.indilib.org/"
+SRC_URI="https://github.com/${PN}/${PN/lib/}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD GPL-2+ LGPL-2+ LGPL-2.1+"
+SLOT="0/1"
+KEYWORDS="amd64 ~ppc ~ppc64 ~x86"
+IUSE="ogg test websocket"
+
+RDEPEND="
+	net-misc/curl
+	sci-libs/cfitsio:=
+	sci-libs/fftw:3.0=
+	sci-libs/gsl:=
+	sci-libs/libnova:=
+	sys-libs/zlib
+	virtual/jpeg:0
+	virtual/libusb:0
+	ogg? (
+		media-libs/libogg
+		media-libs/libtheora
+	)
+	websocket? ( dev-libs/boost:= )
+"
+DEPEND="${RDEPEND}
+	kernel_linux? ( sys-kernel/linux-headers )
+	test? ( >=dev-cpp/gtest-1.8.0 )
+	websocket? ( dev-cpp/websocketpp )
+"
+
+RESTRICT="!test? ( test )"
+
+S="${WORKDIR}/${P/lib/}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DINDI_BUILD_QT5_CLIENT=OFF
+		-DINDI_BUILD_UNITTESTS=$(usex test)
+		-DUDEVRULES_INSTALL_DIR="$(get_udevdir)"/rules.d
+		$(cmake_use_find_package ogg OggTheora)
+		-DINDI_BUILD_WEBSOCKET=$(usex websocket)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	BUILD_DIR="${BUILD_DIR}"/test cmake_src_test
+}