[gentoo-commits] gentoo-x86 commit in net-misc/iputils: ChangeLog iputils-20071127-r1.ebuild

[Mike Frysinger (vapier)]

vapier      08/04/20 20:56:46

  Modified:             ChangeLog
  Added:                iputils-20071127-r1.ebuild
  Log:
  Add support for USE=idn #218638 by Hanno Boeck.
  (Portage version: 2.2_pre5)

Revision  Changes    Path
1.74                 net-misc/iputils/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/iputils/ChangeLog?rev=1.74&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/iputils/ChangeLog?rev=1.74&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/iputils/ChangeLog?r1=1.73&r2=1.74

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/iputils/ChangeLog,v
retrieving revision 1.73
retrieving revision 1.74
diff -u -r1.73 -r1.74
--- ChangeLog	20 Apr 2008 20:55:59 -0000	1.73
+++ ChangeLog	20 Apr 2008 20:56:45 -0000	1.74
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/iputils
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/iputils/ChangeLog,v 1.73 2008/04/20 20:55:59 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/iputils/ChangeLog,v 1.74 2008/04/20 20:56:45 vapier Exp $
+
+*iputils-20071127-r1 (20 Apr 2008)
+
+  20 Apr 2008; Mike Frysinger <vapier@g.o>
+  +files/iputils-20070202-idn.patch, +iputils-20071127-r1.ebuild:
+  Add support for USE=idn #218638 by Hanno Boeck.
 
   20 Apr 2008; Mike Frysinger <vapier@g.o> iputils-20071127.ebuild:
   Mark amd64 stable.



1.1                  net-misc/iputils/iputils-20071127-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/iputils/iputils-20071127-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/iputils/iputils-20071127-r1.ebuild?rev=1.1&content-type=text/plain

Index: iputils-20071127-r1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/iputils/iputils-20071127-r1.ebuild,v 1.1 2008/04/20 20:56:45 vapier Exp $

inherit flag-o-matic eutils toolchain-funcs

DESCRIPTION="Network monitoring tools including ping and ping6"
HOMEPAGE="http://www.linux-foundation.org/en/Net:Iputils"
SRC_URI="http://www.skbuff.net/iputils/iputils-s${PV}.tar.bz2
	mirror://gentoo/iputils-s${PV}-manpages.tar.bz2"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="doc idn ipv6 static"

DEPEND="virtual/os-headers
	doc? (
		app-text/openjade
		dev-perl/SGMLSpm
		app-text/docbook-sgml-dtd
		app-text/docbook-sgml-utils
	)"
RDEPEND="!net-misc/rarpd
	idn? ( net-dns/libidn )"

S=${WORKDIR}/${PN}-s${PV}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}-gcc34.patch
	epatch "${FILESDIR}"/021109-uclibc-no-ether_ntohost.patch
	epatch "${FILESDIR}"/${PN}-20070202-makefile.patch
	epatch "${FILESDIR}"/${P}-kernel-ifaddr.patch
	epatch "${FILESDIR}"/${PN}-20060512-linux-headers.patch
	epatch "${FILESDIR}"/${PN}-20070202-no-open-max.patch #195861
	epatch "${FILESDIR}"/${PN}-20070202-idn.patch #218638

	use static && append-ldflags -static
	use ipv6 || sed -i -e 's:IPV6_TARGETS=:#IPV6_TARGETS=:' Makefile
	export IDN=$(use idn && echo yes)
}

src_compile() {
	tc-export CC
	emake || die "make main failed"

	# We include the extra check for docbook2html
	# because when we emerge from a stage1/stage2,
	# it may not exist #23156
	if use doc && type -P docbook2html >/dev/null ; then
		emake -j1 html || die
	fi
}

src_install() {
	into /
	dobin ping || die "ping"
	use ipv6 && dobin ping6
	dosbin arping || die "arping"
	into /usr
	dosbin tracepath || die "tracepath"
	use ipv6 && dosbin trace{path,route}6
	dosbin clockdiff rarpd rdisc ipg tftpd || die "misc sbin"

	fperms 4711 /bin/ping
	use ipv6 && fperms 4711 /bin/ping6 /usr/sbin/traceroute6

	dodoc INSTALL RELNOTES
	use ipv6 \
		&& dosym ping.8 /usr/share/man/man8/ping6.8 \
		|| rm -f doc/*6.8
	rm -f doc/setkey.8
	doman doc/*.8

	use doc && dohtml doc/*.html
}



-- 
gentoo-commits@l.g.o mailing list