[gentoo-commits] gentoo-x86 commit in net-libs/gnutls: gnutls-2.10.1-r1.ebuild ChangeLog

[Samuli Suominen (ssuominen)]

ssuominen    10/09/28 19:09:09

  Modified:             ChangeLog
  Added:                gnutls-2.10.1-r1.ebuild
  Log:
  USE="test" for app-misc/datefudge DEPEND wrt #326999.
  
  (Portage version: 2.2_rc87/cvs/Linux x86_64)

Revision  Changes    Path
1.262                net-libs/gnutls/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gnutls/ChangeLog?rev=1.262&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gnutls/ChangeLog?rev=1.262&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gnutls/ChangeLog?r1=1.261&r2=1.262

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/gnutls/ChangeLog,v
retrieving revision 1.261
retrieving revision 1.262
diff -u -r1.261 -r1.262
--- ChangeLog	28 Sep 2010 16:57:59 -0000	1.261
+++ ChangeLog	28 Sep 2010 19:09:09 -0000	1.262
@@ -1,6 +1,12 @@
 # ChangeLog for net-libs/gnutls
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/ChangeLog,v 1.261 2010/09/28 16:57:59 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/ChangeLog,v 1.262 2010/09/28 19:09:09 ssuominen Exp $
+
+*gnutls-2.10.1-r1 (28 Sep 2010)
+
+  28 Sep 2010; Samuli Suominen <ssuominen@g.o>
+  +gnutls-2.10.1-r1.ebuild:
+  USE="test" for app-misc/datefudge DEPEND wrt #326999.
 
   28 Sep 2010; Samuli Suominen <ssuominen@g.o> gnutls-2.10.1.ebuild:
   ppc64 stable wrt #337139



1.1                  net-libs/gnutls/gnutls-2.10.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gnutls/gnutls-2.10.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gnutls/gnutls-2.10.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: gnutls-2.10.1-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/gnutls-2.10.1-r1.ebuild,v 1.1 2010/09/28 19:09:09 ssuominen Exp $

EAPI="3"

inherit autotools libtool

DESCRIPTION="A TLS 1.2 and SSL 3.0 implementation for the GNU project"
HOMEPAGE="http://www.gnutls.org/"

if [[ "${PV}" == *pre* ]]; then
	SRC_URI="http://daily.josefsson.org/${P%.*}/${P%.*}-${PV#*pre}.tar.gz"
else
	MINOR_VERSION="${PV#*.}"
	MINOR_VERSION="${MINOR_VERSION%.*}"
	if [[ $((MINOR_VERSION % 2)) == 0 ]]; then
		#SRC_URI="ftp://ftp.gnu.org/pub/gnu/${PN}/${P}.tar.bz2"
		SRC_URI="mirror://gnu/${PN}/${P}.tar.bz2"
	else
		SRC_URI="ftp://alpha.gnu.org/gnu/${PN}/${P}.tar.bz2"
	fi
	unset MINOR_VERSION
fi

# GPL-3 for the gnutls-extras library and LGPL for the gnutls library.
LICENSE="LGPL-2.1 GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~x86 ~sparc-fbsd ~x86-fbsd"
IUSE="bindist +cxx doc examples guile lzo nls test zlib"

RDEPEND="dev-libs/libgpg-error
	>=dev-libs/libgcrypt-1.4.0
	>=dev-libs/libtasn1-0.3.4
	nls? ( virtual/libintl )
	guile? ( dev-scheme/guile[networking] )
	zlib? ( >=sys-libs/zlib-1.1 )
	!bindist? ( lzo? ( >=dev-libs/lzo-2 ) )"
DEPEND="${RDEPEND}
	sys-devel/libtool
	doc? ( dev-util/gtk-doc )
	nls? ( sys-devel/gettext )
	test? ( app-misc/datefudge )"

S="${WORKDIR}/${P%_pre*}"

pkg_setup() {
	if use lzo && use bindist; then
		ewarn "lzo support was disabled for binary distribution of GnuTLS"
		ewarn "due to licensing issues. See Bug #202381 for details."
	fi
}

src_prepare() {
	sed -e 's/imagesdir = $(infodir)/imagesdir = $(htmldir)/' -i doc/Makefile.am

	local dir
	for dir in m4 lib/m4 libextra/m4; do
		rm -f "${dir}/lt"* "${dir}/libtool.m4"
	done
	find . -name ltmain.sh -exec rm {} \;
	for dir in . lib libextra; do
		pushd "${dir}" > /dev/null
		eautoreconf
		popd > /dev/null
	done

	elibtoolize # for sane .so versioning on FreeBSD
}

src_configure() {
	local myconf
	use bindist && myconf="--without-lzo" || myconf="$(use_with lzo)"
	econf --htmldir=/usr/share/doc/${P}/html \
		$(use_enable cxx) \
		$(use_enable doc gtk-doc) \
		$(use_enable guile) \
		$(use_enable nls) \
		$(use_with zlib) \
		${myconf}
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	dodoc AUTHORS ChangeLog NEWS README THANKS doc/TODO

	if use doc; then
		dodoc doc/gnutls.{pdf,ps}
		dohtml doc/gnutls.html
	fi

	if use examples; then
		docinto examples
		dodoc doc/examples/*.c
	fi
}