[gentoo-commits] gentoo-x86 commit in mail-mta/msmtp: ChangeLog msmtp-1.4.23.ebuild

[Tim Harder (radhermit)]

radhermit    11/01/27 23:08:42

  Modified:             ChangeLog
  Added:                msmtp-1.4.23.ebuild
  Log:
  Version bump (bug #352953). Remove mailwrapper support, add vim-syntax USE flag, install gnome-keyring script (bug #341113), and install find_alias script (bug #349869). Bump to EAPI 3, remove unused eutils eclass, and use CDEPEND for common dependencies.
  
  (Portage version: 2.2.0_alpha19/cvs/Linux x86_64)

Revision  Changes    Path
1.91                 mail-mta/msmtp/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-mta/msmtp/ChangeLog?rev=1.91&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-mta/msmtp/ChangeLog?rev=1.91&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-mta/msmtp/ChangeLog?r1=1.90&r2=1.91

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-mta/msmtp/ChangeLog,v
retrieving revision 1.90
retrieving revision 1.91
diff -u -r1.90 -r1.91
--- ChangeLog	28 Sep 2010 14:41:12 -0000	1.90
+++ ChangeLog	27 Jan 2011 23:08:42 -0000	1.91
@@ -1,6 +1,14 @@
 # ChangeLog for mail-mta/msmtp
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-mta/msmtp/ChangeLog,v 1.90 2010/09/28 14:41:12 ranger Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/mail-mta/msmtp/ChangeLog,v 1.91 2011/01/27 23:08:42 radhermit Exp $
+
+*msmtp-1.4.23 (27 Jan 2011)
+
+  27 Jan 2011; Tim Harder <radhermit@g.o> +msmtp-1.4.23.ebuild:
+  Version bump (bug #352953). Remove mailwrapper support, add vim-syntax USE
+  flag, install gnome-keyring script (bug #341113), and install find_alias
+  script (bug #349869). Bump to EAPI 3, remove unused eutils eclass, and use
+  CDEPEND for common dependencies.
 
   28 Sep 2010; Brent Baude <ranger@g.o> msmtp-1.4.21.ebuild:
   Marking msmtp-1.4.21 ppc for bug 330445



1.1                  mail-mta/msmtp/msmtp-1.4.23.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-mta/msmtp/msmtp-1.4.23.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-mta/msmtp/msmtp-1.4.23.ebuild?rev=1.1&content-type=text/plain

Index: msmtp-1.4.23.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-mta/msmtp/msmtp-1.4.23.ebuild,v 1.1 2011/01/27 23:08:42 radhermit Exp $

EAPI=3

DESCRIPTION="An SMTP client and SMTP plugin for mail user agents such as Mutt"
HOMEPAGE="http://msmtp.sourceforge.net/"
SRC_URI="mirror://sourceforge/msmtp/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
IUSE="doc gnome-keyring gnutls idn +mta nls sasl ssl vim-syntax"

CDEPEND="idn? ( net-dns/libidn )
	nls? ( virtual/libintl )
	gnome-keyring? ( gnome-base/gnome-keyring
		dev-python/gnome-keyring-python )
	gnutls? ( >=net-libs/gnutls-1.2.0 )
	!gnutls? ( ssl? ( >=dev-libs/openssl-0.9.6 ) )
	sasl? ( >=virtual/gsasl-0.2.4 )"

RDEPEND="${CDEPEND}
	mta? ( !virtual/mta )
	!net-mail/mailwrapper"

DEPEND="${CDEPEND}
	nls? ( sys-devel/gettext )
	dev-util/pkgconfig"

PROVIDE="mta? ( virtual/mta )"

src_prepare() {
	# Use default Gentoo location for mail aliases
	sed -i -e 's:/etc/aliases:/etc/mail/aliases:' scripts/find_alias/find_alias_for_msmtp.sh
}

src_configure() {
	local myconf

	if use gnutls ; then
		myconf="--with-ssl=gnutls"
	elif use ssl ; then
		myconf="--with-ssl=openssl"
	else
		myconf="--with-ssl=no"
	fi

	econf \
		$(use_with idn libidn) \
		$(use_with sasl libgsasl) \
		$(use_with gnome-keyring ) \
		$(use_enable nls) \
		${myconf}
}

src_install() {
	emake DESTDIR="${D}" install || die "install failed"

	if use mta ; then
		dodir /usr/sbin
		dosym /usr/bin/msmtp /usr/sbin/sendmail || die "dosym failed"
	fi

	dodoc AUTHORS ChangeLog NEWS README THANKS \
		doc/{Mutt+msmtp.txt,msmtprc*} || die "dodoc failed"

	if use doc ; then
		dohtml doc/msmtp.html || die "dohtml failed"
		dodoc doc/msmtp.pdf
	fi

	if use vim-syntax ; then
		insinto /usr/share/vim/vimfiles/syntax
		doins scripts/vim/msmtp.vim || die "doins syntax failed"
	fi

	if use gnome-keyring ; then
		src_install_contrib msmtp-gnome-tool "msmtp-gnome-tool.py" "README"
	fi

	src_install_contrib find_alias "find_alias_for_msmtp.sh"
	src_install_contrib msmtpqueue "*.sh" "README ChangeLog"
	src_install_contrib msmtpq "msmtpq msmtpQ" "README"
	src_install_contrib set_sendmail "set_sendmail.sh" "set_sendmail.conf"
}

src_install_contrib() {
	subdir="$1"
	bins="$2"
	docs="$3"
	local dir=/usr/share/${PN}/$subdir
	insinto ${dir}
	exeinto ${dir}
	for i in $bins ; do
		doexe scripts/$subdir/$i || die "doexe $subdir/$i failed"
	done
	for i in $docs ; do
		newdoc scripts/$subdir/$i $subdir.$i \
			|| die "dodoc $subdir/$i failed"
	done
}