[gentoo-commits] gentoo-x86 commit in sci-libs/libsvm: ChangeLog libsvm-3.0.ebuild

[Sebastien Fabbro (bicatali)]

bicatali    10/12/02 19:46:11

  Modified:             ChangeLog
  Added:                libsvm-3.0.ebuild
  Log:
  Version bump
  
  (Portage version: 2.1.9.25/cvs/Linux x86_64)

Revision  Changes    Path
1.22                 sci-libs/libsvm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/libsvm/ChangeLog?rev=1.22&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/libsvm/ChangeLog?rev=1.22&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/libsvm/ChangeLog?r1=1.21&r2=1.22

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-libs/libsvm/ChangeLog,v
retrieving revision 1.21
retrieving revision 1.22
diff -u -r1.21 -r1.22
--- ChangeLog	5 Aug 2010 20:25:14 -0000	1.21
+++ ChangeLog	2 Dec 2010 19:46:10 -0000	1.22
@@ -1,6 +1,12 @@
 # ChangeLog for sci-libs/libsvm
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/libsvm/ChangeLog,v 1.21 2010/08/05 20:25:14 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/libsvm/ChangeLog,v 1.22 2010/12/02 19:46:10 bicatali Exp $
+
+*libsvm-3.0 (02 Dec 2010)
+
+  02 Dec 2010; Sébastien Fabbro <bicatali@g.o>
+  +files/3.0-makefile.patch, +libsvm-3.0.ebuild:
+  Version bump
 
 *libsvm-2.91 (05 Aug 2010)
 



1.1                  sci-libs/libsvm/libsvm-3.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/libsvm/libsvm-3.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/libsvm/libsvm-3.0.ebuild?rev=1.1&content-type=text/plain

Index: libsvm-3.0.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/libsvm/libsvm-3.0.ebuild,v 1.1 2010/12/02 19:46:11 bicatali Exp $

EAPI="3"
SUPPORT_PYTHON_ABIS="1"

inherit eutils java-pkg-opt-2 python

DESCRIPTION="Library for Support Vector Machines"
HOMEPAGE="http://www.csie.ntu.edu.tw/~cjlin/libsvm/"
SRC_URI="http://www.csie.ntu.edu.tw/~cjlin/libsvm/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="java python tools"

DEPEND="java? ( >=virtual/jdk-1.4 )"
RDEPEND="${DEPEND}
	tools? ( sci-visualization/gnuplot )"

src_prepare() {
	epatch "${FILESDIR}"/${PV}-makefile.patch
	sed -i -e "s@\.\./@${EPREFIX}/usr/bin/@g" tools/*.py \
		|| die "Failed to fix paths in python files"
	if use java; then
		local JAVAC_FLAGS="$(java-pkg_javac-args)"
		sed -i \
			-e "s/JAVAC_FLAGS =/JAVAC_FLAGS=${JAVAC_FLAGS}/g" \
			Makefile || die "Failed to fix java makefile"
	fi
}

src_compile() {
	emake || die "emake failed"
	if use java ; then
		emake -C java || die "emake for java modules failed"
	fi
}

src_install() {
	dobin svm-train svm-predict svm-scale \
		|| die "failed to install binaries"
	dolib.so *.so* || die "failed to install library"
	insinto /usr/include
	doins svm.h || die
	dohtml FAQ.html || die
	dodoc README

	if use tools; then
		for t in tools/*.py; do
			newbin ${t} svm-$(basename ${t} .py) || die "install tools failes"
		done
		newdoc tools/README README.tools
		insinto /usr/share/doc/${PF}
		doins heart_scale || die
		doins -r svm-toy || die
	fi

	if use python ; then
		installation() {
			insinto $(python_get_sitedir)
			doins python/*.py || die "python modules install failed"
		}
		python_execute_function installation
		newdoc python/README README.python
	fi

	if use java; then
		java-pkg_dojar java/libsvm.jar
		dohtml java/test_applet.html
	fi
}