[gentoo-commits] gentoo-x86 commit in app-text/mupdf: metadata.xml ChangeLog mupdf-0.6.ebuild

[Michael Weber (xmw)]

xmw         10/08/24 23:08:44

  Added:                metadata.xml ChangeLog mupdf-0.6.ebuild
  Log:
  Initial commit.
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  app-text/mupdf/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/mupdf/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/mupdf/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<herd>no-herd</herd>
<maintainer>
<email>xmw@g.o</email>
<name>Michael Weber</name>
</maintainer>
</pkgmetadata>




1.1                  app-text/mupdf/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/mupdf/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/mupdf/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for app-text/mupdf
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/app-text/mupdf/ChangeLog,v 1.1 2010/08/24 23:08:44 xmw Exp $

*mupdf-0.6 (24 Aug 2010)

  24 Aug 2010; Michael Weber (xmw) <xmw@g.o> +mupdf-0.6.ebuild,
  +files/mupdf-0.6-buildsystem.patch, +metadata.xml:
  New ebuild for app-text/mupdf from sunrise. Fixes bug #280469. Thanks to
  Manu Wächter for the initial ebuilds.




1.1                  app-text/mupdf/mupdf-0.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/mupdf/mupdf-0.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/mupdf/mupdf-0.6.ebuild?rev=1.1&content-type=text/plain

Index: mupdf-0.6.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/mupdf/mupdf-0.6.ebuild,v 1.1 2010/08/24 23:08:44 xmw Exp $

EAPI=2

inherit eutils flag-o-matic multilib toolchain-funcs

DESCRIPTION="a lightweight PDF viewer and toolkit written in portable C"
HOMEPAGE="http://mupdf.com/"
SRC_URI="http://${PN}.com/download/source/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="X"

S=${WORKDIR}/${PN}

RDEPEND="media-libs/freetype:2
	media-libs/jbig2dec
	media-libs/jpeg
	media-libs/openjpeg
	X? ( x11-libs/libX11
		x11-libs/libXext )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

src_prepare() {
	epatch "${FILESDIR}"/${P}-buildsystem.patch
}

src_compile() {
	use x86 && append-cflags -DARCH_X86
	use amd64 && append-cflags -DARCH_X86_64

	my_pdfexe=
	use X || my_pdfexe="PDFVIEW_EXE="

	emake build=release ${my_pdfexe} CC="$(tc-getCC)" || die
}

src_install() {
	emake build=release ${my_pdfexe} prefix="${D}usr" \
		libprefix="${D}usr/$(get_libdir)" install || die

	insinto /usr/$(get_libdir)/pkgconfig
	doins debian/mupdf.pc || die

	if use X ; then
		domenu debian/mupdf.desktop || die
		doicon debian/mupdf.xpm || die
		doman debian/mupdf.1 || die
	fi
	doman debian/pdf{clean,draw,show}.1 || die
	dodoc README || die

	# avoid collision with app-text/poppler-utils
	mv "${D}"usr/bin/pdfinfo "${D}"usr/bin/mupdf_pdfinfo || die
}

pkg_postinst() {
	elog "pdfinfo was renamed to mupdf_pdfinfo"
}