[gentoo-commits] gentoo-x86 commit in games-engines/odamex: ChangeLog odamex-0.7.0.ebuild

[Julian Ospald (hasufell)]

hasufell    14/03/27 21:20:52

  Modified:             ChangeLog
  Added:                odamex-0.7.0.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.9-r1/cvs/Linux x86_64, signed Manifest commit with key BDEED020)

Revision  Changes    Path
1.15                 games-engines/odamex/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-engines/odamex/ChangeLog?rev=1.15&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-engines/odamex/ChangeLog?rev=1.15&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-engines/odamex/ChangeLog?r1=1.14&r2=1.15

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-engines/odamex/ChangeLog,v
retrieving revision 1.14
retrieving revision 1.15
diff -u -r1.14 -r1.15
--- ChangeLog	30 Sep 2013 17:16:29 -0000	1.14
+++ ChangeLog	27 Mar 2014 21:20:52 -0000	1.15
@@ -1,6 +1,16 @@
 # ChangeLog for games-engines/odamex
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-engines/odamex/ChangeLog,v 1.14 2013/09/30 17:16:29 ago Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/games-engines/odamex/ChangeLog,v 1.15 2014/03/27 21:20:52 hasufell Exp $
+
+*odamex-0.7.0 (27 Mar 2014)
+
+  27 Mar 2014; Julian Ospald <hasufell@g.o> +odamex-0.7.0.ebuild,
+  +files/2-odamex-0.7.0-cmake-options.patch,
+  +files/1-odamex-0.7.0-install-rules.patch,
+  +files/odamex-0.7.0-miniupnpc.patch,
+  +files/4-odamex-0.7.0-odalauncher-bin-path.patch,
+  +files/3-odamex-0.7.0-wad-search-path.patch:
+  version bump
 
   30 Sep 2013; Agostino Sarubbo <ago@g.o> odamex-0.6.4.ebuild:
   Stable for x86, wrt bug #486232



1.1                  games-engines/odamex/odamex-0.7.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-engines/odamex/odamex-0.7.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-engines/odamex/odamex-0.7.0.ebuild?rev=1.1&content-type=text/plain

Index: odamex-0.7.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-engines/odamex/odamex-0.7.0.ebuild,v 1.1 2014/03/27 21:20:52 hasufell Exp $

EAPI=5
WX_GTK_VER="3.0"
inherit cmake-utils eutils gnome2-utils wxwidgets games

MY_P=${PN}-src-${PV}
DESCRIPTION="An online multiplayer, free software engine for Doom and Doom II"
HOMEPAGE="http://odamex.net/"
SRC_URI="mirror://sourceforge/${PN}/Odamex/${PV}/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="dedicated +odalaunch master portmidi server"

RDEPEND="
	dedicated? ( >=net-libs/miniupnpc-1.8 )
	!dedicated? (
		media-libs/libpng:0
		>=media-libs/libsdl-1.2.9[X,audio,joystick,video]
		>=media-libs/sdl-mixer-1.2.6
		odalaunch? ( x11-libs/wxGTK:${WX_GTK_VER}[X] )
		portmidi? ( media-libs/portmidi )
		server? ( >=net-libs/miniupnpc-1.8 )
	)"
DEPEND="${RDEPEND}"

S=${WORKDIR}/src-${PV:2:3}

pkg_pretend() {
	if ! test-flag-CXX -std=c++11; then
		die "You need at least GCC 4.7.x or Clang >= 3.0 for C++11-specific compiler flags"
	fi
}

src_prepare() {
	epatch "${FILESDIR}"/1-${P}-install-rules.patch \
		"${FILESDIR}"/2-${P}-cmake-options.patch \
		"${FILESDIR}"/3-${P}-wad-search-path.patch \
		"${FILESDIR}"/4-${P}-odalauncher-bin-path.patch \
		"${FILESDIR}"/${P}-miniupnpc.patch

	rm -r libraries/libminiupnpc || die

	epatch_user
}

src_configure() {
	local mycmakeargs=(
		-DUSE_INTREE_PORTMIDI=OFF
		-DCMAKE_INSTALL_BINDIR="${GAMES_BINDIR}"
		-DCMAKE_INSTALL_DATADIR="${GAMES_DATADIR}"
		$(cmake-utils_use_build master MASTER)
	)

	if use dedicated ; then
		mycmakeargs+=(
			-DBUILD_CLIENT=OFF
			-DBUILD_ODALAUNCH=OFF
			-DBUILD_SERVER=ON
			-DENABLE_PORTMIDI=OFF
		)
	else
		mycmakeargs+=(
			-DBUILD_CLIENT=ON
			$(cmake-utils_use_build odalaunch ODALAUNCH)
			$(cmake-utils_use_build server SERVER)
			$(cmake-utils_use_enable portmidi PORTMIDI)
		)
	fi

	append-cxxflags -std=c++11

	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_compile
}

src_install() {
	cmake-utils_src_install

	if ! use dedicated ; then
		newicon -s 128 "${S}/media/icon_${PN}_128.png" "${PN}.png"
		make_desktop_entry ${PN}

		if use odalaunch ; then
			newicon -s 128 "${S}/media/icon_odalaunch_128.png" "odalaunch.png"
			make_desktop_entry odalaunch "Odamex Launcher" odalaunch
		fi
	fi

	prepgamesdirs
}

pkg_preinst() {
	games_pkg_preinst
	gnome2_icon_savelist
}

pkg_postinst() {
	games_pkg_postinst
	einfo
	elog "This is just the engine, you will need doom resource files in order to play."
	elog "Check: http://odamex.net/wiki/FAQ#What_data_files_are_required.3F"
	einfo
	gnome2_icon_cache_update
}

pkg_postrm() {
	gnome2_icon_cache_update
}