[gentoo-commits] repo/gentoo:master commit in: net-vpn/networkmanager-openconnect/

[Matt Turner]

commit:     33d8295a8c5fdd74f488a6b6d625630bbd6e0705
Author:     Matthew Smith <matt <AT> offtopica <DOT> uk>
AuthorDate: Thu Dec 30 09:39:47 2021 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Apr  8 21:20:48 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=33d8295a

net-vpn/networkmanager-openconnect: Change metainfo dir

Closes: https://bugs.gentoo.org/830257
Signed-off-by: Matthew Smith <matt <AT> offtopica.uk>
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 .../networkmanager-openconnect-1.2.6-r2.ebuild     | 57 ++++++++++++++++++++++
 1 file changed, 57 insertions(+)

diff --git a/net-vpn/networkmanager-openconnect/networkmanager-openconnect-1.2.6-r2.ebuild b/net-vpn/networkmanager-openconnect/networkmanager-openconnect-1.2.6-r2.ebuild
new file mode 100644
index 000000000000..f105dd2a8833
--- /dev/null
+++ b/net-vpn/networkmanager-openconnect/networkmanager-openconnect-1.2.6-r2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+GNOME_ORG_MODULE="NetworkManager-${PN##*-}"
+
+inherit gnome2
+
+DESCRIPTION="NetworkManager OpenConnect plugin"
+HOMEPAGE="https://wiki.gnome.org/Projects/NetworkManager"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="gtk"
+
+DEPEND="
+	>=net-misc/networkmanager-1.2:=
+	>=dev-libs/glib-2.32:2
+	>=dev-libs/dbus-glib-0.74
+	dev-libs/libxml2:2
+	>=net-vpn/openconnect-3.02:=
+	gtk? (
+		>=app-crypt/gcr-3.4:=
+		>=app-crypt/libsecret-0.18
+		>=x11-libs/gtk+-3.4:3
+	)
+"
+
+RDEPEND="
+	${DEPEND}
+	acct-group/nm-openconnect
+	acct-user/nm-openconnect
+"
+
+BDEPEND="
+	sys-devel/gettext
+	dev-util/intltool
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# Bug #830257
+	sed -i 's|/appdata|/metainfo|g' Makefile.{in,am} || die
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-more-warnings \
+		--disable-static \
+		--without-libnm-glib \
+		$(use_with gtk gnome) \
+		$(use_with gtk authdlg)
+}