[gentoo-commits] gentoo-x86 commit in sys-fs/zfs-kmod: zfs-kmod-9999.ebuild zfs-kmod-0.6.1.ebuild ChangeLog

[Richard Yao (ryao)]

ryao        13/03/28 22:19:35

  Modified:             zfs-kmod-9999.ebuild ChangeLog
  Added:                zfs-kmod-0.6.1.ebuild
  Log:
  Version bump to 0.6.1
  
  (Portage version: 2.2.0_alpha169/cvs/Linux x86_64, signed Manifest commit with key 0xBEE84C64)

Revision  Changes    Path
1.14                 sys-fs/zfs-kmod/zfs-kmod-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/zfs-kmod/zfs-kmod-9999.ebuild?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/zfs-kmod/zfs-kmod-9999.ebuild?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/zfs-kmod/zfs-kmod-9999.ebuild?r1=1.13&r2=1.14

Index: zfs-kmod-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/zfs-kmod/zfs-kmod-9999.ebuild,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- zfs-kmod-9999.ebuild	24 Mar 2013 00:02:31 -0000	1.13
+++ zfs-kmod-9999.ebuild	28 Mar 2013 22:19:35 -0000	1.14
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/zfs-kmod/zfs-kmod-9999.ebuild,v 1.13 2013/03/24 00:02:31 ryao Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/zfs-kmod/zfs-kmod-9999.ebuild,v 1.14 2013/03/28 22:19:35 ryao Exp $
 
 EAPI="4"
 
