[gentoo-commits] gentoo-x86 commit in dev-db/mysql-workbench: mysql-workbench-5.2.34.ebuild ChangeLog

[Hans de Graaff (graaff)]

graaff      11/05/30 19:15:29

  Modified:             ChangeLog
  Added:                mysql-workbench-5.2.34.ebuild
  Log:
  Version bump. Fix compilation with gcc 4.6, closing 365855.
  
  (Portage version: 2.1.9.42/cvs/Linux x86_64)

Revision  Changes    Path
1.38                 dev-db/mysql-workbench/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mysql-workbench/ChangeLog?rev=1.38&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mysql-workbench/ChangeLog?rev=1.38&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mysql-workbench/ChangeLog?r1=1.37&r2=1.38

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-db/mysql-workbench/ChangeLog,v
retrieving revision 1.37
retrieving revision 1.38
diff -u -r1.37 -r1.38
--- ChangeLog	10 Apr 2011 18:14:18 -0000	1.37
+++ ChangeLog	30 May 2011 19:15:29 -0000	1.38
@@ -1,6 +1,12 @@
 # ChangeLog for dev-db/mysql-workbench
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-db/mysql-workbench/ChangeLog,v 1.37 2011/04/10 18:14:18 graaff Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-db/mysql-workbench/ChangeLog,v 1.38 2011/05/30 19:15:29 graaff Exp $
+
+*mysql-workbench-5.2.34 (30 May 2011)
+
+  30 May 2011; Hans de Graaff <graaff@g.o>
+  +mysql-workbench-5.2.34.ebuild, +files/mysql-workbench-5.2.34-gcc46.patch:
+  Version bump. Fix compilation with gcc 4.6, closing 365855.
 
   10 Apr 2011; Hans de Graaff <graaff@g.o>
   mysql-workbench-5.2.33.ebuild, +files/mysql-workbench-5.2.33-gtkmm.patch:



1.1                  dev-db/mysql-workbench/mysql-workbench-5.2.34.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mysql-workbench/mysql-workbench-5.2.34.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mysql-workbench/mysql-workbench-5.2.34.ebuild?rev=1.1&content-type=text/plain

Index: mysql-workbench-5.2.34.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/mysql-workbench/mysql-workbench-5.2.34.ebuild,v 1.1 2011/05/30 19:15:29 graaff Exp $

EAPI="3"
GCONF_DEBUG="no"

inherit gnome2 eutils flag-o-matic autotools

MY_P="${PN}-gpl-${PV}-src"

DESCRIPTION="MySQL Workbench"
HOMEPAGE="http://dev.mysql.com/workbench/"
SRC_URI="mirror://mysql/Downloads/MySQLGUITools/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="debug doc nls readline static-libs"

CDEPEND="dev-db/sqlite:3
	>=x11-libs/gtk+-2.6:2
	dev-libs/glib:2
	gnome-base/libglade:2.0
	dev-libs/libsigc++:2
	dev-libs/boost
	>=dev-cpp/ctemplate-0.95
	>=dev-libs/libxml2-2.6.2:2
	>=dev-cpp/glibmm-2.14:2
	>=dev-cpp/gtkmm-2.14:2.4
	dev-libs/libzip
	>=virtual/mysql-5.1
	dev-libs/libpcre
	virtual/opengl
	>=dev-lang/lua-5.1[deprecated]
	gnome-base/libgnome
	x11-libs/pango
	|| ( sys-libs/e2fsprogs-libs
		dev-libs/ossp-uuid )
	>=x11-libs/cairo-1.5.12[svg]
	dev-python/pexpect
	dev-python/paramiko
	doc? ( dev-python/pysqlite:2 )
	nls? ( sys-devel/gettext )
	readline? ( sys-libs/readline )"
RDEPEND="${CDEPEND}
	app-admin/sudo
	sys-apps/net-tools"
DEPEND="${CDEPEND}
	dev-util/pkgconfig"

S="${WORKDIR}"/"${MY_P}"

src_prepare() {
	# ifconfig isn't in the normal path
	sed -i -e 's:ifconfig:/sbin/ifconfig:' plugins/wb.admin/backend/wb_server_control.py || die

	epatch "${FILESDIR}/${PN}-5.2.31-python-libs.patch"
	epatch "${FILESDIR}/${P}-gcc46.patch"
	eautoreconf

	# Remove bundled ctemplate version to make sure we use the system
	# version, but leave a directory to avoid confusing configure, bug
	# 357539.
	rm -rf ext/ctemplate || die
	mkdir -p ext/ctemplate/ctemplate-src || die
}

src_configure() {
	econf \
		$(use_enable nls i18n) \
		$(use_enable readline readline) \
		$(use_enable debug) \
		$(use_enable static-libs static)
}

src_install() {
	emake install DESTDIR="${D}" || die
	find "${ED}" -name '*.la' -delete || die
}