[gentoo-commits] gentoo-x86 commit in net-im/ejabberd: ChangeLog ejabberd-1.1.4-r1.ebuild ejabberd-1.1.4-r2.ebuild

[Patrick Lauer (patrick)]

patrick     09/02/01 10:01:07

  Modified:             ChangeLog ejabberd-1.1.4-r1.ebuild
  Added:                ejabberd-1.1.4-r2.ebuild
  Log:
  Fixing doc installation, closes #155101
  (Portage version: 2.2_rc23/cvs/Linux x86_64)

Revision  Changes    Path
1.50                 net-im/ejabberd/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/ejabberd/ChangeLog?rev=1.50&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/ejabberd/ChangeLog?rev=1.50&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/ejabberd/ChangeLog?r1=1.49&r2=1.50

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/ejabberd/ChangeLog,v
retrieving revision 1.49
retrieving revision 1.50
diff -u -r1.49 -r1.50
--- ChangeLog	1 Feb 2009 09:47:34 -0000	1.49
+++ ChangeLog	1 Feb 2009 10:01:06 -0000	1.50
@@ -1,6 +1,11 @@
 # ChangeLog for net-im/ejabberd
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/ejabberd/ChangeLog,v 1.49 2009/02/01 09:47:34 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/ejabberd/ChangeLog,v 1.50 2009/02/01 10:01:06 patrick Exp $
+
+*ejabberd-1.1.4-r2 (01 Feb 2009)
+
+  01 Feb 2009; Patrick Lauer <patrick@g.o> +ejabberd-1.1.4-r2.ebuild:
+  Fixing doc installation, closes #155101
 
 *ejabberd-2.0.2-r1 (01 Feb 2009)
 



1.5                  net-im/ejabberd/ejabberd-1.1.4-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/ejabberd/ejabberd-1.1.4-r1.ebuild?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/ejabberd/ejabberd-1.1.4-r1.ebuild?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/ejabberd/ejabberd-1.1.4-r1.ebuild?r1=1.4&r2=1.5

Index: ejabberd-1.1.4-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/ejabberd/ejabberd-1.1.4-r1.ebuild,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ejabberd-1.1.4-r1.ebuild	22 Feb 2008 14:58:22 -0000	1.4
+++ ejabberd-1.1.4-r1.ebuild	1 Feb 2009 10:01:06 -0000	1.5
@@ -1,6 +1,6 @@
-# Copyright 1999-2008 Gentoo Foundation
+# Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/ejabberd/ejabberd-1.1.4-r1.ebuild,v 1.4 2008/02/22 14:58:22 caleb Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/ejabberd/ejabberd-1.1.4-r1.ebuild,v 1.5 2009/02/01 10:01:06 patrick Exp $
 
 inherit eutils multilib
 



1.1                  net-im/ejabberd/ejabberd-1.1.4-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/ejabberd/ejabberd-1.1.4-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/ejabberd/ejabberd-1.1.4-r2.ebuild?rev=1.1&content-type=text/plain

Index: ejabberd-1.1.4-r2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/ejabberd/ejabberd-1.1.4-r2.ebuild,v 1.1 2009/02/01 10:01:06 patrick Exp $

inherit eutils multilib

JABBER_ETC="/etc/jabber"
JABBER_RUN="/var/run/jabber"
JABBER_SPOOL="/var/spool/jabber"
JABBER_LOG="/var/log/jabber"

DESCRIPTION="The Erlang Jabber Daemon"
HOMEPAGE="http://ejabberd.jabber.ru/"
SRC_URI="http://process-one.net/en/projects/${PN}/download/${PV}/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug mod_irc mod_muc mod_pubsub ldap odbc ssl web zlib"

DEPEND=">=net-im/jabber-base-0.01
	>=dev-libs/expat-1.95
	>=dev-lang/erlang-10.2.0
	odbc? ( dev-db/unixODBC )
	ldap? ( =net-nds/openldap-2* )
	ssl? ( >=dev-libs/openssl-0.9.8e )
	zlib? ( sys-libs/zlib )"

