[gentoo-commits] gentoo-x86 commit in dev-java/lucene: ChangeLog lucene-2.9.4.ebuild

[Miroslav Sulc (fordfrog)]

fordfrog    11/01/28 14:32:10

  Modified:             ChangeLog
  Added:                lucene-2.9.4.ebuild
  Log:
  dev-java/lucene: version bump
  
  (Portage version: 2.1.9.35/cvs/Linux x86_64)

Revision  Changes    Path
1.74                 dev-java/lucene/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/lucene/ChangeLog?rev=1.74&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/lucene/ChangeLog?rev=1.74&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/lucene/ChangeLog?r1=1.73&r2=1.74

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-java/lucene/ChangeLog,v
retrieving revision 1.73
retrieving revision 1.74
diff -u -r1.73 -r1.74
--- ChangeLog	28 Jan 2011 14:04:40 -0000	1.73
+++ ChangeLog	28 Jan 2011 14:32:09 -0000	1.74
@@ -1,6 +1,12 @@
 # ChangeLog for dev-java/lucene
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/lucene/ChangeLog,v 1.73 2011/01/28 14:04:40 fordfrog Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-java/lucene/ChangeLog,v 1.74 2011/01/28 14:32:09 fordfrog Exp $
+
+*lucene-2.9.4 (28 Jan 2011)
+
+  28 Jan 2011; Miroslav Šulc <fordfrog@g.o> +lucene-2.9.4.ebuild:
+  Version bump. The new ebuild removes bundled jars and puts junit on classpath
+  for compilation always, because javacc builds tests too.
 
 *lucene-3.0.3 (28 Jan 2011)
 



1.1                  dev-java/lucene/lucene-2.9.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/lucene/lucene-2.9.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/lucene/lucene-2.9.4.ebuild?rev=1.1&content-type=text/plain

Index: lucene-2.9.4.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/lucene/lucene-2.9.4.ebuild,v 1.1 2011/01/28 14:32:09 fordfrog Exp $

EAPI="2"
JAVA_PKG_IUSE="doc source test"
JAVA_PKG_BSFIX_ALL="no"
JAVA_PKG_BSFIX_NAME="build.xml common-build.xml"

inherit java-pkg-2 java-ant-2

DESCRIPTION="High-performance, full-featured text search engine written entirely in Java"
HOMEPAGE="http://jakarta.apache.org/lucene"
# when doing version bump, SRC_URI of the previous version should most probably
# be changed to java/archive/ !
SRC_URI="mirror://apache/lucene/java/${P}-src.tar.gz"
LICENSE="Apache-2.0"
SLOT="2.9"
KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
IUSE=""
DEPEND=">=virtual/jdk-1.4
	dev-java/ant-nodeps:0
	dev-java/javacc:0
	dev-java/junit:0
	test? ( dev-java/ant-junit )"
# junit is needed for compilation because tests are compiled for javacc target even when not requested
RDEPEND=">=virtual/jdk-1.4"

java_prepare() {
	sed -i -e '/-Xmax/ d' common-build.xml
	find -name "*.jar" -type f | xargs rm -v
	java-pkg_jar-from --build-only --into lib junit junit.jar junit-3.8.2.jar
}

src_compile() {
	# regenerate javacc files just because we can
	# put javacc.jar on ant's classpath here even when <javacc> task
	# doesn't use it - it's to fool the <available> test, first time
	# it's useful not to have ignoresystemclasses=true...
	ANT_TASKS="ant-nodeps javacc" eant \
		-Djavacc.home=/usr/share/javacc/lib javacc
	ANT_TASKS="none" eant -Dversion=${PV} jar-core jar-demo $(use_doc javadocs-core javadocs-demo)
}

src_test() {
	java-ant_rewrite-classpath common-build.xml
	EANT_GENTOO_CLASSPATH="junit ant-core" ANT_TASKS="ant-junit" eant test-core
}

src_install() {
	dodoc CHANGES.txt README.txt || die
	java-pkg_newjar build/${PN}-core-${PV}.jar ${PN}-core.jar
	java-pkg_newjar build/${PN}-demos-${PV}.jar ${PN}-demos.jar

	if use doc; then
		dohtml -r docs/* || die
		# for the core and demo subdirs
		java-pkg_dohtml -r build/docs/api
	fi
	use source && java-pkg_dosrc src/java/org
}