[gentoo-commits] repo/gentoo:master commit in: net-im/pyicq-t/files/, net-im/pyicq-t/

[Austin English]

commit:     f8faca5c19419e40adb47d84689beabe7225bea6
Author:     Austin English <wizardedit <AT> gentoo <DOT> org>
AuthorDate: Mon May  2 19:13:40 2016 +0000
Commit:     Austin English <wizardedit <AT> gentoo <DOT> org>
CommitDate: Mon May  2 22:21:47 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f8faca5c

net-im/pyicq-t: use #!/sbin/openrc-run instead of #!/sbin/runscript

Gentoo-Bug: https://bugs.gentoo.org/573846

Package-Manager: portage-2.2.26

 net-im/pyicq-t/files/pyicq-t-0.8-initd-r1 |  4 +--
 net-im/pyicq-t/pyicq-t-0.8.1.5-r5.ebuild  | 55 +++++++++++++++++++++++++++++++
 2 files changed, 57 insertions(+), 2 deletions(-)

diff --git a/net-im/pyicq-t/files/pyicq-t-0.8-initd-r1 b/net-im/pyicq-t/files/pyicq-t-0.8-initd-r1
index 8c46bc6..cc9057e 100644
--- a/net-im/pyicq-t/files/pyicq-t-0.8-initd-r1
+++ b/net-im/pyicq-t/files/pyicq-t-0.8-initd-r1
@@ -1,5 +1,5 @@
-#!/sbin/runscript
-# Copyright 1999-2013 Gentoo Foundation
+#!/sbin/openrc-run
+# Copyright 1999-2016 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 

diff --git a/net-im/pyicq-t/pyicq-t-0.8.1.5-r5.ebuild b/net-im/pyicq-t/pyicq-t-0.8.1.5-r5.ebuild
new file mode 100644
index 0000000..a4d1d38
--- /dev/null
+++ b/net-im/pyicq-t/pyicq-t-0.8.1.5-r5.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="6"
+PYTHON_COMPAT=( python2_7 )
+inherit eutils python-single-r1 systemd
+
+MY_P="${P/pyicq-t/pyicqt}"
+DESCRIPTION="Python based jabber transport for ICQ"
+HOMEPAGE="https://code.google.com/p/pyicqt/"
+SRC_URI="https://pyicqt.googlecode.com/files/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="webinterface"
+
+DEPEND="net-im/jabber-base"
+RDEPEND="${DEPEND}
+	dev-python/twisted-core[${PYTHON_USEDEP}]
+	dev-python/twisted-words[${PYTHON_USEDEP}]
+	dev-python/twisted-web[${PYTHON_USEDEP}]
+	webinterface? ( >=dev-python/nevow-0.4.1[${PYTHON_USEDEP}] )
+	dev-python/pillow[${PYTHON_USEDEP}]"
+
+src_prepare() {
+	eapply "${FILESDIR}/${P}-python26-warnings.diff"
+	eapply "${FILESDIR}/${P}-pillow-imaging.patch"
+	eapply_user
+}
+
+src_install() {
+	python_moduleinto ${PN}
+	cp PyICQt.py ${PN}.py || die
+	python_domodule ${PN}.py data tools src
+
+	insinto /etc/jabber
+	newins config_example.xml ${PN}.xml
+	fperms 600 /etc/jabber/${PN}.xml
+	fowners jabber:jabber /etc/jabber/${PN}.xml
+	fperms 755 "$(python_get_sitedir)/${PN}/${PN}.py"
+	sed -i \
+		-e "s:<spooldir>[^\<]*</spooldir>:<spooldir>/var/spool/jabber</spooldir>:" \
+		-e "s:<pid>[^\<]*</pid>:<pid>/var/run/jabber/${PN}.pid</pid>:" \
+		"${ED}/etc/jabber/${PN}.xml" || die
+
+	newinitd "${FILESDIR}/${PN}-0.8-initd-r1" ${PN}
+	systemd_dounit "${FILESDIR}/${PN}.service"
+	sed -i -e "s:INSPATH:$(python_get_sitedir)/${PN}:" \
+		"${ED}/etc/init.d/${PN}" "${ED}/usr/lib/systemd/system/${PN}.service" || die
+
+	python_fix_shebang "${D}$(python_get_sitedir)/${PN}"
+}