[gentoo-commits] gentoo-x86 commit in gnome-base/gnome-volume-manager: ChangeLog gnome-volume-manager-2.17.0-r1.ebuild

[Daniel Gryniewicz (dang)]

dang        07/12/02 18:59:35

  Modified:             ChangeLog
  Added:                gnome-volume-manager-2.17.0-r1.ebuild
  Log:
  Bump to 2.17.0-r1
  	- Patch to fix default totem command for gstreamer backend. Bug #200999
  
  (Portage version: 2.1.4_rc3)

Revision  Changes    Path
1.96                 gnome-base/gnome-volume-manager/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-volume-manager/ChangeLog?rev=1.96&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-volume-manager/ChangeLog?rev=1.96&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-volume-manager/ChangeLog?r1=1.95&r2=1.96

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-base/gnome-volume-manager/ChangeLog,v
retrieving revision 1.95
retrieving revision 1.96
diff -u -r1.95 -r1.96
--- ChangeLog	23 Sep 2007 05:06:47 -0000	1.95
+++ ChangeLog	2 Dec 2007 18:59:34 -0000	1.96
@@ -1,6 +1,14 @@
 # ChangeLog for gnome-base/gnome-volume-manager
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-volume-manager/ChangeLog,v 1.95 2007/09/23 05:06:47 tgall Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-volume-manager/ChangeLog,v 1.96 2007/12/02 18:59:34 dang Exp $
+
+*gnome-volume-manager-2.17.0-r1 (02 Dec 2007)
+
+  02 Dec 2007; Daniel Gryniewicz <dang@g.o>
+  +files/gnome-volume-manager-2.17.0-totem-dvd.patch,
+  +gnome-volume-manager-2.17.0-r1.ebuild:
+  Bump to 2.17.0-r1
+  	- Patch to fix default totem command for gstreamer backend. Bug #200999
 
   23 Sep 2007; Tom Gall <tgall@g.o>
   gnome-volume-manager-2.17.0.ebuild:



1.1                  gnome-base/gnome-volume-manager/gnome-volume-manager-2.17.0-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-volume-manager/gnome-volume-manager-2.17.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-volume-manager/gnome-volume-manager-2.17.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: gnome-volume-manager-2.17.0-r1.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-volume-manager/gnome-volume-manager-2.17.0-r1.ebuild,v 1.1 2007/12/02 18:59:34 dang Exp $

inherit gnome2 eutils autotools

DESCRIPTION="Daemon that enforces volume-related policies"
HOMEPAGE="http://www.gnome.org/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="crypt debug doc"

RDEPEND="gnome-base/nautilus
	>=gnome-base/libgnomeui-2.1.5
	>=dev-libs/dbus-glib-0.71
	>=sys-apps/hal-0.5.6
	>=x11-libs/gtk+-2.6
	>=gnome-base/libglade-2
	>=x11-libs/libnotify-0.3
	>=gnome-base/gconf-2
	>=gnome-base/control-center-2.0
	gnome-base/gnome-mime-data
	gnome-base/gnome-mount"

DEPEND="${RDEPEND}
	  sys-devel/gettext
	>=dev-util/pkgconfig-0.20
	>=dev-util/intltool-0.35"

DOCS="AUTHORS ChangeLog README HACKING NEWS TODO"

pkg_setup() {
	G2CONF="${G2CONF} \
			$(use_enable crypt) \
			$(use_enable debug) \
			$(use_enable doc)"

	# FIXME: We should be more intelligent about disabling multiuser support
	# (like enable it when pam_console is available?). For now, this is a
	# slightly nicer solution than applying ${PN}-1.5.9-no-pam_console.patch
	G2CONF="${G2CONF} --disable-multiuser"
}

src_unpack() {
	gnome2_src_unpack

	# fbsd fixes.  bug #183442
	epatch "${FILESDIR}"/${P}-fbsd.patch

	# Fix default totem command.  Bug #200999
	epatch "${FILESDIR}"/${P}-totem-dvd.patch
}

pkg_postinst() {
	gnome2_pkg_postinst

	elog "To start the gnome-volume-manager daemon you need to configure"
	elog "it through it's preferences capplet. Also the HAL daemon (hald)"
	elog "needs to be running or it will shut down."
}



-- 
gentoo-commits@g.o mailing list