[gentoo-commits] gentoo-x86 commit in app-forensics/zzuf: ChangeLog zzuf-0.13.ebuild

[Patrick Lauer (patrick)]

patrick     10/02/26 20:50:29

  Modified:             ChangeLog
  Added:                zzuf-0.13.ebuild
  Log:
  Bump
  (Portage version: 2.2_rc63/cvs/Linux x86_64)

Revision  Changes    Path
1.6                  app-forensics/zzuf/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-forensics/zzuf/ChangeLog?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-forensics/zzuf/ChangeLog?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-forensics/zzuf/ChangeLog?r1=1.5&r2=1.6

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-forensics/zzuf/ChangeLog,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- ChangeLog	28 Dec 2009 16:29:48 -0000	1.5
+++ ChangeLog	26 Feb 2010 20:50:28 -0000	1.6
@@ -1,6 +1,11 @@
 # ChangeLog for app-forensics/zzuf
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-forensics/zzuf/ChangeLog,v 1.5 2009/12/28 16:29:48 flameeyes Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-forensics/zzuf/ChangeLog,v 1.6 2010/02/26 20:50:28 patrick Exp $
+
+*zzuf-0.13 (26 Feb 2010)
+
+  26 Feb 2010; Patrick Lauer <patrick@g.o> +zzuf-0.13.ebuild:
+  Bump
 
   28 Dec 2009; Diego E. Pettenò <flameeyes@g.o> metadata.xml:
   Relinquish this to maintainer-needed.



1.1                  app-forensics/zzuf/zzuf-0.13.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-forensics/zzuf/zzuf-0.13.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-forensics/zzuf/zzuf-0.13.ebuild?rev=1.1&content-type=text/plain

Index: zzuf-0.13.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-forensics/zzuf/zzuf-0.13.ebuild,v 1.1 2010/02/26 20:50:28 patrick Exp $

inherit autotools

DESCRIPTION="Transparent application input fuzzer"
HOMEPAGE="http://libcaca.zoy.org/wiki/zzuf/"
SRC_URI="http://caca.zoy.org/files/${PN}/${P}.tar.gz"

LICENSE="WTFPL-2"
SLOT="0"
KEYWORDS="~amd64 ~sparc ~x86"
IUSE=""

RDEPEND=""

src_unpack() {
	unpack ${A}
	cd "${S}"

	sed -i -e '/CFLAGS/d' "${S}"/configure.ac \
		|| die "unable to fix the configure.ac"
	sed -i -e 's:noinst_:check_:' "${S}"/test/Makefile.am \
		|| die "unable to fix unconditional test building"

	eautoreconf
}

src_compile() {
	# Don't build the static library, as the library is only used for
	# preloading, so there is no reason to build it statically, unless
	# you want to use zzuf with a static-linked executable, which I'm
	# not even sure would be a good idea.
	econf \
		--disable-dependency-tracking \
		--disable-static \
		|| die "econf failed"
	emake || die "emake failed"
}

# This could be removed in next versions if my patches will be applied
# by Sam. -- Diego 'Flameeyes'
src_test() {
	if hasq sandbox ${FEATURES}; then
		ewarn "zzuf tests don't work correctly when sandbox is enabled,"
		ewarn "skipping tests. If you want to run the testsuite, please"
		ewarn "disable sandbox for this build."
		return
	fi

	cd "${S}"/test
	emake check || die "Unable to build tools needed for testsuite"

	./testsuite.sh || die "testsuite failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS ChangeLog NEWS README TODO

	find "${D}" -name '*.la' -delete
}