[gentoo-commits] gentoo-x86 commit in kde-base/systemsettings: systemsettings-4.11.9.ebuild ChangeLog

[Johannes Huber (johu)]

johu        14/04/29 18:53:05

  Modified:             ChangeLog
  Added:                systemsettings-4.11.9.ebuild
  Log:
  Version bump KDE Workspace 4.11.9
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key F3CFD2BD)

Revision  Changes    Path
1.251                kde-base/systemsettings/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/systemsettings/ChangeLog?rev=1.251&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/systemsettings/ChangeLog?rev=1.251&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/systemsettings/ChangeLog?r1=1.250&r2=1.251

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/systemsettings/ChangeLog,v
retrieving revision 1.250
retrieving revision 1.251
diff -u -r1.250 -r1.251
--- ChangeLog	5 Apr 2014 17:31:11 -0000	1.250
+++ ChangeLog	29 Apr 2014 18:53:05 -0000	1.251
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/systemsettings
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/systemsettings/ChangeLog,v 1.250 2014/04/05 17:31:11 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/systemsettings/ChangeLog,v 1.251 2014/04/29 18:53:05 johu Exp $
+
+*systemsettings-4.11.9 (29 Apr 2014)
+
+  29 Apr 2014; Johannes Huber <johu@g.o> +systemsettings-4.11.9.ebuild:
+  Version bump KDE Workspace 4.11.9
 
   05 Apr 2014; Andreas K. Huettel <dilfridge@g.o>
   systemsettings-4.11.8.ebuild:



1.1                  kde-base/systemsettings/systemsettings-4.11.9.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/systemsettings/systemsettings-4.11.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/systemsettings/systemsettings-4.11.9.ebuild?rev=1.1&content-type=text/plain

Index: systemsettings-4.11.9.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/systemsettings/systemsettings-4.11.9.ebuild,v 1.1 2014/04/29 18:53:05 johu Exp $

EAPI=5

KDE_HANDBOOK="optional"
KMNAME="kde-workspace"
OPENGL_REQUIRED="optional"
VIRTUALX_REQUIRED="test"
VIRTUALDBUS_TEST="true"
inherit kde4-meta

DESCRIPTION="System settings utility"
HOMEPAGE+=" http://userbase.kde.org/System_Settings"
IUSE="debug gtk semantic-desktop +usb"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"

COMMONDEPEND="
	app-misc/strigi
	dev-libs/glib:2
	$(add_kdebase_dep kwin)
	$(add_kdebase_dep libkworkspace)
	media-libs/fontconfig
	>=media-libs/freetype-2
	>=x11-libs/libxklavier-3.2
	x11-libs/libX11
	x11-libs/libXcursor
	x11-libs/libXext
	x11-libs/libXfixes
	x11-libs/libXft
	x11-libs/libXi
	x11-libs/libxkbfile
	x11-libs/libXrandr
	x11-libs/libXtst
	opengl? ( virtual/opengl )
	usb? ( virtual/libusb:0 )
"
DEPEND="${COMMONDEPEND}
	x11-proto/kbproto
	x11-proto/xextproto
"
RDEPEND="${COMMONDEPEND}
	sys-libs/timezone-data
	x11-apps/setxkbmap
	x11-misc/xkeyboard-config
	gtk? ( kde-misc/kde-gtk-config )
	semantic-desktop? ( $(add_kdebase_dep nepomuk) )
"

KMEXTRA="
	kcontrol/
"
KMEXTRACTONLY="
	krunner/dbus/org.kde.krunner.App.xml
	krunner/dbus/org.kde.screensaver.xml
	ksmserver/screenlocker/dbus/org.kde.screensaver.xml
	kwin/
	libs/
	plasma/
"
# fails to connect to a kded instance
RESTRICT="test"

src_unpack() {
	if use handbook; then
		KMEXTRA+="
			doc/kcontrol
			doc/kfontview
		"
	fi

	kde4-meta_src_unpack
}

src_prepare() {
	sed -i -e 's/systemsettingsrc DESTINATION ${SYSCONF_INSTALL_DIR}/systemsettingsrc DESTINATION ${CONFIG_INSTALL_DIR}/' \
		systemsettings/CMakeLists.txt \
		|| die "Failed to fix systemsettingsrc install location"

	kde4-meta_src_prepare
}

# FIXME: is have_openglxvisual found without screensaver
src_configure() {
	# Old keyboard-detection code is unmaintained,
	# so we force the new stuff, using libxklavier.
	mycmakeargs=(
		-DUSE_XKLAVIER=ON -DWITH_LibXKlavier=ON
		-DWITH_GLIB2=ON -DWITH_GObject=ON
		$(cmake-utils_use_with opengl OpenGL)
		$(cmake-utils_use_with usb)
	)

	kde4-meta_src_configure
}