Gentoo Archives: gentoo-commits

From: "Michał Górny" <mgorny@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-python/virtualenv/
Date: Sun, 31 Jan 2021 18:31:56
Message-Id: 1612117907.eca49bdb5a9e0b7a5fe7bcd38e2306c3d6eb1763.mgorny@gentoo
1 commit: eca49bdb5a9e0b7a5fe7bcd38e2306c3d6eb1763
2 Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
3 AuthorDate: Sun Jan 31 18:05:02 2021 +0000
4 Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
5 CommitDate: Sun Jan 31 18:31:47 2021 +0000
6 URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=eca49bdb
7
8 dev-python/virtualenv: Bump to 20.4.1
9
10 Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
11
12 dev-python/virtualenv/Manifest | 1 +
13 dev-python/virtualenv/virtualenv-20.4.1.ebuild | 99 ++++++++++++++++++++++++++
14 2 files changed, 100 insertions(+)
15
16 diff --git a/dev-python/virtualenv/Manifest b/dev-python/virtualenv/Manifest
17 index 32ee6cc6468..b02e70f308c 100644
18 --- a/dev-python/virtualenv/Manifest
19 +++ b/dev-python/virtualenv/Manifest
20 @@ -3,3 +3,4 @@ DIST virtualenv-20.2.1.tar.gz 8286055 BLAKE2B da77c51b352e979f05515107df49101a70
21 DIST virtualenv-20.3.0.tar.gz 9074217 BLAKE2B a5a00e39e31beff84e28e66d1cf6693804861ec0a3c0d0ee5c042e39a8edf894e89d6e78093fe1a4fecaf8b43bceff82e47a1ef7b8a92a1d2bc58d61411575b9 SHA512 5703a934d373d88670092febf26782f65303c65de93cffdd1a2ca06d6f2de4868378421f3ad96e3857eb99d0b60e7a77b0a2dbcf10561918efcbadb29a4ebf3b
22 DIST virtualenv-20.3.1.tar.gz 9077527 BLAKE2B 9932c75ffd42c2448a3f5dc49aa8b31f7cd169cc671e225a97fa75fabc3339728d0b280abec9616c11fc869dc696bfd17da05bf911c6f8a14947d710ade86897 SHA512 ee95e851e9e3597fd1691086d1d4dc72a41d6a143e9644be208cadbc1dfe7c8e562cd506a657ba1f77161d8d80a9f6f648b345e6533265b0e989c7ad39cc7680
23 DIST virtualenv-20.4.0.tar.gz 9079287 BLAKE2B a3c97537b9c35b463a0077e6020fd087a1cf7c22302ab9f57a7df951bd68d3b0e1bc323cdf12a71ca0fdba938364dbd970467d4f9f768ee688a5d9709949b08a SHA512 4dcc141441626ca2a565c1b51453ef0b7a05016037c44ae1017269e5b2ea98fb7fb29fb9cf3f8909a377824b5e52c5b40d2592e40931d8ad63ad850b8e5f23ac
24 +DIST virtualenv-20.4.1.tar.gz 10578390 BLAKE2B 6304d9296c69da098e2f348aeaa42ad46217975070661f4233a8e8b3c733f366bf2a44eaa887269923a1d0329aa06cd4095342025b595b2d8a0c31171c6b1264 SHA512 7e95174de155fa1b3671cfaa7c5a122dc0626f696c033226c20bec37747fd3c270ab2f843e83da91fc8a6bce53712f4eca5b8fb3d94a92e3ddc19f7e43cb83ee
25
26 diff --git a/dev-python/virtualenv/virtualenv-20.4.1.ebuild b/dev-python/virtualenv/virtualenv-20.4.1.ebuild
27 new file mode 100644
28 index 00000000000..2b78ff679af
29 --- /dev/null
30 +++ b/dev-python/virtualenv/virtualenv-20.4.1.ebuild
31 @@ -0,0 +1,99 @@
32 +# Copyright 1999-2021 Gentoo Authors
33 +# Distributed under the terms of the GNU General Public License v2
34 +
35 +EAPI=7
36 +
37 +PYTHON_COMPAT=( python3_{7..9} pypy3 )
38 +DISTUTILS_USE_SETUPTOOLS=manual
39 +
40 +inherit distutils-r1
41 +
42 +DESCRIPTION="Virtual Python Environment builder"
43 +HOMEPAGE="
44 + https://virtualenv.pypa.io/en/stable/
45 + https://pypi.org/project/virtualenv/
46 + https://github.com/pypa/virtualenv/
47 +"
48 +SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
49 +
50 +LICENSE="MIT"
51 +KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
52 +SLOT="0"
53 +IUSE="test"
54 +RESTRICT="!test? ( test )"
55 +
56 +RDEPEND="
57 + >=dev-python/appdirs-1.4.3[${PYTHON_USEDEP}]
58 + >=dev-python/distlib-0.3.1[${PYTHON_USEDEP}]
59 + >=dev-python/filelock-3[${PYTHON_USEDEP}]
60 + >=dev-python/setuptools-41[${PYTHON_USEDEP}]
61 + >=dev-python/six-1.9.0[${PYTHON_USEDEP}]
62 + $(python_gen_cond_dep '
63 + >=dev-python/importlib_metadata-0.12[${PYTHON_USEDEP}]
64 + ' python3_{6,7} pypy3)
65 + $(python_gen_cond_dep '
66 + >=dev-python/importlib_resources-1.0[${PYTHON_USEDEP}]
67 + ' python3_6 pypy3)"
68 +# coverage is used somehow magically in virtualenv, maybe it actually
69 +# tests something useful
70 +BDEPEND="
71 + dev-python/setuptools_scm[${PYTHON_USEDEP}]
72 + test? (
73 + ${RDEPEND}
74 + $(python_gen_cond_dep '
75 + dev-python/coverage[${PYTHON_USEDEP}]
76 + dev-python/flaky[${PYTHON_USEDEP}]
77 + >=dev-python/pip-20.0.2[${PYTHON_USEDEP}]
78 + >=dev-python/pytest-5[${PYTHON_USEDEP}]
79 + >=dev-python/pytest-freezegun-0.4.1[${PYTHON_USEDEP}]
80 + >=dev-python/pytest-mock-2.0.0[${PYTHON_USEDEP}]
81 + >=dev-python/pytest-timeout-1.3.4[${PYTHON_USEDEP}]
82 + dev-python/wheel[${PYTHON_USEDEP}]
83 + >=dev-python/packaging-20.0[${PYTHON_USEDEP}]
84 + ' 'python3*')
85 + )"
86 +
87 +distutils_enable_sphinx docs \
88 + dev-python/sphinx_rtd_theme \
89 + dev-python/towncrier
90 +
91 +src_configure() {
92 + export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
93 +}
94 +
95 +python_test() {
96 + local deselect=(
97 + tests/unit/activation/test_xonsh.py
98 + tests/unit/seed/embed/test_bootstrap_link_via_app_data.py::test_seed_link_via_app_data
99 + tests/unit/create/test_creator.py::test_cross_major
100 + )
101 + [[ ${EPYTHON} == pypy3 ]] && deselect+=(
102 + 'tests/unit/create/test_creator.py::test_create_no_seed[root-pypy3-posix-copies-isolated]'
103 + 'tests/unit/create/test_creator.py::test_create_no_seed[root-pypy3-posix-copies-global]'
104 + 'tests/unit/create/test_creator.py::test_create_no_seed[venv-pypy3-posix-copies-isolated]'
105 + 'tests/unit/create/test_creator.py::test_create_no_seed[venv-pypy3-posix-copies-global]'
106 + 'tests/unit/create/test_creator.py::test_zip_importer_can_import_setuptools'
107 + 'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.9-64-bin-]'
108 + 'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.9--bin-]'
109 + 'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7-64-bin-]'
110 + 'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7--bin-]'
111 + 'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3-64-bin-]'
112 + 'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3--bin-]'
113 + 'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.9-64-bin-]'
114 + 'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.9--bin-]'
115 + 'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7-64-bin-]'
116 + 'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7--bin-]'
117 + 'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3-64-bin-]'
118 + 'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3--bin-]'
119 + )
120 +
121 + distutils_install_for_testing --via-root
122 + pytest -vv ${deselect[@]/#/--deselect } ||
123 + die "Tests fail with ${EPYTHON}"
124 +}
125 +
126 +pkg_postinst() {
127 + elog "Please note that while virtualenv package no longer supports"
128 + elog "Python 2.7, you can still create py2.7 virtualenvs via:"
129 + elog " $ virtualenv -p 2.7 ..."
130 +}