[gentoo-commits] gentoo-x86 commit in www-apps/mediawiki: ChangeLog mediawiki-1.11.2.ebuild mediawiki-1.12.0.ebuild mediawiki-1.11.1.ebuild mediawiki-1.13.0.ebuild

[Benedikt Boehm (hollow)]

hollow      08/09/01 07:47:36

  Modified:             ChangeLog mediawiki-1.11.2.ebuild
                        mediawiki-1.12.0.ebuild mediawiki-1.11.1.ebuild
  Added:                mediawiki-1.13.0.ebuild
  Log:
  fix #218051; version bump
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.110                www-apps/mediawiki/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/mediawiki/ChangeLog?rev=1.110&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/mediawiki/ChangeLog?rev=1.110&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/mediawiki/ChangeLog?r1=1.109&r2=1.110

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apps/mediawiki/ChangeLog,v
retrieving revision 1.109
retrieving revision 1.110
diff -u -r1.109 -r1.110
--- ChangeLog	23 Aug 2008 04:54:30 -0000	1.109
+++ ChangeLog	1 Sep 2008 07:47:36 -0000	1.110
@@ -1,6 +1,13 @@
 # ChangeLog for www-apps/mediawiki
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-apps/mediawiki/ChangeLog,v 1.109 2008/08/23 04:54:30 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-apps/mediawiki/ChangeLog,v 1.110 2008/09/01 07:47:36 hollow Exp $
+
+*mediawiki-1.13.0 (01 Sep 2008)
+
+  01 Sep 2008; Benedikt Böhm <hollow@g.o> mediawiki-1.11.1.ebuild,
+  mediawiki-1.11.2.ebuild, mediawiki-1.12.0.ebuild,
+  +mediawiki-1.13.0.ebuild:
+  fix #218051; version bump
 
   23 Aug 2008; Doug Goldstein <cardoe@g.o> metadata.xml:
   add GLEP 56 USE flag desc from use.local.desc



1.7                  www-apps/mediawiki/mediawiki-1.11.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/mediawiki/mediawiki-1.11.2.ebuild?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/mediawiki/mediawiki-1.11.2.ebuild?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/mediawiki/mediawiki-1.11.2.ebuild?r1=1.6&r2=1.7

Index: mediawiki-1.11.2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apps/mediawiki/mediawiki-1.11.2.ebuild,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- mediawiki-1.11.2.ebuild	3 Apr 2008 10:06:02 -0000	1.6
+++ mediawiki-1.11.2.ebuild	1 Sep 2008 07:47:36 -0000	1.7
@@ -1,6 +1,6 @@
 # Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-apps/mediawiki/mediawiki-1.11.2.ebuild,v 1.6 2008/04/03 10:06:02 hollow Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-apps/mediawiki/mediawiki-1.11.2.ebuild,v 1.7 2008/09/01 07:47:36 hollow Exp $
 
 EAPI="1"
 inherit webapp depend.php versionator eutils
@@ -19,7 +19,7 @@
 RDEPEND="${DEPEND}
 	math? (
 		app-text/dvipng
-		virtual/tetex
+		virtual/tex-base
 		virtual/ghostscript
 		media-gfx/imagemagick
 	)



1.4                  www-apps/mediawiki/mediawiki-1.12.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/mediawiki/mediawiki-1.12.0.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/mediawiki/mediawiki-1.12.0.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/mediawiki/mediawiki-1.12.0.ebuild?r1=1.3&r2=1.4

Index: mediawiki-1.12.0.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apps/mediawiki/mediawiki-1.12.0.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- mediawiki-1.12.0.ebuild	26 Jun 2008 11:15:46 -0000	1.3
+++ mediawiki-1.12.0.ebuild	1 Sep 2008 07:47:36 -0000	1.4
@@ -1,6 +1,6 @@
 # Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-apps/mediawiki/mediawiki-1.12.0.ebuild,v 1.3 2008/06/26 11:15:46 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-apps/mediawiki/mediawiki-1.12.0.ebuild,v 1.4 2008/09/01 07:47:36 hollow Exp $
 
 EAPI="1"
 inherit webapp depend.php versionator eutils
@@ -19,7 +19,7 @@
 RDEPEND="${DEPEND}
 	math? (
 		app-text/dvipng
-		virtual/tetex
+		virtual/tex-base
 		virtual/ghostscript
 		media-gfx/imagemagick
 	)



1.8                  www-apps/mediawiki/mediawiki-1.11.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/mediawiki/mediawiki-1.11.1.ebuild?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/mediawiki/mediawiki-1.11.1.ebuild?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/mediawiki/mediawiki-1.11.1.ebuild?r1=1.7&r2=1.8

Index: mediawiki-1.11.1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apps/mediawiki/mediawiki-1.11.1.ebuild,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- mediawiki-1.11.1.ebuild	3 Apr 2008 10:06:02 -0000	1.7
+++ mediawiki-1.11.1.ebuild	1 Sep 2008 07:47:36 -0000	1.8
@@ -1,6 +1,6 @@
 # Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-apps/mediawiki/mediawiki-1.11.1.ebuild,v 1.7 2008/04/03 10:06:02 hollow Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-apps/mediawiki/mediawiki-1.11.1.ebuild,v 1.8 2008/09/01 07:47:36 hollow Exp $
 
 EAPI="1"
 inherit webapp depend.php versionator eutils
@@ -19,7 +19,7 @@
 RDEPEND="${DEPEND}
 	math? (
 		app-text/dvipng
-		virtual/tetex
+		virtual/tex-base
 		virtual/ghostscript
 		media-gfx/imagemagick
 	)



