[gentoo-commits] repo/gentoo:master commit in: media-gfx/gnome-photos/

[Mart Raudsepp]

commit:     ee20b12609776a382b2c76e769f94671fe629ee4
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 29 17:07:52 2020 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sun Mar 29 17:08:22 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ee20b126

media-gfx/gnome-photos: bump to 3.34.1

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 media-gfx/gnome-photos/Manifest                   |  1 +
 media-gfx/gnome-photos/gnome-photos-3.34.1.ebuild | 94 +++++++++++++++++++++++
 2 files changed, 95 insertions(+)

diff --git a/media-gfx/gnome-photos/Manifest b/media-gfx/gnome-photos/Manifest
index 09973981de9..2f6ea28e1df 100644
--- a/media-gfx/gnome-photos/Manifest
+++ b/media-gfx/gnome-photos/Manifest
@@ -1 +1,2 @@
 DIST gnome-photos-3.32.1.tar.xz 632688 BLAKE2B 9fa7307d1571f6c4e07d6c9700fd947e4a0ff26f8308f7b1871da817e5d80b19861d3c94a1b8ffe0daa820862ad064075641c8eb42ad66134e7c554696448932 SHA512 31a52b93c27ee603ddb314998d663d02c1cfdbc33214d2d9f977f7b66f4fc131a52cd17b274efcfb80f2fb17d7b469157e99a783cbfe76e0b872a2a75363b208
+DIST gnome-photos-3.34.1.tar.xz 636916 BLAKE2B 3d041f3a8349164e12b8788b028edf23c0db1e671c5da4356dbdc01f5129e8dfabd3ee9df3af82b2794e22c1d8d894b7726068d69a605b0d598ec1dc21754470 SHA512 9ee1bf299f82b4a55d2642e34cfa82e0a3a362cd5e415acd5421d54430da5ea5a9f831ecf5ccf6966eea056c851fde57385f9224441be3d06e086be108d53227

diff --git a/media-gfx/gnome-photos/gnome-photos-3.34.1.ebuild b/media-gfx/gnome-photos/gnome-photos-3.34.1.ebuild
new file mode 100644
index 00000000000..7a8e9d539fb
--- /dev/null
+++ b/media-gfx/gnome-photos/gnome-photos-3.34.1.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_6 )
+
+inherit gnome.org gnome2-utils meson python-any-r1 virtualx xdg
+
+DESCRIPTION="Access, organize and share your photos on GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Photos"
+
+LICENSE="GPL-3+ LGPL-2+ CC0-1.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="flickr test upnp-av"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	media-libs/babl
+	>=x11-libs/cairo-1.14.0
+	>=x11-libs/gdk-pixbuf-2.36.8:2
+	>=media-libs/gegl-0.4.0:0.4[cairo,raw]
+	sci-geosciences/geocode-glib
+	>=media-libs/gexiv2-0.10.8
+	>=dev-libs/glib-2.57.2:2
+	>=net-libs/gnome-online-accounts-3.8.0:=
+	>=media-libs/grilo-0.3.5:0.3=
+	gnome-base/gsettings-desktop-schemas
+	>=x11-libs/gtk+-3.22.16:3
+	>=dev-libs/libdazzle-3.26.0
+	>=dev-libs/libgdata-0.15.2:0=[gnome-online-accounts]
+	>=net-libs/libgfbgraph-0.2.1:0.2
+	virtual/jpeg:0
+	>=media-libs/libpng-1.6:0=
+	>=app-misc/tracker-2.0:0/2.0
+	sys-apps/dbus
+"
+# gnome-online-miners is also used for google, facebook, DLNA - not only flickr
+# but out of all the grilo-plugins, only upnp-av and flickr get used, which have USE flags here,
+# so don't pull it always, but only if either USE flag is enabled.
+# tracker-miners gschema used at runtime.
+RDEPEND="${DEPEND}
+	net-misc/gnome-online-miners[flickr?]
+	upnp-av? ( media-plugins/grilo-plugins:0.3[upnp-av] )
+	flickr? ( media-plugins/grilo-plugins:0.3[flickr] )
+	>=app-misc/tracker-miners-2
+"
+BDEPEND="
+	dev-libs/appstream-glib
+	dev-util/desktop-file-utils
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	test? ( $(python_gen_any_dep 'dev-util/dogtail[${PYTHON_USEDEP}]') )
+"
+
+DOCS=() # meson installs docs itself
+
+python_check_deps() {
+	use test && has_version "dev-util/dogtail[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	xdg_src_prepare
+	sed -i -e "/photos_docdir.*=.*join_paths/s/meson.project_name()/'${PF}'/" meson.build
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use test dogtail)
+		-Dinstalled_tests=false
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}