[gentoo-commits] gentoo-x86 commit in dev-java/rhino: ChangeLog rhino-1.7.2-r1.ebuild

[Alistair Bush (ali_bush)]

ali_bush    10/04/01 20:12:58

  Modified:             ChangeLog
  Added:                rhino-1.7.2-r1.ebuild
  Log:
  Stop build downloading deps #312175.
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.64                 dev-java/rhino/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/rhino/ChangeLog?rev=1.64&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/rhino/ChangeLog?rev=1.64&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/rhino/ChangeLog?r1=1.63&r2=1.64

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-java/rhino/ChangeLog,v
retrieving revision 1.63
retrieving revision 1.64
diff -u -r1.63 -r1.64
--- ChangeLog	27 Mar 2010 22:23:17 -0000	1.63
+++ ChangeLog	1 Apr 2010 20:12:57 -0000	1.64
@@ -1,6 +1,11 @@
 # ChangeLog for dev-java/rhino
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/rhino/ChangeLog,v 1.63 2010/03/27 22:23:17 ali_bush Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-java/rhino/ChangeLog,v 1.64 2010/04/01 20:12:57 ali_bush Exp $
+
+*rhino-1.7.2-r1 (01 Apr 2010)
+
+  01 Apr 2010; Alistair Bush <ali_bush@g.o> +rhino-1.7.2-r1.ebuild:
+  Stop build downloading deps #312175.
 
 *rhino-1.7.2 (27 Mar 2010)
 



1.1                  dev-java/rhino/rhino-1.7.2-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/rhino/rhino-1.7.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/rhino/rhino-1.7.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: rhino-1.7.2-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/rhino/rhino-1.7.2-r1.ebuild,v 1.1 2010/04/01 20:12:57 ali_bush Exp $

EAPI="1"
JAVA_PKG_IUSE="doc examples source"
inherit java-pkg-2 java-ant-2 eutils versionator

MY_P="${PN}$(replace_version_separator 1 _ $(replace_version_separator 2 R))"

DESCRIPTION="An open-source implementation of JavaScript written in Java."
SRC_URI="ftp://ftp.mozilla.org/pub/mozilla.org/js/${MY_P}.zip
	mirror://gentoo/rhino-swing-ex-1.0.zip"
HOMEPAGE="http://www.mozilla.org/rhino/"
# dual license for rhino and BSD-2 for the swing-ex from Sun's tutorial
LICENSE="|| ( MPL-1.1 GPL-2 ) BSD-2"
SLOT="1.6"
KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~x86-macos"
IUSE=""

S="${WORKDIR}/${MY_P}"

CDEPEND="=dev-java/xml-xmlbeans-1*
	dev-java/jsr173:0"
RDEPEND=">=virtual/jre-1.5
	${CDEPEND}"
DEPEND=">=virtual/jdk-1.5
	app-arch/unzip
	${CDEPEND}"

src_unpack() {
	unpack ${MY_P}.zip
	cd "${S}"

	# don't download src.zip from Sun
	epatch "${FILESDIR}/rhino-1.6-noget.patch"

	rm -v *.jar || die
	rm -rf docs/apidocs || die

	local dir="toolsrc/org/mozilla/javascript/tools/debugger/downloaded"
	mkdir ${dir} || die
	cp "${DISTDIR}/rhino-swing-ex-1.0.zip" ${dir}/swingExSrc.zip || die

	mkdir lib/ && cd lib/ || die
	java-pkg_jar-from xml-xmlbeans-1 xbean.jar
	java-pkg_jar-from jsr173 jsr173.jar jsr173_1.0_api.jar

	# Stop downloading of deps
	cd "${S}"
	mkdir -p build/tmp-xbean
	touch build/tmp-xbean/xbean.zip
}

src_install() {
	java-pkg_dojar build/${MY_P}/js.jar

	java-pkg_dolauncher jsscript-${SLOT} \
		--main org.mozilla.javascript.tools.shell.Main

	use doc && java-pkg_dojavadoc "build/${MY_P}/javadoc"
	use examples && java-pkg_doexamples examples
	use source && java-pkg_dosrc {src,toolsrc,xmlimplsrc}/org
}