[gentoo-commits] gentoo-x86 commit in games-board/gnubg: ChangeLog gnubg-20101126.ebuild

[Michael Sterrett (mr_bones_)]

mr_bones_    10/11/28 02:11:21

  Modified:             ChangeLog
  Added:                gnubg-20101126.ebuild
  Log:
  version bump
  
  (Portage version: 2.1.9.24/cvs/Linux i686)

Revision  Changes    Path
1.55                 games-board/gnubg/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-board/gnubg/ChangeLog?rev=1.55&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-board/gnubg/ChangeLog?rev=1.55&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-board/gnubg/ChangeLog?r1=1.54&r2=1.55

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-board/gnubg/ChangeLog,v
retrieving revision 1.54
retrieving revision 1.55
diff -u -r1.54 -r1.55
--- ChangeLog	29 Apr 2010 15:37:45 -0000	1.54
+++ ChangeLog	28 Nov 2010 02:11:19 -0000	1.55
@@ -1,6 +1,12 @@
 # ChangeLog for games-board/gnubg
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-board/gnubg/ChangeLog,v 1.54 2010/04/29 15:37:45 tupone Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-board/gnubg/ChangeLog,v 1.55 2010/11/28 02:11:19 mr_bones_ Exp $
+
+*gnubg-20101126 (28 Nov 2010)
+
+  28 Nov 2010; Michael Sterrett <mr_bones_@g.o>
+  +gnubg-20101126.ebuild, +files/gnubg-20101126-build.patch:
+  version bump
 
   29 Apr 2010; Tupone Alfredo <tupone@g.o> gnubg-20100107.ebuild:
   Force python2 fixing bug #312239 by arfrever@g.o



1.1                  games-board/gnubg/gnubg-20101126.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-board/gnubg/gnubg-20101126.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-board/gnubg/gnubg-20101126.ebuild?rev=1.1&content-type=text/plain

Index: gnubg-20101126.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-board/gnubg/gnubg-20101126.ebuild,v 1.1 2010/11/28 02:11:19 mr_bones_ Exp $

EAPI=2
PYTHON_DEPEND="python? 2"
inherit autotools eutils python games

DESCRIPTION="GNU BackGammon"
HOMEPAGE="http://www.gnubg.org/"
SRC_URI="http://www.gnubg.org/media/sources/${PN}-source-SNAPSHOT-${PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
IUSE="gtk opengl python threads"

GTK_DEPS="
	x11-libs/gtk+:2
	x11-libs/cairo
	x11-libs/pango"
RDEPEND="dev-libs/glib:2
	media-libs/libpng
	dev-libs/libxml2
	media-libs/freetype:2
	media-libs/libcanberra
	gtk? ( ${GTK_DEPS} )
	opengl? (
		${GTK_DEPS}
		x11-libs/gtkglext
		>=media-libs/ftgl-2.1.2-r1
	)
	sys-libs/readline
	python? ( dev-lang/python )
	media-fonts/ttf-bitstream-vera
	virtual/libintl
	dev-db/sqlite:3"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	sys-devel/gettext"

S=${WORKDIR}/${PN}

pkg_setup() {
	python_set_active_version 2
	games_pkg_setup
}

src_prepare() {
	# use ${T} instead of /tmp for constructing credits (bug #298275)
	sed -i \
		-e 's:/tmp:${T}:' \
		credits.sh \
		|| die 'sed failed'
	epatch "${FILESDIR}"/${P}-build.patch
	python_convert_shebangs -r 2 python-config
	eautoreconf
}

src_configure() {
	egamesconf \
		--disable-dependency-tracking \
		--localedir=/usr/share/locale \
		--docdir=/usr/share/doc/${PF}/html \
		$(use_enable threads) \
		$(use_with python) \
		$(use gtk || use opengl && echo --with-gtk) \
		$(use_with opengl board3d)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	insinto "${GAMES_DATADIR}/${PN}"
	doins ${PN}.weights *bd || die "doins failed"
	dodoc AUTHORS README NEWS
	dosym /usr/share/fonts/ttf-bitstream-vera "${GAMES_DATADIR}"/${PN}/fonts
	newicon textures/logo.png gnubg.png
	make_desktop_entry "gnubg -w" "GNU Backgammon"
	prepgamesdirs
}