1.1                  www-apps/mediawiki/mediawiki-1.13.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/mediawiki/mediawiki-1.13.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/mediawiki/mediawiki-1.13.0.ebuild?rev=1.1&content-type=text/plain

Index: mediawiki-1.13.0.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/mediawiki/mediawiki-1.13.0.ebuild,v 1.1 2008/09/01 07:47:36 hollow Exp $

EAPI="1"
inherit webapp depend.php versionator eutils

MY_BRANCH=$(get_version_component_range 1-2)

DESCRIPTION="The MediaWiki wiki web application (as used on wikipedia.org)"
HOMEPAGE="http://www.mediawiki.org"
SRC_URI="http://download.wikimedia.org/mediawiki/${MY_BRANCH}/${P}.tar.gz"

LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86"
IUSE="imagemagick math mysql postgres restrict +ocamlopt"

DEPEND="math? ( >=dev-lang/ocaml-3.0.6 )"
RDEPEND="${DEPEND}
	math? (
		app-text/dvipng
		virtual/tex-base
		virtual/ghostscript
		media-gfx/imagemagick
	)
	imagemagick? ( media-gfx/imagemagick )"

RESTRICT="test"

need_httpd_cgi
need_php_httpd

pkg_setup() {
	webapp_pkg_setup
	local flags="pcre session xml"
	use mysql && flags="${flags} mysql"
	use postgres && flags="${flags} postgres"
	if ! PHPCHECKNODIE="yes" require_php_with_use ${flags} || \
		! PHPCHECKNODIE="yes" require_php_with_any_use gd gd-external ; then
			die "Re-install ${PHP_PKG} with ${flags} and either gd or gd-external"
	fi

	# see Bug 204812
	if use ocamlopt && use math && ! built_with_use --missing true dev-lang/ocaml ocamlopt; then
		eerror "In order to build ${PN} with native code support from ocaml"
		eerror "You first need to have a native code ocaml compiler."
		eerror "You need to install dev-lang/ocaml with ocamlopt useflag on."
		die "Please install ocaml with ocamlopt useflag"
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	# XXX: besides, is/was this patch really that required? if so, why? (trapni)
#	epatch ${FILESDIR}/jobindexlength-mysql.patch

	if use restrict ; then
		epatch "${FILESDIR}/access_restrict_${PV}.patch"
	fi
}

src_compile() {
	if use math; then
		einfo "Compiling math support"
		cd math || die
		if ! use ocamlopt; then
			sed -i -e "s/ocamlopt/ocamlc/" Makefile
			sed -i -e "s/cmxa/cma/" Makefile
			sed -i -e "s/cmx/cmo/g" Makefile
		fi
		emake || die
	else
		einfo "No math support enabled. Skipping."
	fi

	# TODO: think about includes/zhtable/ support
}

src_install() {
	webapp_src_preinst

	# copy the app's main files excluding math support, docs, and tests
	local DIRS=(
		"bin"
		"config"
		"extensions"
		"images"
		"includes"
		"includes/api"
		"includes/cbt"
		"includes/filerepo"
		"includes/media"
		"includes/normal"
		"includes/templates"
		"includes/zhtable"
		"languages"
		"languages/classes"
		"languages/messages"
		"locale"
		"maintenance"
		"maintenance/archives"
		"maintenance/dtrace"
		"maintenance/language"
		"maintenance/ora"
		"maintenance/postgres"
		"maintenance/postgres/archives"
		"maintenance/storage"
		"serialized"
		"skins"
		"skins/chick"
		"skins/common"
		"skins/common/images"
		"skins/common/images/icons"
		"skins/disabled"
		"skins/htmldump"
		"skins/monobook"
		"skins/myskin"
		"skins/simple"
	)

	insinto ${MY_HTDOCSDIR}
	doins *.php *.inc *.phtml
	for DIR in ${DIRS[*]}; do
		insinto ${MY_HTDOCSDIR}/${DIR}
		doins ${DIR}/*
		[[ -f ${DIR}/.htaccess ]] && doins ${DIR}/.htaccess
	done

	# installing some docs
	local DOCS="AdminSettings.sample FAQ HISTORY INSTALL README RELEASE-NOTES UPGRADE"
	dodoc ${DOCS} docs/*.txt
	rm -f ${DOCS} COPYING docs/*.txt

	docinto php-memcached
	dodoc docs/php-memcached/*

	# If imagemagick is enabled then setup for image upload.
	# We ensure the directory is prepared for writing.  The post-
	# install instructions guide the user to enable the feature.
	if use imagemagick; then
		webapp_serverowned ${MY_HTDOCSDIR}/images
	fi

	# If we've enabled math USE-flag, install math support.
	# We ensure the directories are prepared for writing.  The post-
	# install instructions guide the user to enable the feature.
	if use math; then
		einfo "Installing math support"
		exeinto ${MY_HTDOCSDIR}/math
		doexe math/texvc

		# Docs
		docinto math
		dodoc math/{README,TODO}

		# Working directories.  Server writeable.
		dodir ${MY_HTDOCSDIR}/images/math
		webapp_serverowned ${MY_HTDOCSDIR}/images/math
		dodir ${MY_HTDOCSDIR}/images/tmp
		webapp_serverowned ${MY_HTDOCSDIR}/images/tmp
	fi

	webapp_postinst_txt en "${FILESDIR}/postinstall-1.11-en.txt"
	webapp_src_install
}