[gentoo-commits] repo/gentoo:master commit in: dev-libs/atcore/

[Michael Palimaka]

commit:     f78d336c8792bd154dce291e2647ecab8362ac4f
Author:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
AuthorDate: Thu Jan 25 13:26:08 2018 +0000
Commit:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
CommitDate: Thu Jan 25 13:26:44 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f78d336c

dev-libs/atcore: new package

Package-Manager: Portage-2.3.19, Repoman-2.3.6

 dev-libs/atcore/Manifest            |  1 +
 dev-libs/atcore/atcore-1.0.0.ebuild | 51 +++++++++++++++++++++++++++++++++++++
 dev-libs/atcore/metadata.xml        | 11 ++++++++
 3 files changed, 63 insertions(+)

diff --git a/dev-libs/atcore/Manifest b/dev-libs/atcore/Manifest
new file mode 100644
index 00000000000..680d872e729
--- /dev/null
+++ b/dev-libs/atcore/Manifest
@@ -0,0 +1 @@
+DIST atcore-1.0.0.tar.xz 169116 BLAKE2B 8aaafe18edfbb0dcbe08b99c9cfba2d2390a9e9aaf5ed8ebbc61b6320c37ac4e893a7c64e5c56a131e32ec112fa0d9e253749e634661834de3d03e2cced97dea SHA512 8be63850d939aa9b89651252e91cd3295d52d2d0603f88b846783cca25fc0e29dd3569bfef97aeaf6c115a3bc3328fb127e126b20aaf67faf1c319ac8be7b88b

diff --git a/dev-libs/atcore/atcore-1.0.0.ebuild b/dev-libs/atcore/atcore-1.0.0.ebuild
new file mode 100644
index 00000000000..357745bd6e6
--- /dev/null
+++ b/dev-libs/atcore/atcore-1.0.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils kde5-functions
+
+DESCRIPTION="API to manage the serial connection between the computer and 3D Printers"
+SRC_URI="mirror://kde/stable/${PN}/${PV}/${P}.tar.xz"
+HOMEPAGE="https://atelier.kde.org/"
+
+LICENSE="|| ( LGPL-2.1+ LGPL-3 ) gui? ( GPL-3+ )"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc gui test"
+
+RDEPEND="
+	$(add_qt_dep qtcore)
+	$(add_qt_dep qtserialport)
+	gui? (
+		$(add_qt_dep qtcharts)
+		$(add_qt_dep qtgui)
+		$(add_qt_dep qtwidgets)
+	)
+"
+DEPEND="${RDEPEND}
+	$(add_frameworks_dep extra-cmake-modules)
+	doc? ( app-doc/doxygen[dot] )
+	test? ( $(add_qt_dep qttest) )
+"
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	sed -e "s/${PN}/${PF}/" -i doc/CMakeLists.txt || die
+
+	use gui || punt_bogus_dep Qt5 Charts
+	if ! use test; then
+		cmake_comment_add_subdirectory unittests
+		punt_bogus_dep Qt5 Test
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_DOCS=$(usex doc)
+		-DBUILD_TEST_GUI=$(usex gui)
+	)
+
+	cmake-utils_src_configure
+}

diff --git a/dev-libs/atcore/metadata.xml b/dev-libs/atcore/metadata.xml
new file mode 100644
index 00000000000..8ded8878afc
--- /dev/null
+++ b/dev-libs/atcore/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>kde@g.o</email>
+		<name>Gentoo KDE Project</name>
+	</maintainer>
+	<use>
+		<flag name="gui">Build test GUI</flag>
+	</use>
+</pkgmetadata>