[gentoo-commits] repo/gentoo:master commit in: dev-libs/librelp/

[Thomas Deutschmann]

commit:     40fe4fe772611857d65b3dc0fe18206f561335e0
Author:     Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
AuthorDate: Wed Sep 30 16:49:23 2020 +0000
Commit:     Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
CommitDate: Wed Sep 30 18:03:51 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=40fe4fe7

dev-libs/librelp: bump to v1.8.0

Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Thomas Deutschmann <whissi <AT> gentoo.org>

 dev-libs/librelp/Manifest             |  1 +
 dev-libs/librelp/librelp-1.8.0.ebuild | 74 +++++++++++++++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/dev-libs/librelp/Manifest b/dev-libs/librelp/Manifest
index 5b2f59a2ed8..273afbcef11 100644
--- a/dev-libs/librelp/Manifest
+++ b/dev-libs/librelp/Manifest
@@ -1,2 +1,3 @@
 DIST librelp-1.6.0.tar.gz 522827 BLAKE2B 04e608a3afe4e6e0109cc9bf753de34e9486595e33bc57387b9428bcf50f8d56177e8f849870611778636be5a58714e4640048758c83a041a354f70442d55cf0 SHA512 1bf96b700fa5ab648ed671b341ae7101fc1db4107f178abd507647afe4f12d59a94c821cc0e06998ac7b344ed41a5e3821843c722c82bf5284c6556995391228
 DIST librelp-1.7.0.tar.gz 532967 BLAKE2B 19e3eaa05aa7a53b4701eaf96b3be6d8467c7f5c0de0bc1ba81fcb6d6ed6529146140a32b05fcdb47330be2b573a9d84779ea519dd9cacf50d3b7710d523b808 SHA512 e9d71f27d5c50b043254a3f1b0643e7172e5678b6a5a7dddb9d4a9e3afa3ed0adf818a4e868960c1607da5f63430f163f9e76c882ed5460149cb1cceff42b4bd
+DIST librelp-1.8.0.tar.gz 539467 BLAKE2B 3d1d396059955d2b83a21a42838b56c6a18cde296e6b7c4beb79ba9a8d222d7e5d738419b87b24ed05da553cb16fd827e8820c4c81c50d5a3770ad745efe3ef5 SHA512 aa3e02010cdd4587ff28987f00291708e752b2e2f5f37f5a5239bda6992f55cf428cf1b6e06847062be31844cfdda6b654bcbb9024dff943d140b405ec93c0f4

diff --git a/dev-libs/librelp/librelp-1.8.0.ebuild b/dev-libs/librelp/librelp-1.8.0.ebuild
new file mode 100644
index 00000000000..edacd29ee8e
--- /dev/null
+++ b/dev-libs/librelp/librelp-1.8.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit autotools python-any-r1
+
+DESCRIPTION="An easy to use library for the RELP protocol"
+HOMEPAGE="https://www.rsyslog.com/librelp/"
+SRC_URI="https://download.rsyslog.com/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+ doc? ( FDL-1.3 )"
+
+# subslot = soname version
+SLOT="0/0.5.0"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~sparc ~x86"
+IUSE="debug doc +ssl +gnutls libressl openssl static-libs test"
+REQUIRED_USE="ssl? ( ^^ ( gnutls openssl ) )"
+
+RDEPEND="
+	ssl? (
+		gnutls? ( >=net-libs/gnutls-3.3.17.1:0= )
+		openssl? (
+			!libressl? ( dev-libs/openssl:0= )
+			libressl? ( dev-libs/libressl:0= )
+		)
+	)"
+DEPEND="${RDEPEND}
+	test? ( ${PYTHON_DEPS} )
+	virtual/pkgconfig"
+
+RESTRICT="!test? ( test )"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	sed -i \
+		-e 's/ -g"/"/g' \
+		configure.ac || die "sed failed"
+
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-valgrind
+		$(use_enable debug)
+		$(use_enable gnutls tls)
+		$(use_enable openssl tls-openssl)
+		$(use_enable static-libs static)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_test() {
+	emake -j1 check
+}
+
+src_install() {
+	local DOCS=( ChangeLog )
+	use doc && local HTML_DOCS=( doc/relp.html )
+	default
+
+	if ! use static-libs; then
+		find "${D}" -name '*.la' -delete || die
+	fi
+}