[gentoo-commits] repo/gentoo:master commit in: www-client/httrack/

[Sebastian Pipping]

commit:     d0c7f3efc70a10189696aed2e00c67745061996c
Author:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 31 21:04:36 2019 +0000
Commit:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
CommitDate: Sun Mar 31 21:05:43 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d0c7f3ef

www-client/httrack: EAPI 7 + ltprune + icon cache

Closes: https://bugs.gentoo.org/675958
Signed-off-by: Sebastian Pipping <sping <AT> gentoo.org>
Package-Manager: Portage-2.3.62, Repoman-2.3.12

 www-client/httrack/httrack-3.49.2-r2.ebuild | 57 +++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

diff --git a/www-client/httrack/httrack-3.49.2-r2.ebuild b/www-client/httrack/httrack-3.49.2-r2.ebuild
new file mode 100644
index 00000000000..f513c18ae01
--- /dev/null
+++ b/www-client/httrack/httrack-3.49.2-r2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit eutils xdg-utils
+
+DESCRIPTION="HTTrack Website Copier, Open Source Offline Browser"
+HOMEPAGE="https://www.httrack.com/"
+SRC_URI="https://mirror.httrack.com/historical/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="libressl static-libs"
+
+RDEPEND=">=sys-libs/zlib-1.2.5.1-r1
+	!libressl? ( dev-libs/openssl:= )
+	libressl? ( dev-libs/libressl )
+	"
+DEPEND="${RDEPEND}"
+
+DOCS=( AUTHORS README greetings.txt history.txt )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.48.13-minizip.patch
+)
+
+src_configure() {
+	econf $(use_enable static-libs static) \
+		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
+		--htmldir="${EPREFIX}"/usr/share/doc/${PF}/html
+}
+
+src_install() {
+	default
+
+	# Make webhttrack work despite FEATURES=nodoc cutting
+	# all of /usr/share/doc/ away (bug #493376)
+	if has nodoc ${FEATURES} ; then
+		dodir /usr/share/${PF}/
+		mv "${D}"/usr/share/{doc/,}${PF}/html || die
+
+		rm "${D}"/usr/share/${PN}/html || die
+		dosym ../../${PF}/html /usr/share/${PN}/html
+	fi
+
+	find "${D}" -name '*.la' -type f -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}