[gentoo-commits] repo/gentoo:master commit in: dev-python/jeepney/

[Michał Górny]

commit:     c93f074fd1d5ab86970bc68b58b5cd9070d5701b
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Apr  3 20:24:39 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Apr  3 21:54:47 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c93f074f

dev-python/jeepney: Bump to 0.8.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/jeepney/Manifest             |  1 +
 dev-python/jeepney/jeepney-0.8.0.ebuild | 64 +++++++++++++++++++++++++++++++++
 2 files changed, 65 insertions(+)

diff --git a/dev-python/jeepney/Manifest b/dev-python/jeepney/Manifest
index 132762d5f718..3001db4cb9d7 100644
--- a/dev-python/jeepney/Manifest
+++ b/dev-python/jeepney/Manifest
@@ -1,2 +1,3 @@
 DIST jeepney-0.6.0.tar.gz 49513 BLAKE2B e5f9b5104cf07dbcd2d40c2d22b690dfd56c456ab56daf44f4abee83f0bfe7e1dfbad797348044d51e3dc20fbc6ce68bf8df54f9c1e46d7a86ceb22d3ab30f8d SHA512 140be9dd28ed853d2d41b6a8bbeb2f22c0270ce7bf33b943ec2ac010db17d4f06e253fa8637fbbb3044fe9ffdbfa1e15f0c663eb44bdd538f8c47c2e7dab3ca5
 DIST jeepney-0.7.1.tar.gz 61833 BLAKE2B 626d4c921d0548ea898197ac5459f20b4c73fd52d3579c5b74f257158c82803011655c1d418d7d10afe8ba803100530bc08dbcce41e12727888de5be5995adb3 SHA512 f0af5a18a669f1a6322925201cad83ee01bc5a1b91577565042fd8a18b506a3650ff67b0ba333c8fb3b179f43ef243d16b07a9a1f7a7e5baec825dda0e6b0571
+DIST jeepney-0.8.0.tar.gz 106005 BLAKE2B 23dbd876915ca364202b6e1888d5b6892c56020a492f9dbdd22c1e04f40c2627bfb90ce209c69be000e176cc6b144b6c2232a21ce1ab089971911ffa2c22cd2c SHA512 823675f262c2c9778ccf9c1083601d936cca534fc0d2d9309b52aa6beeb7f73d225a37c5f18f6b0683c4829a93b1299a2cb4f8f341e55b92bedf58c8dce0aa75

diff --git a/dev-python/jeepney/jeepney-0.8.0.ebuild b/dev-python/jeepney/jeepney-0.8.0.ebuild
new file mode 100644
index 000000000000..18ca1de03898
--- /dev/null
+++ b/dev-python/jeepney/jeepney-0.8.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( pypy3 python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, pure Python DBus protocol wrapper"
+HOMEPAGE="https://gitlab.com/takluyver/jeepney/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="examples"
+
+BDEPEND="
+	test? (
+		dev-python/async_timeout[${PYTHON_USEDEP}]
+		>=dev-python/pytest-asyncio-0.7.1[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+		sys-apps/dbus
+		$(python_gen_cond_dep '
+			dev-python/pytest-trio[${PYTHON_USEDEP}]
+			dev-python/trio[${PYTHON_USEDEP}]
+		' 'python3*')
+	)
+"
+
+distutils_enable_tests pytest
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx_rtd_theme
+
+src_test() {
+	local dbus_params=(
+		$(dbus-daemon --session --print-address --fork --print-pid)
+	)
+	local -x DBUS_SESSION_BUS_ADDRESS=${dbus_params[0]}
+
+	distutils-r1_src_test
+
+	kill "${dbus_params[1]}" || die
+}
+
+python_test() {
+	local EPYTEST_IGNORE=()
+	# keep in sync with python_gen_cond_dep!
+	if [[ ${EPYTHON} != python3* ]]; then
+		EPYTEST_IGNORE+=( jeepney/io/tests/test_trio.py )
+	fi
+	epytest
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		dodoc -r examples
+	fi
+	distutils-r1_python_install_all
+}