[gentoo-commits] gentoo-x86 commit in dev-python/chaco: ChangeLog chaco-3.4.0.ebuild

[Arfrever Frehtes Taifersar Arahesis (arfrever)]

arfrever    11/01/30 21:46:17

  Modified:             ChangeLog
  Added:                chaco-3.4.0.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha19_p24/cvs/Linux x86_64)

Revision  Changes    Path
1.10                 dev-python/chaco/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/chaco/ChangeLog?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/chaco/ChangeLog?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/chaco/ChangeLog?r1=1.9&r2=1.10

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/chaco/ChangeLog,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- ChangeLog	18 Oct 2010 14:51:00 -0000	1.9
+++ ChangeLog	30 Jan 2011 21:46:17 -0000	1.10
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/chaco
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/chaco/ChangeLog,v 1.9 2010/10/18 14:51:00 arfrever Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/chaco/ChangeLog,v 1.10 2011/01/30 21:46:17 arfrever Exp $
+
+*chaco-3.4.0 (30 Jan 2011)
+
+  30 Jan 2011; Arfrever Frehtes Taifersar Arahesis <arfrever@g.o>
+  -chaco-3.3.2.ebuild, +chaco-3.4.0.ebuild:
+  Version bump.
 
 *chaco-3.3.2 (18 Oct 2010)
 



1.1                  dev-python/chaco/chaco-3.4.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/chaco/chaco-3.4.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/chaco/chaco-3.4.0.ebuild?rev=1.1&content-type=text/plain

Index: chaco-3.4.0.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/chaco/chaco-3.4.0.ebuild,v 1.1 2011/01/30 21:46:17 arfrever Exp $

EAPI="3"
PYTHON_DEPEND="2"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.* *-jython"
DISTUTILS_SRC_TEST="setup.py"

inherit distutils virtualx

MY_PN="Chaco"
MY_P="${MY_PN}-${PV}"

DESCRIPTION="Interactive plotting toolkit"
HOMEPAGE="http://code.enthought.com/projects/chaco/ http://pypi.python.org/pypi/Chaco"
SRC_URI="http://www.enthought.com/repo/ETS/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc examples test"

RDEPEND=">=dev-python/enable-3.4.0
	>=dev-python/enthoughtbase-3.1.0
	dev-python/numpy"
DEPEND="${RDEPEND}
	dev-python/setuptools
	doc? (
		dev-python/sphinx
		media-fonts/font-cursor-misc
		media-fonts/font-misc-misc
		x11-apps/xhost
	)
	test? (
		dev-python/coverage
		dev-python/nose
		media-fonts/font-cursor-misc
		media-fonts/font-misc-misc
		x11-apps/xhost
	)"

S="${WORKDIR}/${MY_P}"

PYTHON_CFLAGS=("2.* + -fno-strict-aliasing")

DOCS="docs/*.txt"
PYTHON_MODNAME="enthought"

src_prepare() {
	distutils_src_prepare

	# "${S}/enthought/chaco2/tests and "${S}/enthought/chaco2/shell/tests" do not exist.
	sed \
		-e "s:,enthought/chaco2/tests::" \
		-e "s:,enthought/chaco2/shell/tests::" \
		-i setup.cfg || die "sed setup.cfg failed"

	# Disable failing test.
	sed -e "s/test_draw_border_simple/_&/" -i enthought/chaco/tests/border_test_case.py
}

src_compile() {
	distutils_src_compile

	if use doc; then
		einfo "Generation of documentation"
		pushd docs > /dev/null
		doc_generation() {
			emake html || die "Generation of documentation failed"
		}
		maketype="doc_generation" virtualmake
		popd > /dev/null
	fi
}

src_test() {
	maketype="distutils_src_test" virtualmake
}

src_install() {
	find -name "*LICENSE.txt" -delete
	distutils_src_install

	if use doc; then
		pushd docs/build/html > /dev/null
		insinto /usr/share/doc/${PF}/html
		doins -r [a-z]* _images _static || die "Installation of documentation failed"
		popd > /dev/null
	fi

	if use examples; then
		insinto /usr/share/doc/${PF}/examples
		doins -r examples/* || die "Installation of examples failed"
	fi
}