PROVIDE="virtual/jabber-server"
S=${WORKDIR}/${P}/src

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Bug #171427
	epatch "${FILESDIR}/${PV}-missing-declaration.patch"
	# Bug 202114
	epatch "${FILESDIR}/${P}-erlang-12.patch"
}

src_compile() {
	econf								\
		$(use_enable mod_irc)					\
		$(use_enable ldap eldap)				\
		$(use_enable mod_muc)					\
		$(use_enable mod_pubsub)				\
		$(use_enable ssl tls)					\
		$(use_enable web)					\
		$(use_enable odbc)					\
		$(use_enable zlib ejabberd_zlib)			\
		|| die "econf failed"

	if useq debug; then
		emake ejabberd_debug=true || die "compiling ejabberd core failed"
	else
		emake || die "compiling ejabberd core failed"
	fi
}

src_install() {
	make								\
		DESTDIR="${D}"						\
		EJABBERDDIR="${D}/usr/$(get_libdir)/erlang/lib/${P}"	\
		ETCDIR="${D}${JABBER_ETC}"				\
		LOGDIR="${D}${JABBER_LOG}"				\
		install							\
		|| die "install failed"

	chown -R jabber:jabber "${D}${JABBER_ETC}"
	chown -R jabber:jabber "${D}${JABBER_LOG}"
	chown -R jabber:jabber "${D}/usr/$(get_libdir)/erlang/lib/${P}"

	cd "${WORKDIR}/${P}"
	insinto /usr/share/doc/${PF}
	dohtml doc/*.{html,png}

	#
	# Create /usr/bin/ejabberd
	#
	cat <<EOF > "${T}/ejabberd"
#!/bin/bash

erl -pa /usr/$(get_libdir)/erlang/lib/${P}/ebin \\
	${pa} \\
	-sname ejabberd \\
	-s ejabberd \\
	-ejabberd config \"${JABBER_ETC}/ejabberd.cfg\" \\
	log_path \"${JABBER_LOG}/ejabberd.log\" \\
	-kernel inetrc \"${JABBER_ETC}/inetrc\" \\
	-sasl sasl_error_logger \{file,\"${JABBER_LOG}/sasl.log\"\} \\
	-mnesia dir \"${JABBER_SPOOL}\" \\
	\$@
EOF

	#
	# Create /usr/bin/ejabberdctl
	#
	cat <<EOF > "${T}/ejabberdctl"
#!/bin/sh

exec env HOME=${JABBER_RUN} \\
	erl -pa /usr/$(get_libdir)/erlang/lib/${P}/ebin \\
		${pa} \\
		-noinput \\
		-sname ejabberdctl \\
		-s ejabberd_ctl \\
		-extra \$@
EOF

	dobin "${T}/ejabberdctl"
	dobin "${T}/ejabberd"

	newinitd "${FILESDIR}/${P}.initd" ${PN}
	newconfd "${FILESDIR}/ejabberd-1.1.4.confd" ${PN}

	insinto ${JABBER_ETC}
	doins "${FILESDIR}/inetrc"
	if useq ssl ; then
		doins "${FILESDIR}/ssl.cnf"
		newins "${FILESDIR}/self-cert-v2.sh" self-cert.sh
	fi
}

pkg_postinst() {
	elog "For configuration instructions, please see /usr/share/doc/${PF}/html/guide.html"
	elog "or the online version at http://www.process-one.net/en/projects/ejabberd/docs/guide_en.html"
	echo
	if useq ssl ; then
		if [ ! -e /etc/jabber/ssl.pem ]; then
			elog "Please edit ${JABBER_ETC}/ssl.cnf and run ${JABBER_ETC}/self-cert.sh"
			elog "Ejabberd may refuse to start without an SSL certificate"
		fi
	fi
	if ! useq web ; then
		elog "The web USE flag is off, this has disabled the web admin interface."
	fi
}