[gentoo-commits] repo/gentoo:master commit in: dev-python/cryptography/

[Matt Thode]

commit:     24265b72e10774512312e02a5ba4669b61ecfc6f
Author:     Matthew Thode <prometheanfire <AT> gentoo <DOT> org>
AuthorDate: Tue Oct 31 19:52:42 2017 +0000
Commit:     Matt Thode <prometheanfire <AT> gentoo <DOT> org>
CommitDate: Tue Oct 31 19:53:43 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=24265b72

dev-python/cryptography: allow the new ecc enabled openssl (got around patents) bug 531540

Package-Manager: Portage-2.3.8, Repoman-2.3.4

 .../cryptography/cryptography-2.1.2-r1.ebuild      | 53 ++++++++++++++++++++++
 1 file changed, 53 insertions(+)

diff --git a/dev-python/cryptography/cryptography-2.1.2-r1.ebuild b/dev-python/cryptography/cryptography-2.1.2-r1.ebuild
new file mode 100644
index 00000000000..70a0e57999b
--- /dev/null
+++ b/dev-python/cryptography/cryptography-2.1.2-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy{,3} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 flag-o-matic
+
+DESCRIPTION="Library providing cryptographic recipes and primitives"
+HOMEPAGE="https://github.com/pyca/cryptography/ https://pypi.python.org/pypi/cryptography/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="|| ( Apache-2.0 BSD )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~x86 ~x64-solaris"
+IUSE="libressl test"
+
+RDEPEND="
+	!libressl? ( dev-libs/openssl:0= ( || ( dev-libs/openssl:0[-bindist(-)]
+										=dev-libs/openssl-1.0.2l-r1:0
+										=dev-libs/openssl-1.1.0f-r1:0 ) ) )
+	libressl? ( dev-libs/libressl )
+	$(python_gen_cond_dep '>=dev-python/cffi-1.7:=[${PYTHON_USEDEP}]' 'python*')
+	$(python_gen_cond_dep 'dev-python/enum34[${PYTHON_USEDEP}]' python2_7 pypy{,3})
+	>=dev-python/idna-2.1[${PYTHON_USEDEP}]
+	>=dev-python/asn1crypto-0.21.0[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/six-1.4.1[${PYTHON_USEDEP}]
+	virtual/python-ipaddress[${PYTHON_USEDEP}]
+	"
+DEPEND="${RDEPEND}
+	>=dev-python/setuptools-1.0[${PYTHON_USEDEP}]
+	test? (
+		~dev-python/cryptography-vectors-${PV}[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/iso8601[${PYTHON_USEDEP}]
+		dev-python/pretend[${PYTHON_USEDEP}]
+		dev-python/pyasn1-modules[${PYTHON_USEDEP}]
+		>=dev-python/pytest-2.9.0[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+	)"
+
+DOCS=( AUTHORS.rst CONTRIBUTING.rst README.rst )
+
+python_configure_all() {
+	append-cflags $(test-flags-CC -pthread)
+}
+
+python_test() {
+	py.test -v -v -x || die "Tests fail with ${EPYTHON}"
+}