[gentoo-commits] gentoo-x86 commit in app-misc/task: ChangeLog task-2.1.1.ebuild

[Tim Harder (radhermit)]

radhermit    12/08/01 06:55:57

  Modified:             ChangeLog
  Added:                task-2.1.1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha120/cvs/Linux x86_64)

Revision  Changes    Path
1.33                 app-misc/task/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/task/ChangeLog?rev=1.33&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/task/ChangeLog?rev=1.33&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/task/ChangeLog?r1=1.32&r2=1.33

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/task/ChangeLog,v
retrieving revision 1.32
retrieving revision 1.33
diff -u -r1.32 -r1.33
--- ChangeLog	18 Mar 2012 04:19:01 -0000	1.32
+++ ChangeLog	1 Aug 2012 06:55:57 -0000	1.33
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/task
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/task/ChangeLog,v 1.32 2012/03/18 04:19:01 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/task/ChangeLog,v 1.33 2012/08/01 06:55:57 radhermit Exp $
+
+*task-2.1.1 (01 Aug 2012)
+
+  01 Aug 2012; Tim Harder <radhermit@g.o> +task-2.1.1.ebuild:
+  Version bump.
 
 *task-2.0.0-r1 (18 Mar 2012)
 



1.1                  app-misc/task/task-2.1.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/task/task-2.1.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/task/task-2.1.1.ebuild?rev=1.1&content-type=text/plain

Index: task-2.1.1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/task/task-2.1.1.ebuild,v 1.1 2012/08/01 06:55:57 radhermit Exp $

EAPI=4

inherit eutils cmake-utils bash-completion-r1

DESCRIPTION="A task management tool with a command-line interface"
HOMEPAGE="http://taskwarrior.org/projects/show/taskwarrior/"
SRC_URI="http://taskwarrior.org/download/${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="lua vim-syntax zsh-completion"

DEPEND="lua? ( dev-lang/lua )"
RDEPEND="${DEPEND}"

src_prepare() {
	# Use the correct directory locations
	sed -i -e "s:/usr/local/share/doc/task/rc:/usr/share/task/rc:" \
		doc/man/taskrc.5.in doc/man/task-tutorial.5.in doc/man/task-color.5.in || die
	sed -i -e "s:/usr/local/bin:/usr/bin:" doc/man/task-faq.5.in scripts/add-ons/* || die

	# Don't automatically install scripts
	sed -i -e '/scripts/d' CMakeLists.txt || die

	epatch "${FILESDIR}"/${PN}-2.0.0_beta4-rcdir.patch
	epatch "${FILESDIR}"/${PN}-1.9.4-lua-automagic.patch
}

src_configure() {
	mycmakeargs=(
		$(cmake-utils_use_enable lua LUA)
		-DTASK_DOCDIR=/usr/share/doc/${PF}
	)

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	newbashcomp scripts/bash/task.sh task

	if use lua ; then
		insinto /usr/share/${PN}/extensions
		doins scripts/extensions/*
	fi

	if use vim-syntax ; then
		rm scripts/vim/README
		insinto /usr/share/vim/vimfiles
		doins -r scripts/vim/*
	fi

	if use zsh-completion ; then
		insinto /usr/share/zsh/site-functions
		doins scripts/zsh/*
	fi

	exeinto /usr/share/${PN}/scripts
	doexe scripts/add-ons/*
}