[gentoo-commits] repo/gentoo:master commit in: games-action/formido/

[Austin English]

commit:     1ed45a84dabae7aff6833e58e4e718e45bd2c766
Author:     Austin English <wizardedit <AT> gentoo <DOT> org>
AuthorDate: Tue Jan 24 23:39:00 2017 +0000
Commit:     Austin English <wizardedit <AT> gentoo <DOT> org>
CommitDate: Tue Jan 24 23:39:17 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1ed45a84

games-action/formido: remove deprecated games eclass

Also update to EAPI 6

Gentoo-Bug: https://bugs.gentoo.org/574082

Package-Manager: Portage-2.3.2, Repoman-2.3.1

 games-action/formido/formido-1.0.1-r1.ebuild | 48 ++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

diff --git a/games-action/formido/formido-1.0.1-r1.ebuild b/games-action/formido/formido-1.0.1-r1.ebuild
new file mode 100644
index 00000000..3c45a44
--- /dev/null
+++ b/games-action/formido/formido-1.0.1-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit eutils toolchain-funcs
+
+DESCRIPTION="A shooting game in the spirit of Phobia games"
+HOMEPAGE="http://www.mhgames.org/oldies/formido/"
+SRC_URI="http://noe.falzon.free.fr/prog/${P}.tar.gz
+	http://koti.mbnet.fi/lsoft/formido/formido-music.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT=0
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE=""
+
+DEPEND="media-libs/libsdl[sound,video]
+	media-libs/sdl-image
+	media-libs/sdl-mixer"
+RDEPEND=${DEPEND}
+
+src_unpack() {
+	unpack ${P}.tar.gz
+	cd "${S}"/data || die
+	unpack ${PN}-music.tar.bz2
+}
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "s:g++:$(tc-getCXX):" \
+		-e "/^FLAGS=/s:$: ${CXXFLAGS}:" \
+		-e "/^LINKFLAGS=/s:=.*:=${LDFLAGS}:" \
+		-e "s:\${DATDIR}:/usr/share/${PN}/data:" \
+		-e "s:\${DEFCONFIGDIR}:/usr/share/${PN}:" \
+		Makefile || die
+}
+
+src_install() {
+	dobin ${PN}
+	insinto /usr/share/${PN}
+	doins -r ${PN}.cfg data
+	newicon data/icon.dat ${PN}.bmp
+	make_desktop_entry ${PN} Formido /usr/share/pixmaps/${PN}.bmp
+	dodoc README README-1.0.1
+}