[gentoo-commits] gentoo-x86 commit in www-apps/dokuwiki: dokuwiki-20140505.ebuild ChangeLog

[Jorge Manuel B. S. Vicetto (jmbsvicetto)]

jmbsvicetto    14/06/02 21:00:16

  Modified:             ChangeLog
  Added:                dokuwiki-20140505.ebuild
  Log:
  20140505 version bump - fixes bug 512054.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key BB0E6E98)

Revision  Changes    Path
1.65                 www-apps/dokuwiki/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/dokuwiki/ChangeLog?rev=1.65&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/dokuwiki/ChangeLog?rev=1.65&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/dokuwiki/ChangeLog?r1=1.64&r2=1.65

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apps/dokuwiki/ChangeLog,v
retrieving revision 1.64
retrieving revision 1.65
diff -u -r1.64 -r1.65
--- ChangeLog	9 Jan 2014 13:05:57 -0000	1.64
+++ ChangeLog	2 Jun 2014 21:00:16 -0000	1.65
@@ -1,6 +1,12 @@
 # ChangeLog for www-apps/dokuwiki
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-apps/dokuwiki/ChangeLog,v 1.64 2014/01/09 13:05:57 jmbsvicetto Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-apps/dokuwiki/ChangeLog,v 1.65 2014/06/02 21:00:16 jmbsvicetto Exp $
+
+*dokuwiki-20140505 (02 Jun 2014)
+
+  02 Jun 2014; Jorge Manuel B. S. Vicetto <jmbsvicetto@g.o>
+  +dokuwiki-20140505.ebuild:
+  20140505 version bump - fixes bug 512054.
 
 *dokuwiki-20131208 (09 Jan 2014)
 



1.1                  www-apps/dokuwiki/dokuwiki-20140505.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/dokuwiki/dokuwiki-20140505.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/dokuwiki/dokuwiki-20140505.ebuild?rev=1.1&content-type=text/plain

Index: dokuwiki-20140505.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/dokuwiki/dokuwiki-20140505.ebuild,v 1.1 2014/06/02 21:00:16 jmbsvicetto Exp $

EAPI="4"

inherit webapp depend.php

# upstream uses dashes in the datestamp
MY_BASE_PV="${PV:0:4}-${PV:4:2}-${PV:6:2}"
MY_PV="${MY_BASE_PV}${PV:8:1}"

DESCRIPTION="DokuWiki is a simple to use Wiki aimed at a small company's documentation needs."
HOMEPAGE="http://wiki.splitbrain.org/wiki:dokuwiki"
SRC_URI="http://download.dokuwiki.org/src/${PN}/${PN}-${MY_PV}.tgz"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="gd"

DEPEND=""
RDEPEND="
	>=dev-lang/php-5.3[xml]
	gd? ( ||
		(
			dev-lang/php[gd]
			media-gfx/imagemagick
		)
	)
"

need_httpd_cgi
need_php_httpd

S="${WORKDIR}/${PN}-${MY_PV}"

src_prepare() {
	# create initial changes file
	touch data/changes.log
}

src_install() {
	webapp_src_preinst

	dodoc README
	rm -f README COPYING

	docinto scripts
	dodoc bin/*
	rm -rf bin

	insinto "${MY_HTDOCSDIR}"
	doins -r .

	for x in $(find data/ -not -name '.htaccess'); do
		webapp_serverowned "${MY_HTDOCSDIR}"/${x}
	done

	webapp_configfile "${MY_HTDOCSDIR}"/.htaccess.dist
	webapp_configfile "${MY_HTDOCSDIR}"/conf

	for x in $(find conf/ -not -name 'msg'); do
		webapp_configfile "${MY_HTDOCSDIR}"/${x}
	done

	webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
	webapp_src_install
}