[gentoo-commits] gentoo-x86 commit in gnome-base/gnome-applets: ChangeLog gnome-applets-2.20.1.ebuild

[Gilles Dartiguelongue (eva)]

eva         08/01/09 00:02:07

  Modified:             ChangeLog
  Added:                gnome-applets-2.20.1.ebuild
  Log:
  bump to 2.20.1
  (Portage version: 2.1.4_rc14)

Revision  Changes    Path
1.249                gnome-base/gnome-applets/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-applets/ChangeLog?rev=1.249&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-applets/ChangeLog?rev=1.249&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-applets/ChangeLog?r1=1.248&r2=1.249

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-base/gnome-applets/ChangeLog,v
retrieving revision 1.248
retrieving revision 1.249
diff -u -r1.248 -r1.249
--- ChangeLog	1 Jan 2008 22:24:05 -0000	1.248
+++ ChangeLog	9 Jan 2008 00:02:07 -0000	1.249
@@ -1,6 +1,12 @@
 # ChangeLog for gnome-base/gnome-applets
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-applets/ChangeLog,v 1.248 2008/01/01 22:24:05 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-applets/ChangeLog,v 1.249 2008/01/09 00:02:07 eva Exp $
+
+*gnome-applets-2.20.1 (08 Jan 2008)
+
+  08 Jan 2008; Gilles Dartiguelongue <eva@g.o>
+  +gnome-applets-2.20.1.ebuild:
+  bump to 2.20.1
 
   01 Jan 2008; Gilles Dartiguelongue <eva@g.o>
   -files/gnome-applets-2.16.1-dbus-version.patch,



1.1                  gnome-base/gnome-applets/gnome-applets-2.20.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-applets/gnome-applets-2.20.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-applets/gnome-applets-2.20.1.ebuild?rev=1.1&content-type=text/plain

Index: gnome-applets-2.20.1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-applets/gnome-applets-2.20.1.ebuild,v 1.1 2008/01/09 00:02:07 eva Exp $

inherit eutils gnome2 autotools

DESCRIPTION="Applets for the GNOME Desktop and Panel"
HOMEPAGE="http://www.gnome.org/"

LICENSE="GPL-2 FDL-1.1 LGPL-2"
SLOT="2"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="acpi apm doc gnome gstreamer hal ipv6 test"

RDEPEND=">=x11-libs/gtk+-2.11
		>=dev-libs/glib-2.13
		>=gnome-base/libgnome-2.8
		>=gnome-base/libgnomeui-2.8
		>=gnome-base/gconf-2.8
		>=gnome-base/gnome-panel-2.13.4
		>=gnome-base/libglade-2.4
		>=gnome-base/gail-1.1
		>=x11-libs/libxklavier-2.91
		>=x11-libs/libwnck-2.9.3
		>=app-admin/system-tools-backends-1.1.3
		>=gnome-base/gnome-desktop-2.11.1
		>=x11-libs/libnotify-0.3.2
		hal? ( >=sys-apps/hal-0.5.3 )
		>=dev-libs/dbus-glib-0.71
		>=x11-themes/gnome-icon-theme-2.15.91
		>=dev-libs/libxml2-2.5.0
		>=virtual/python-2.4
		apm? ( sys-apps/apmd )
		x11-apps/xrdb x11-libs/libX11
		gnome?	(
					gnome-base/libgnomekbd
					gnome-base/control-center

					>=gnome-extra/gucharmap-1.4
					>=gnome-base/libgtop-2.11.92
					>=gnome-base/gnome-vfs-2.15.4

					>=dev-python/pygtk-2.6
					>=dev-python/gnome-python-2.10
				)
		gstreamer?	(
						>=media-libs/gstreamer-0.10.2
						>=media-libs/gst-plugins-base-0.10.2
					)"

DEPEND="${RDEPEND}
		>=app-text/scrollkeeper-0.1.4
		>=dev-util/pkgconfig-0.19
		>=dev-util/intltool-0.35
		dev-libs/libxslt
		doc? (
				app-text/docbook-sgml-utils
				>=app-text/gnome-doc-utils-0.3.2
				~app-text/docbook-xml-dtd-4.3
			)
		test? ( ~app-text/docbook-xml-dtd-4.3 )"

DOCS="AUTHORS ChangeLog NEWS README"

MAKEOPTS="${MAKEOPTS} -j1"

pkg_setup() {
	G2CONF="--disable-scrollkeeper --enable-flags \
		$(use_with hal)
		$(use_enable ipv6)
		$(use_enable doc gtk-doc)"

	if use gstreamer; then
		G2CONF="${G2CONF} --with-gstreamer=0.10"
	fi

	if ! use ppc && ! use apm && ! use acpi; then
		G2CONF="${G2CONF} --disable-battstat"
	fi

	if use ppc && ! use apm; then
		G2CONF="${G2CONF} --disable-battstat"
	fi
}

src_install() {
	gnome2_src_install

	APPLETS="accessx-status battstat charpick cpufreq drivemount geyes \
			 gkb-new gswitchit gweather invest-applet mini-commander \
			 mixer modemlights multiload null_applet stickynotes trashapplet"

	for applet in ${APPLETS} ; do
		docinto ${applet}

		for d in AUTHORS ChangeLog NEWS README README.themes TODO ; do
			[ -s ${applet}/${d} ] && dodoc ${applet}/${d}
		done
	done
}

pkg_postinst() {
	gnome2_pkg_postinst

	if use acpi && ! use hal ; then
		elog "It is highly recommended that you install acpid if you use the"
		elog "battstat applet to prevent any issues with other applications "
		elog "trying to read acpi information."
	fi
}



-- 
gentoo-commits@l.g.o mailing list