[gentoo-commits] gentoo-x86 commit in games-strategy/0ad: ChangeLog metadata.xml 0ad-0.0.16_alpha-r1.ebuild 0ad-0.0.16_alpha.ebuild

[Julian Ospald (hasufell)]

hasufell    14/05/22 12:06:23

  Modified:             ChangeLog metadata.xml
  Added:                0ad-0.0.16_alpha-r1.ebuild
  Removed:              0ad-0.0.16_alpha.ebuild
  Log:
  restrict broken tests wrt #511006, add lobby USE flag, rm obsolete fam USE flag, install ActorEditor binary for +editor
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key BDEED020)

Revision  Changes    Path
1.2                  games-strategy/0ad/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/0ad/ChangeLog?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/0ad/ChangeLog?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/0ad/ChangeLog?r1=1.1&r2=1.2

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-strategy/0ad/ChangeLog,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- ChangeLog	21 May 2014 18:09:13 -0000	1.1
+++ ChangeLog	22 May 2014 12:06:23 -0000	1.2
@@ -1,6 +1,13 @@
 # ChangeLog for games-strategy/0ad
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-strategy/0ad/ChangeLog,v 1.1 2014/05/21 18:09:13 hasufell Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/0ad/ChangeLog,v 1.2 2014/05/22 12:06:23 hasufell Exp $
+
+*0ad-0.0.16_alpha-r1 (22 May 2014)
+
+  22 May 2014; Julian Ospald <hasufell@g.o> -0ad-0.0.16_alpha.ebuild,
+  +0ad-0.0.16_alpha-r1.ebuild, metadata.xml:
+  restrict broken tests wrt #511006, add lobby USE flag, rm obsolete fam USE
+  flag, install ActorEditor binary for +editor
 
 *0ad-0.0.16_alpha (21 May 2014)
 



1.2                  games-strategy/0ad/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/0ad/metadata.xml?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/0ad/metadata.xml?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/0ad/metadata.xml?r1=1.1&r2=1.2

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-strategy/0ad/metadata.xml,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- metadata.xml	21 May 2014 18:09:13 -0000	1.1
+++ metadata.xml	22 May 2014 12:06:23 -0000	1.2
@@ -8,5 +8,7 @@
 	</maintainer>
 	<use>
 		<flag name="editor">Include Atlas scenario editor projects</flag>
+		<flag name="lobby">Enable the use of <pkg>net-libs/gloox</pkg>
+			and the multiplayer lobby</flag>
 	</use>
 </pkgmetadata>



1.1                  games-strategy/0ad/0ad-0.0.16_alpha-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/0ad/0ad-0.0.16_alpha-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/0ad/0ad-0.0.16_alpha-r1.ebuild?rev=1.1&content-type=text/plain

Index: 0ad-0.0.16_alpha-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/0ad/0ad-0.0.16_alpha-r1.ebuild,v 1.1 2014/05/22 12:06:23 hasufell Exp $

EAPI=5

WX_GTK_VER="2.8"

inherit eutils wxwidgets toolchain-funcs gnome2-utils games

MY_P=0ad-${PV/_/-}
DESCRIPTION="A free, real-time strategy game"
HOMEPAGE="http://wildfiregames.com/0ad/"
SRC_URI="http://releases.wildfiregames.com/${MY_P}-unix-build.tar.xz"

LICENSE="GPL-2 LGPL-2.1 MIT CC-BY-SA-3.0 ZLIB"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="editor +lobby pch sound test"
RESTRICT="test"

RDEPEND="
	dev-lang/spidermonkey:24
	dev-libs/boost
	dev-libs/icu
	dev-libs/libxml2
	~games-strategy/0ad-data-${PV}
	media-gfx/nvidia-texture-tools
	media-libs/libpng:0
	media-libs/libsdl[X,opengl,video]
	net-libs/enet:1.3
	net-libs/miniupnpc
	net-misc/curl
	sys-libs/zlib
	virtual/jpeg
	virtual/opengl
	x11-libs/libX11
	x11-libs/libXcursor
	editor? ( x11-libs/wxGTK:${WX_GTK_VER}[X,opengl] )
	lobby? ( net-libs/gloox )
	sound? ( media-libs/libogg
		media-libs/libvorbis
		media-libs/openal )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	test? ( dev-lang/perl )"

S=${WORKDIR}/${MY_P}

src_prepare() {
	epatch "${FILESDIR}"/${P}-gentoo.patch
}

src_configure() {
	local myconf=(
		--with-system-nvtt
		--with-system-enet
		--with-system-miniupnpc
		--with-system-mozjs24
		--minimal-flags
		$(usex pch "" "--without-pch")
		$(usex test "" "--without-tests")
		$(usex sound "" "--without-audio")
		$(usex editor "--atlas" "")
		$(usex lobby "" "--without-lobby")
		--collada
		--bindir="${GAMES_BINDIR}"
		--libdir="$(games_get_libdir)"/${PN}
		--datadir="${GAMES_DATADIR}"/${PN}
		)

	# stock premake4 does not work, use the shipped one
	emake -C "${S}"/build/premake/premake4/build/gmake.unix

	# regenerate scripts.c so our patch applies
	cd "${S}"/build/premake/premake4 || die
	"${S}"/build/premake/premake4/bin/release/premake4 embed || die

	# rebuild premake again... this is the most stupid build system
	emake -C "${S}"/build/premake/premake4/build/gmake.unix clean
	emake -C "${S}"/build/premake/premake4/build/gmake.unix

	# run premake to create build scripts
	cd "${S}"/build/premake || die
	"${S}"/build/premake/premake4/bin/release/premake4 \
		--file="premake4.lua" \
		--outpath="../workspaces/gcc/" \
		--platform=$(usex amd64 "x64" "x32") \
		--os=linux \
		"${myconf[@]}" \
		gmake || die "Premake failed"
}

src_compile() {
	# build 3rd party fcollada
	emake -C libraries/source/fcollada/src

	# build 0ad
	emake -C build/workspaces/gcc verbose=1
}

src_test() {
	cd binaries/system || die
	./test -libdir "${S}/binaries/system" || die "test phase failed"
}

src_install() {
	dogamesbin binaries/system/pyrogenesis
	use editor && dogamesbin binaries/system/ActorEditor

	insinto "${GAMES_DATADIR}"/${PN}
	doins -r binaries/data/l10n

	exeinto "$(games_get_libdir)"/${PN}
	doexe binaries/system/libCollada.so
	use editor && doexe binaries/system/libAtlasUI.so

	dodoc binaries/system/readme.txt
	doicon -s 128 build/resources/${PN}.png
	games_make_wrapper ${PN} "${GAMES_BINDIR}/pyrogenesis"
	use editor &&
		games_make_wrapper ${PN}-ActorEditor "${GAMES_BINDIR}/ActorEditor"
	make_desktop_entry ${PN}

	prepgamesdirs
}

pkg_preinst() {
	games_pkg_preinst
	gnome2_icon_savelist
}

pkg_postinst() {
	games_pkg_postinst
	gnome2_icon_cache_update
}

pkg_postrm() {
	gnome2_icon_cache_update
}