@@ -64,27 +64,6 @@
 }
 
 src_prepare() {
-	if [ ${PV} != "9999" ]
-	then
-		# Cast constant for 32-bit compatibility
-		epatch "${FILESDIR}/${P}-cast-const-for-32bit-compatibility.patch"
-
-		# Handle missing name length check in Linux VFS
-		epatch "${FILESDIR}/${P}-vfs-name-length-compatibility.patch"
-
-		# Fix NULL pointer exception on hardened kernels, bug #457176
-		epatch "${FILESDIR}/${P}-improved-hardened-support.patch"
-
-		# Fix barrier regression on Linux 2.6.37 and later
-		epatch "${FILESDIR}/${P}-flush-properly.patch"
-
-		# Improve accuracy of autotools checks
-		epatch "${FILESDIR}/${P}-improved-autotools-checks.patch"
-
-		# Linux 3.9 Support
-		epatch "${FILESDIR}/${P}-linux-3.9-compat.patch"
-	fi
-
 	# Remove GPLv2-licensed ZPIOS unless we are debugging
 	use debug || sed -e 's/^subdir-m += zpios$//' -i "${S}/module/Makefile.in"
 
@@ -118,13 +97,23 @@
 pkg_postinst() {
 	linux-mod_pkg_postinst
 
+	# Remove old modules
+	if [ -d "${EROOT}lib/modules/${KV_FULL}/addon/zfs" ]
+	then
+		ewarn "${PN} now installs modules in ${EROOT}lib/modules/${KV_FULL}/extra/zfs"
+		ewarn "Old modules were detected in ${EROOT}lib/modules/${KV_FULL}/addon/zfs"
+		ewarn "Automatically removing old modules to avoid problems."
+		rm -r "${EROOT}lib/modules/${KV_FULL}/addon/zfs" || die "Cannot remove modules"
+		rmdir --ignore-fail-on-non-empty "${EROOT}lib/modules/${KV_FULL}/addon"
+	fi
+
 	if use x86 || use arm
 	then
 		ewarn "32-bit kernels will likely require increasing vmalloc to"
 		ewarn "at least 256M and decreasing zfs_arc_max to some value less than that."
 	fi
 
-	ewarn "This version of ZFSOnLinux introduces support for features flags."
+	ewarn "This version of ZFSOnLinux includes support for features flags."
 	ewarn "If you upgrade your pools to make use of feature flags, you will lose"
 	ewarn "the ability to import them using older versions of ZFSOnLinux."
 	ewarn "Any new pools will be created with feature flag support and will"



1.26                 sys-fs/zfs-kmod/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/zfs-kmod/ChangeLog?rev=1.26&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/zfs-kmod/ChangeLog?rev=1.26&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/zfs-kmod/ChangeLog?r1=1.25&r2=1.26

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/zfs-kmod/ChangeLog,v
retrieving revision 1.25
retrieving revision 1.26
diff -u -r1.25 -r1.26
--- ChangeLog	24 Mar 2013 00:02:31 -0000	1.25
+++ ChangeLog	28 Mar 2013 22:19:35 -0000	1.26
@@ -1,6 +1,12 @@
 # ChangeLog for sys-fs/zfs-kmod
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/zfs-kmod/ChangeLog,v 1.25 2013/03/24 00:02:31 ryao Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/zfs-kmod/ChangeLog,v 1.26 2013/03/28 22:19:35 ryao Exp $
+
+*zfs-kmod-0.6.1 (28 Mar 2013)
+
+  28 Mar 2013; Richard Yao <ryao@g.o> +zfs-kmod-0.6.1.ebuild,
+  zfs-kmod-9999.ebuild:
+  Version bump to 0.6.1
 
   24 Mar 2013; Richard Yao <ryao@g.o> zfs-kmod-0.6.0_rc14-r5.ebuild,
   zfs-kmod-9999.ebuild:



1.1                  sys-fs/zfs-kmod/zfs-kmod-0.6.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/zfs-kmod/zfs-kmod-0.6.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/zfs-kmod/zfs-kmod-0.6.1.ebuild?rev=1.1&content-type=text/plain

Index: zfs-kmod-0.6.1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/zfs-kmod/zfs-kmod-0.6.1.ebuild,v 1.1 2013/03/28 22:19:35 ryao Exp $

EAPI="4"

AT_M4DIR="config"
AUTOTOOLS_AUTORECONF="1"
AUTOTOOLS_IN_SOURCE_BUILD="1"

inherit bash-completion-r1 flag-o-matic linux-info linux-mod toolchain-funcs autotools-utils

if [ ${PV} == "9999" ] ; then
	inherit git-2
	MY_PV=9999
	EGIT_REPO_URI="git://github.com/zfsonlinux/zfs.git"
else
	inherit eutils versionator
	MY_PV=$(replace_version_separator 3 '-')
	SRC_URI="https://github.com/zfsonlinux/zfs/archive/zfs-${MY_PV}.tar.gz"
	S="${WORKDIR}/zfs-zfs-${MY_PV}"
	KEYWORDS="~amd64"
fi

DESCRIPTION="Linux ZFS kernel module for sys-fs/zfs"
HOMEPAGE="http://zfsonlinux.org/"

LICENSE="CDDL debug? ( GPL-2+ )"
SLOT="0"
IUSE="custom-cflags debug +rootfs"
RESTRICT="test"

DEPEND="
	=sys-kernel/spl-${PV}*
	virtual/awk
"

RDEPEND="${DEPEND}
	!sys-fs/zfs-fuse
"

pkg_setup() {
	linux-info_pkg_setup
	CONFIG_CHECK="!DEBUG_LOCK_ALLOC
		BLK_DEV_LOOP
		EFI_PARTITION
		IOSCHED_NOOP
		MODULES
		!PAX_KERNEXEC_PLUGIN_METHOD_OR
		ZLIB_DEFLATE
		ZLIB_INFLATE
	"

	use rootfs && \
		CONFIG_CHECK="${CONFIG_CHECK} BLK_DEV_INITRD
			DEVTMPFS"

	kernel_is ge 2 6 26 || die "Linux 2.6.26 or newer required"

	[ ${PV} != "9999" ] && \
		{ kernel_is le 3 9 || die "Linux 3.9 is the latest supported version."; }

	check_extra_config
}

src_prepare() {
	# Remove GPLv2-licensed ZPIOS unless we are debugging
	use debug || sed -e 's/^subdir-m += zpios$//' -i "${S}/module/Makefile.in"

	autotools-utils_src_prepare
}

src_configure() {
	use custom-cflags || strip-flags
	filter-ldflags -Wl,*

	set_arch_to_kernel
	local myeconfargs=(
		--bindir="${EPREFIX}/bin"
		--sbindir="${EPREFIX}/sbin"
		--with-config=kernel
		--with-linux="${KV_DIR}"
		--with-linux-obj="${KV_OUT_DIR}"
		$(use_enable debug)
	)
	autotools-utils_src_configure
}

src_install() {
	autotools-utils_src_install
	dodoc AUTHORS COPYRIGHT DISCLAIMER README.markdown

	# Provide /usr/src/zfs symlink for lustre
	dosym "$(basename $(echo "${ED}/usr/src/zfs-"*))/${KV_FULL}" /usr/src/zfs
}

pkg_postinst() {
	linux-mod_pkg_postinst

	# Remove old modules
	if [ -d "${EROOT}lib/modules/${KV_FULL}/addon/zfs" ]
	then
		ewarn "${PN} now installs modules in ${EROOT}lib/modules/${KV_FULL}/extra/zfs"
		ewarn "Old modules were detected in ${EROOT}lib/modules/${KV_FULL}/addon/zfs"
		ewarn "Automatically removing old modules to avoid problems."
		rm -r "${EROOT}lib/modules/${KV_FULL}/addon/zfs" || die "Cannot remove modules"
		rmdir --ignore-fail-on-non-empty "${EROOT}lib/modules/${KV_FULL}/addon"
	fi

	if use x86 || use arm
	then
		ewarn "32-bit kernels will likely require increasing vmalloc to"
		ewarn "at least 256M and decreasing zfs_arc_max to some value less than that."
	fi

	ewarn "This version of ZFSOnLinux includes support for features flags."
	ewarn "If you upgrade your pools to make use of feature flags, you will lose"
	ewarn "the ability to import them using older versions of ZFSOnLinux."
	ewarn "Any new pools will be created with feature flag support and will"
	ewarn "not be compatible with older versions of ZFSOnLinux. To create a new"
	ewarn "pool that is backward compatible, use zpool create -o version=28 ..."
}