[gentoo-commits] gentoo-x86 commit in net-im/qutim: metadata.xml qutim-0.3.0.ebuild ChangeLog

[Davide Pesavento (pesa)]

pesa        12/04/06 19:53:57

  Modified:             metadata.xml ChangeLog
  Added:                qutim-0.3.0.ebuild
  Log:
  Version bump. Ebuild rewritten and largely simplified.
  
  (Portage version: 2.2.0_alpha100/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  net-im/qutim/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/qutim/metadata.xml?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/qutim/metadata.xml?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/qutim/metadata.xml?r1=1.2&r2=1.3

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/qutim/metadata.xml,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- metadata.xml	13 Jun 2011 15:12:17 -0000	1.2
+++ metadata.xml	6 Apr 2012 19:53:57 -0000	1.3
@@ -3,13 +3,23 @@
 <pkgmetadata>
 <herd>qt</herd>
 <use>
-	<flag name="irc">Enable irc support</flag>
-	<flag name="histman">Enable histman plugin</flag>
-	<flag name="mrim">Enable mrim plugin</flag>
-	<flag name="vkontakte">Enable vkontakte plugin</flag>
-	<flag name="yandexnarod">Enable yanderx.narod plugin</flag>
+	<flag name="aspell">Enable spellchecking using <pkg>app-text/aspell</pkg></flag>
+	<flag name="awn">Enable integration with <pkg>gnome-extra/avant-window-navigator</pkg></flag>
+	<flag name="crypt">Enable AES crypto plugin</flag>
+	<flag name="histman">Enable history importer plugin</flag>
+	<flag name="hunspell">Enable spellchecking using <pkg>app-text/hunspell</pkg></flag>
+	<flag name="irc">Enable IRC protocol support</flag>
+	<flag name="kinetic">Enable Growl-like kinetic popups plugin</flag>
+	<flag name="mrim">Enable mail.ru protocol support</flag>
+	<flag name="multimedia">Add sound support via <pkg>x11-libs/qt-multimedia</pkg></flag>
+	<flag name="phonon">Add sound support via <pkg>media-libs/phonon</pkg> or <pkg>x11-libs/qt-phonon</pkg></flag>
+	<flag name="purple">Enable libpurple-based protocol support</flag>
+	<flag name="qml">Enable QtQuick-based chat plugin</flag>
+	<flag name="sdl">Add sound support via <pkg>media-libs/sdl-mixer</pkg></flag>
+	<flag name="telepathy">Enable telepathy-based protocol support</flag>
+	<flag name="vkontakte">Enable vkontakte protocol support</flag>
+	<flag name="webkit">Enable Adium-like WebView plugin</flag>
+	<flag name="xscreensaver">Use X screensaver protocol extension to monitor idle/active status based on mouse/keyboard events</flag>
+	<flag name="yandexnarod">Enable yandex.narod plugin</flag>
 </use>
-<longdescription lang="en">
-</longdescription>
 </pkgmetadata>
-



1.14                 net-im/qutim/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/qutim/ChangeLog?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/qutim/ChangeLog?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/qutim/ChangeLog?r1=1.13&r2=1.14

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/qutim/ChangeLog,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- ChangeLog	16 Mar 2012 11:58:25 -0000	1.13
+++ ChangeLog	6 Apr 2012 19:53:57 -0000	1.14
@@ -1,6 +1,12 @@
 # ChangeLog for net-im/qutim
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/qutim/ChangeLog,v 1.13 2012/03/16 11:58:25 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/qutim/ChangeLog,v 1.14 2012/04/06 19:53:57 pesa Exp $
+
+*qutim-0.3.0 (06 Apr 2012)
+
+  06 Apr 2012; Davide Pesavento <pesa@g.o> +qutim-0.3.0.ebuild,
+  metadata.xml:
+  Version bump. Ebuild rewritten and largely simplified.
 
 *qutim-0.2.0-r4 (16 Mar 2012)
 



1.1                  net-im/qutim/qutim-0.3.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/qutim/qutim-0.3.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/qutim/qutim-0.3.0.ebuild?rev=1.1&content-type=text/plain

Index: qutim-0.3.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/qutim/qutim-0.3.0.ebuild,v 1.1 2012/04/06 19:53:57 pesa Exp $

EAPI=4

LANGS="ar bg cs de en_GB ru uk zh_CN"

inherit qt4-r2 cmake-utils

DESCRIPTION="Qt4-based multi-protocol instant messenger"
HOMEPAGE="http://www.qutim.org"
SRC_URI="http://www.qutim.org/downloads/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="aspell awn ayatana crypt dbus debug doc histman hunspell irc jabber kde kinetic mrim
	multimedia oscar phonon purple qml sdl +ssl telepathy vkontakte webkit +xscreensaver"

REQUIRED_USE="
	oscar? ( ssl )
"

QT_PV="4.7.0:4"

RDEPEND="
	x11-libs/libqxt
	>=x11-libs/qt-core-${QT_PV}[ssl?]
	>=x11-libs/qt-gui-${QT_PV}
	>=x11-libs/qt-script-${QT_PV}
	aspell? ( app-text/aspell )
	awn? ( >=x11-libs/qt-dbus-${QT_PV} )
	ayatana? ( >=dev-libs/libindicate-qt-0.2.2 )
	crypt? ( app-crypt/qca:2 )
	dbus? ( >=x11-libs/qt-dbus-${QT_PV} )
	debug? ( >=x11-libs/qt-declarative-${QT_PV} )
	histman? ( >=x11-libs/qt-sql-${QT_PV} )
	hunspell? ( app-text/hunspell )
	jabber? ( net-libs/jreen )
	kde? (
		dev-util/automoc
		kde-base/kdelibs:4
	)
	kinetic? ( >=x11-libs/qt-declarative-${QT_PV} )
	multimedia? ( >=x11-libs/qt-multimedia-${QT_PV} )
	oscar? ( app-crypt/qca:2 )
	phonon? (
		kde? ( media-libs/phonon )
		!kde? ( || ( >=x11-libs/qt-phonon-${QT_PV} media-libs/phonon ) )
	)
	purple? ( net-im/pidgin )
	qml? (
		>=x11-libs/qt-declarative-${QT_PV}
		>=x11-libs/qt-opengl-${QT_PV}
	)
	sdl? ( media-libs/sdl-mixer )
	telepathy? ( net-libs/telepathy-qt )
	vkontakte? ( >=x11-libs/qt-webkit-${QT_PV} )
	webkit? ( >=x11-libs/qt-webkit-${QT_PV} )
	xscreensaver? ( x11-libs/libXScrnSaver )
"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	doc? ( app-doc/doxygen )
"

src_prepare() {
	base_src_prepare

	# fix automagic dep on libXScrnSaver
	if ! use xscreensaver; then
		sed -i -e '/XSS xscrnsaver/d' \
			core/src/corelayers/idledetector/CMakeLists.txt || die
	fi

	# remove unwanted translations
	local lang
	for lang in ${LANGS}; do
		use linguas_${lang} || rm -f translations/modules/*/${lang}.{po,ts}
	done
}

src_configure() {
	local mycmakeargs=(
		-DSYSTEM_JREEN=ON
		$(cmake-utils_use_with doc DOXYGEN)
		$(cmake-utils_use doc QUTIM_GENERATE_DOCS)
		# plugins
		$(cmake-utils_use aspell ASPELLER)
		$(cmake-utils_use awn)
		$(cmake-utils_use ayatana INDICATOR)
		$(cmake-utils_use crypt AESCRYPTO)
		$(cmake-utils_use dbus DBUSAPI)
		$(cmake-utils_use dbus DBUSNOTIFICATIONS)
		$(cmake-utils_use dbus NOWPLAYING)
		$(cmake-utils_use debug LOGGER)
		$(cmake-utils_use histman)
		$(cmake-utils_use hunspell HUNSPELLER)
		$(cmake-utils_use kde KDEINTEGRATION)
		$(cmake-utils_use kinetic KINETICPOPUPS)
		$(cmake-utils_use multimedia MULTIMEDIABACKEND)
		$(cmake-utils_use phonon PHONONSOUND)
		$(cmake-utils_use qml QMLCHAT)
		$(cmake-utils_use sdl SDLSOUND)
		$(cmake-utils_use webkit ADIUMWEBVIEW)
		-DHAIKUNOTIFICATIONS=OFF
		-DUNITYLAUNCHER=OFF
		-DUPDATER=OFF
		# protocols
		$(cmake-utils_use irc)
		$(cmake-utils_use jabber)
		$(cmake-utils_use mrim)
		$(cmake-utils_use oscar)
		$(cmake-utils_use purple QUETZAL)
		$(cmake-utils_use telepathy ASTRAL)
		$(cmake-utils_use vkontakte)
	)
	cmake-utils_src_configure
}